{Change Comments ***********************************************************}

{added CRCOffC to rapid up and repeats, same as all other Fadal posts, 9/26/88 WFG}

{5/31/89
Copied & modified; Fadal M003.57, for Pearallel Ventures.
Add OperationComment & ToolComment to DoSubComment.
Add OpToolID to 1st operation.
Move CoolOn to OfstOn line.
Move SpinOff to CoolOff line.
Add OfstOff - G49Z0.
Move ToolComment to be on same line as OpToolID.
Move WFO, SpinOn & Speed to same line as StrtPos.
Add another OpToolID to StrtPos line - for operator searching.
Add Feed Override Disable commands if Tapping.
Use parens for comments.
Change subroutine #'s to begin with 'L100', and increment by 100.
change "NewProg" to "TagInc"
change "SubIDF" to "'L' Tag# '00'"
Change subroutine calls to 'L1nn' where nn is Repeats for 'L100'.
change "CallLab" to "'L' Tag#"
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/10/90, Updated: Fadal (PV) M208.56 to .74 format, JR}
{5/11/98, Updated for Catalyst v2.20 per Fanuc 6M M001.89 Format, CDH}

{30Jul98
Original: Fadal [PV] M208.89
Created: Fadal [PV] M208.89.1
For: Parallel Venturers Inc
Changes made per: Bob Hendricks
Post was outputting invalid line numbers.
Replaced all SeqC with SeqLab in RestoreAbsOrInc, ZonlyRepAutoCycle and on the 'G80' Line at the end of Drilling.
Added TagInit at InitProg. Post was outputting invalid Sub Numbers.
Added ToolChng in FirstOperation after OpToolID.
Added OfstOff at End of Prog
Charles Winston}

