{added CRCOffC to rapid up and repeats, same as all other Fadal posts, 9/26/88 WFG}
{Changed max rpm from 10000 to 15000 JR 6/5/89}

{1/26/90, Updated: Fadal M003.58, to .69 format, JR}
{2/90/90, Updated: Fadal M003.69, to .70 format, JR}
{3/23/90, 15000 max RPM, JR}

{4/6/90
Added '01' literal for looping once on CallLab line at ZonlyRepAutoCycle & ZonlyRep subs.
DWB}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{8/10/90, Updated: Fadal M003.71 to .74 format, JR}

{8/10/90
Copied & modified: Fadal M003.74
For: Admiral
Add CRCOffsetC & ResetCRCNum.
Change to First Tool Not In Spindle.
OpToolID & ToolChng on same line.
WFO's output for MultipleParts & NewWFO only.
Added 'Z0H0' for offset cancel (full up) with CoolOff on same line.
Remove StrtPos from drill cycle line.
CoolOn on same line as OfstOn.
Combine M codes on 1 line.
Jim Radcliffe}

{4/03/91
Modified: Fadal (AEM) M332.74
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{7/2/92
Copied & modified from Fadal (AEM) M332.79
New designation Fadal Format 1 (AC) M509.81.2
For Amcraft
Add WFO to move to StrtPos.
Add StrtPos to WFO's at multi parts.
Change 'Z0H0' to 'G0G49Z0' for offset cancel and remove CoolOff except at end.
Add 'X0Y10.E0' to bring table to operator for loading. Works with VMC 4020 only. Y value would differ
for other models. Not ideal way to handle but consistent with customers current method.
Add 'M0' before 'M2' at end of program so that table stops at modified E0 position.
Add StrtPos to drill cycle line.
Move Rapid StrtPos lines ahead of IF Multiparts? lines.
KC}

{8/19/92
Added "SetProgNum" to reset subroutine numbers to one "1" regardless of program number
KC}

{4/6/93
Added G8 at each tool. Remove BYE from program end.
KC}

{4/6/93
Copied from Fadal Format 1 (AC) M509.81.2
New designation Fadal Format 1 (KC) M---.--.-
CoolOn command M8 replaces M7
KC}

{09/07/93
Removed 'DrillCP' and 'RapidC ZCP3C' from the 'IF Drilling?' commands
KC}

{09/10/93
Changed CRC to XY plane. [ckCRC].
KC}

{09/13/93
Initial rapid goes to first Autocycle posistion instead of part origin.
Changed #6 format to add trailing 0's.
KC}

{3/2/94
Removed M0 from end of program.
Changed G84 tap cycle to G85, adding M49 and M48.
Removed some comments.
These changes are at customers request.
KC}

{3/30/94
Copied and changed to Fadal Format 1 [SMF] M636.81.2 for Sanders Machine & Tool Company.
Minor changes to remove E's from repeats and seperate coolant spindle off from
zero return command.
KC}

{4/15/94
Uncheck 'Allow R-Format Arcs' boolean. (Caused mixed output in programs input in metric).
KC}

{5/13/94
Changed CRC on and off back to Z moves. Loads first tool into spindle at end of program
instead of start.
KC}

{1/17/96, Updated .85 to .86 version, MPK}
{3/7/96,
Initial: Fadal Format 1 [SMF] M636.86
Created: Fadal Format 1 [SMF] M636.86.1
Moved CRCoff out of subroutines, MPK}
{3/7/96,
Initial: Fadal Format 1 [SMF] M636.86.1
Created: Fadal Format 1 [SMF] M636.86.2
Put 'G8' line by itself, created tool list at program beginning, MPK}
{3/8/96,
Initial: Fadal Format 1 [SMF] M636.86.2
Created: Fadal Format 1 [SMF] M636.86.3
Moved CRCOff back into subroutines, created RepCRC subroutine to check for CRC and turn CRC on
before every repeat of a z shift sub, MPK}
{3/11/96
Initial: Fadal Format 1 [SMF] M636.86.2
Created: Fadal Format 1 [SMF] M636.86.3
added sequence # to Tool list, added tool comment to tool list, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{29/4/97,
Initial: Fadal Format 1 [SMF] M636.89
Created: Fadal Format 1 [SMF] M636.89.1
Added WorkGroupComment in DoOpComment?
Charles Winston}

{7Jul97
Original: Fadal Format 1 [SMF] M636.89.1
Created: Fadal Format 1 [SMF] M636.89.2
For: Sanders Machine
Changes made per: Matt Finley
Added FormatNameComment, TimeComment & MovesComment in FirstOperation
Moved CRCOn to subroutines, Deleted CRCOnC at IF Milling in Common point
Charles Winston}

{1Aug97
Original: Fadal Format 1 [SMF] M636.89.2
Created: Fadal Format 1 [SMF] M636.89.3
For: Sanders Machine
Changes made per: Matt Finley
Added Literal '01' in Toolpath to correct invalid Sub calls
Customer requires to exit to ZCP1 between repeat patterns to clear clamps
Added *** WARNING *** in UtilityData to caution user that whilst using repeats,
This post will output clearance plane moves NOT seen in Virtuals cut-part rendering
Added Rapid ZCP2 to AutoCycCutSub1 and ZonlyRepAutoCycle
Added Boolean to RapidC ZCP1 in AutoCycCutSub2 and ZonlyRepAutoCycle
Charles Winston}

{8/26/97,
Initial: Fadal Format 1 [SMF] M636.89.3
Created: Fadal Format 1 [SMF] M636.89.4
For: Sanders Machine
Made output of Speed unconditional in SameTool when doing a program stop,
moved turning on of CRC to Z move into part and turning off of CRC to move to ZCP3,
modified fStuff to output WFO at same tool when doing a program stop,
MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '#####^##0;.'
#5 = '####.####;0.'
#6 = '########;0'
#7 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,4)
FORMAT(ToolDiameter#,5)
FORMAT(Program#,6
FORMAT(Operation#,6)
FORMAT(Tool#,6
FORMAT(NewWFO#,6)
FORMAT(Parts#,6)
FORMAT(CallMasterNum#,7)
FORMAT(TLDia#,2)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLab '* SUB NUMBER: ' Program# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1') {restore scale for comments}
IF OperationIDComment?
SeqLab '* OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
SeqLab '* ' OperationComment$ EOL
END
IF WorkGroupComment?
SeqLab '* ' WorkGroupComment$ EOL
END
IF ToolComment?
SeqLab '* ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab Feed ZIn FeedEnt EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqLab SubIDF EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLab '* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLab CallLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
RapidC ZCP3C
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLab Preset ShiftR EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftR EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EACHWFO
SeqLab AbsOrInc Rapid StrtPos SetWFO EOL
SeqLab CallLab OnePart EOL
IncWFO
NEXTWFO
ELSE
SeqLab CallLab Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLab EndSub EOL
CloseSub
ELSE
SeqLab Preset ShiftP EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftP EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLab AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLab DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLab MoveSXYC EOL
SeqLab CallLab '01' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLab DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqLab DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqLab DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLab DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc ArcFeedC EOL
DecelMove2
END
SeqLab FormatArc DecelFeed EOL
ELSE
SeqLab FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

fStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqLab 'E' NewWFO# EOL
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
SeqLab 'E' NewWFO# EOL
END
ELSE
IF LAST ProgStop?
SeqLab 'E' NewWFO# EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab Rapid ZCP2 EOL
SeqLab IncValue EOL
SeqLab StrtPosC EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLab AbsOrInc EOL {.69 removed RapidC}
ELSE
IF Repeats? AND NOT FeedConnect? AND ZShiftOnly?
SeqLab AbsOrInc RapidC ZCP2 EOL
ELSE
SeqLab AbsOrInc RapidC ZCP1 EOL
END
END
SeqLab EndSub EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLab AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
SetPass1 {for correct Z's}
SeqLab Rapid ZCP2 EOL
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Feed IncValue StrtPosC EOL
SeqLab AbsOrInc
ELSE
SeqLab Feed
END
ELSE
SeqLab Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLab AbsOrInc ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLab Rapid ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab CallLab '01' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FIFO?
SeqC Feed ZCP1 FeedEnt EOL
ELSE
SeqC Rapid ZCP1 EOL
END
SeqLab EndSub EOL
CloseSub
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab Connect StrtPos EOL
END
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusIncC EOL {can't call for cycle =1}
{.69 added Rapid, reads better}
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab RapidC ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
SeqLab CallLab '01' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50') {?}
SetMaxRPM('15000')
SetMaxFeed('500') {?}
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' ' EOL
' *** CAUTION ***' EOL
' ' EOL
' When using Repeat Patterns in Milling' EOL
' This post will output clearance plane moves' EOL
' NOT seen in Virtuals cut-part rendering' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
SeqLab 'O' Program#
IF UseComments? AND ProgramNameComment?
'* ' ProgramName$
END
EOL
SetProgNum('0')
IF UseComments?
IF ProgramComment?
SeqLab '* ' ProgramComment$ EOL
END
IF FormatNameComment?
SeqLab '* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
SeqLab '* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
SeqLab '* OUTPUT IN ' MoveType$ ' INCHES ' EOL
END
IF PartsComment?
SeqLab '* PARTS PROGRAMMED: ' Parts# EOL
END
EachTool {tool loop to give a list of tools in program header}
SeqLab '( TOOL ' TLNum# ': ' TLToolComment$ ' )' EOL
NextTool
EOL
END
IF ToolChangeAtHome?
SetHome
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SeqLab Speed SpinOn EOL
IF StartToolComment?
SeqLab '* FIRST TOOL IN SPINDLE' EOL
END
SeqLab Plane AbsOrInc Rapid StrtPos fStuff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab 'M5M9' EOL
SeqLab 'G0G49Z0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLab AbsOrInc Rapid Home
END
IF LAST ProgStop?
SeqLab 'M00' EOL
ELSE
SeqLab ProgStop EOL
END

{Start new Operation}

SeqLab OpToolID ToolChng EOL
DoOpComments
DoPostScript
SeqLab Speed SpinOn EOL
SeqLab Plane AbsOrInc Rapid StrtPos fStuff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab 'G0G49Z0' CoolOff SpinOff 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqLab Speed SpinOn EOL
SeqLab Plane AbsOrInc Rapid StrtPos fStuff EOL
SeqLab OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqLab 'M5M9' EOL
SeqLab 'G0G49Z0' EOL
SeqLab SpeedC EOL
SeqLab PlaneC AbsOrInc Rapid StrtPos fStuff EOL
SeqLab OfstOn EOL
ELSE
{Start new Operation}

GetStartOfSameTool
SeqLab SpeedC EOL
SeqLab PlaneC AbsOrInc Rapid StrtPos EOL
END
IF LAST CoolOff? AND NOT CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLab ZCP2C EOL
SeqLab 'G8' EOL
SeqLab 'G1F50.' EOL
SeqLab CRCOnC EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLab RapidC CRCOffC ZCP3C EOL
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLab AbsOrInc Rapid StrtPos fStuff EOL
END
GetCycle
IF Tap?
SeqLab 'M49' EOL
END
SeqLab Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqLab 'L' CallMasterNum# '01' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLab CallLab OnePart EOL
StartSub
ToolPath
SeqLab EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
IF Tap?
SeqLab 'G80M48' EOL
ELSE
SeqLab 'G80' EOL
END
IF Repeats?
FinishSubG92
END
END
END
NEXTOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab 'M5M9' EOL
SeqLab 'G0G49Z0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLab AbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab 'G90G0X0Y0E0' EOL
SeqLab PreTool ToolChng EOL
SeqLab EOP EOL
EndSubs
Post
EOR EOL
Close
Reseq
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'* FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'* FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'* FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END