{8/31/98,
Initial : Fadal [PV] M208.89.1
Created: Fadal Format 1 [PV] M208.89.2
Customer: Parallel Venturers Inc., Bob Hendricks - 520/745-5288

Changes to "Prog":

1. Added FORMAT for TrackZNO#.
2. Added park line at end (G0G90X0.Y0.E0)
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '#####.###;0.'
#5 = '####.####;0.'
#6 = '########;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,4)
FORMAT(ToolDiameter#,5)
FORMAT(TrackZNO#,5) {Added - JHE}
FORMAT(Program#,6)
FORMAT(Operation#,6)
FORMAT(Tool#,6)
FORMAT(NewWFO#,6)
FORMAT(Parts#,6)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments?
IF SubComment?
SeqLab '( SUB NUMBER: ' Tag# ' )' EOL
END
IF OperationComment?
SeqLab '( ' OperationComment$ ' )' EOL
END
IF ToolComment?
SeqLab '( ' ToolComment$ ' )' EOL
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLab '( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLab '( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLab '( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
ProgStopF
CoolOffF
RotateF
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab Feed ZIn FeedEnt EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqLab 'L' Tag# '00' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLab 'L' Tag# RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLab CRCOffC
IF NOT FeedConnect?
RapidC ZCP3C
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLab Preset ShiftR EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftR EOL
RETURN

OpenMP:
TagInc
IF WorkFixtureOffsets?
NewWFO
EACHWFO
SeqLab SetWFO EOL
SeqLab 'L' Tag# OnePart EOL
IncWFO
NEXTWFO
ELSE
SeqLab 'L' Tag# Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLab EndSub EOL
CloseSub
SeqLab WFO1 EOL
ELSE
SeqLab Preset ShiftP EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftP EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLab AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLab DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed EOL
ELSE
SeqLab DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC EOL
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqLab DoDrillAbsOrInc MoveSXYC EOL
IF AutoCycle?
SeqLab 'L' Tag# OnePart EOL
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqLab DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
SeqLab DoAbsOrInc RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqLab DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLab DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc ArcFeedC EOL
DecelMove2
END
SeqLab FormatArc DecelFeed EOL
ELSE
SeqLab FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS'
ELSE
'E' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'E' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
SeqLab StrtPosC EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLab AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqLab AbsOrInc RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
SeqLab EndSub EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLab AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
SetPass1 {for correct Z's}
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Feed IncValue StrtPosC EOL
SeqLab AbsOrInc
ELSE
SeqLab Feed
END
ELSE
SeqLab Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLab AbsOrInc ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLab Rapid ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab 'L' Tag# OnePart EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
SeqLab Rapid ZCP2 EOL {.69}
END {.69}
SeqLab EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLab 'L' Tag# OnePart EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetCoolant:
IF NOT CoolOff?
CoolOn
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN


{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50') {?}
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' CoolantOff, COff -' EOL
' suppress coolant on command for current operation' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' ProgramStop, PS' - EOL
' Coolant Off, full tool up, M00, restore tool postion, coolant on.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
SeqLab 'O' Program#
IF UseComments? AND ProgramNameComment?
'(' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
SeqLab '( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLab '( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLab '( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLab '( OUTPUT IN ' MoveType$ ' )' EOL
END
IF PartsComment?
SeqLab '( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqLab '( FIRST TOOL IN SPINDLE' ' )' EOL
END
END
IF ToolChangeAtHome?
SetHome
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab OpToolID ToolChng
IF UseComments? AND ToolComment?
'( ' ToolComment$ ' )'
END
EOL
DoOpComments
DoPostScript
IF ProgStop?
SeqLab 'M00' EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab Plane AbsOrInc Rapid StrtPos Speed SpinOn WFOStuff EOL
SeqLab OfstOn GetCoolant EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab AbsOrInc Rapid StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab CoolOff SpinOff EOL
SeqLab OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLab AbsOrInc Rapid Home EOL
END
IF ProgStop?
SeqLab 'M00' EOL
ELSE
SeqLab ProgStop EOL
END

{Start new Operation}

SeqLab OpToolID ToolChng
IF UseComments? AND ToolComment?
'( ' ToolComment$ ' )'
END
EOL
DoOpComments
DoPostScript
IF ProgStop?
SeqLab 'M00' EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab Plane AbsOrInc Rapid StrtPos Speed SpinOn WFOStuff OpToolID EOL
SeqLab OfstOn GetCoolant EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab AbsOrInc Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF ProgStop?
SeqLab CoolOff SpinOff EOL
SeqLab OfstOff EOL
SeqLab 'M00' EOL

{Start new Operation}

GetStartOfSameTool
IF ProgStop?
SeqLab 'M00' EOL
END
SeqLab PlaneC AbsOrInc Rapid StrtPos SpeedC SpinOn WFOStuff EOL
SeqLab OfstOn GetCoolant EOL
ELSE
IF NewToolOffset?
SeqLab OfstOff EOL

{Start new Operation}

GetStartOfSameTool
IF ProgStop?
SeqLab CoolOff SpinOff EOL
SeqLab 'M00' EOL
SeqLab PlaneC AbsOrInc Rapid StrtPos SpeedC SpinOn WFOStuff EOL
SeqLab OfstOn GetCoolant EOL
ELSE
SeqLab PlaneC AbsOrInc Rapid StrtPos SpeedC WFOStuff EOL
SeqLab OfstOn EOL
END
ELSE
{Start new Operation}

GetStartOfSameTool
IF ProgStop?
SeqLab CoolOff SpinOff EOL
SeqLab 'M00' EOL
SeqLab PlaneC AbsOrInc Rapid StrtPos SpeedC SpinOn WFOStuff EOL
SeqLab GetCoolant EOL
ELSE
SeqLab PlaneC AbsOrInc Rapid StrtPos SpeedC WFOStuff EOL
END
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLab RapidC CRCOffC ZCP3C EOL
ELSE
IF Drilling?
IF Tap?
SeqLab 'M49' EOL {feedrate override disable}
END
IF Repeats?
TagInc
StdSub
SeqLab AbsOrInc Rapid StrtPos EOL
END
SeqLab DrillCP EOL
IF Tap?
SeqLab GetCycle Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FadalTapF FadalTapQ EOL
ELSE
SeqLab GetCycle Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
END
IF CallMasterOp?
SeqLab 'L' CallMasterNum# '01' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterTag
StdSub
ToolPath
SeqLab EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
IF Tap?
SeqLab 'M48' EOL {feedrate override enable}
END
SeqLab Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab CoolOff SpinOff EOL
SeqLab OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLab Rapid AbsOrInc FirstHome 'E0' EOL {Added E0 - JHE}
ELSE
SeqLab Rapid AbsOrInc 'X0.Y0.E0' EOL {Added this line - JHE}
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab UnTool ToolChng EOL
SeqLab 'M0' EOL
SeqLab EOP EOL
EndSubs
Post
EOR EOL
'BYE' EOL
Close
ReTag
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS' ' )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET' ' )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS' ' )' EOL
END
Close
END