{Change Comments ***********************************************************}

{3/1/90, Updated to Version 3.2 per Fanuc 6M M001.70 Format, DWB}

{4/23/90
Copied & modified: Fanuc 10M Kit M028.70
For: Graziano Machining
Use operation numbers for min seq numbers in main and in sub.
Change colon to dash in comments.
CoolOn on same line as OfstOn.
Added to SpinOff line.
ProgStop and UnTool at end of prog.
Added FIRST modifier to end of prog for home position.
Fix connect to StrPos in ZonlyRep
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{9/28/90, Changed CRCOffC to CRCOff in NewTool.
Add CheckSeq call in SameTool if MultipleParts to get # before comments, JR}

{6/14/91
Modified: Fanuc 10M Kit [GM] M303.72
Modified SameTool ops to output CheckSeq reqardless of MP condition
Updated to Version 4.0 per Fanuc 6M M001.80 Format
KLM}

{03/26/92
Modified: Fanuc 10M Kit [GM] M303.73
Changed the form/prog number to M303.80 (miss numbered)
Minor changes.
Kim Michelman}

{03/26/92
Modified: Fanuc 10M Kit [GM] M303.80
For: Graziano
Added the PreTool after the ToolChng.
Deleted the CheckSeq and replaced with SeqC.
Added AbsOrInc Rapid to the SpinOff line in the ELSE in the IF ToolChangeAtHome? boolean
per version .72 for Ricardo. Changed to SpinOff on a line by itself in update, and prefers to
call the AbsOrInc Rapid with the Spinoff if not going home. *Do not change back in future updates.
Moved the Seq Plane 'G80' CRCOffC EOL after the comments in NewTool.
Kim Michelman}

{09/05/92
Copied Fanuc 10M Kit [GM] M303.73
Renamed to Fadal Format 2 [BM] M510.81.3 and modified to ReSequence.
Minor changes to start up and end arrangements.
KC}

{01/27/93
Corrected, AbsValue at two places in WFOStuff.
KC}

{04/23/93
Changed Retag command to Reseq.
KC}

{07/22/93
Copied Fadal Format 2 [GM] M510.81.3
Renamed to Fadal Format 2 [E] M585.81.2
Add G8 to milling ops.
Change fixture offsets from G54/G59 to E1/E24.
Cancel CRC in XY plane. [ckCRC]
KC}

{09/07/93
Copied Fadal Format 2 [E] M585.81.2
Renamed to Fadal Format 2 [G85E] M---.--.-
Uses G85 as tapping cycle together with M49 [Pots disabled] & M48 [Pots enabled]
Feeds down and up with speed and feed override switches disabled. Used with Tapmatic NCR series.
Removed 'DrillCP' and 'RapidC ZCP3C' from the 'IF Drilling?' commands.
Add SpinOff to IncValue OfstOff blocks.
Changed #6 format to add trailing 0's.
KC}

{* 11/3/93 [cwh]
Modeified: Fadal 2 [G85E] M602.81.6
To: Fadal 2 [G85E] M602.81.7
For: Gibbs and Associates

Modified the form so that it could be used with the 32MP and 32MPOL
versions of Catalyst ( Virtual ).
*}

{3/3/94
Add SeqLab to PostSDcript line in 'DoPostScript'.
KC}

{4/12/94
Minor clean up. Move Rapid, Abs., WFO's to Plane line.
KC}

{4/15/94
Uncheck 'Allow R-Format Arcs' boolean. (Caused mixed output in programs input in metric).
KC}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{12/11/97
Initial: Fadal 2 [G85E] M602.89
Created: Fadal 2 [G85E] M602.89.1
ForUser: Lopardo Mfg Co
Develop: ComPost2 1.1b3, Virtual 4.21.21
Comment: Added Rigid tapping per fax and conversation with Robert Shoemaker.
Jim Radcliffe}

{02/13/98,
Initial: Fadal 2 [G85E] M602.89.1
Created: Fadal 2 [G85E] M602.89.2
For: Lopardo Mfg Co
Changed Sub output to Lxxx calls instead of M98P calls.
In Form: Moved Sub-routines to beginning of program.
In Form: Changed M30 at end of program to M2.
Added line numbers to sub comments.
Moved SpinOff from OfstOff line to CoolOff line in NewTool and End of Prog.
Changed End of All Subs in form to M30. Changed Return from Sub in form to M17.
Added the sub-routine doEndSubs. This sub-routine will create the last sub-program
in the program, output a literal M30, and then close the sub-routine. It will
only create this sub-program if one sub-program has already been created, using Flag('4').
Changed all occurances of OnePart to '01'.
Deleted CRCOffC in IF LineFeat? and IF RapidFeat? in ToolPath.
Added boolean to WFOStuff so it will output a WFO if the previous operation had a progstop.
Deleted WFOStuff from GetStartOfSameTool.
Added WFOStuff to StartPos lines in SameTool.
Added ckCRC to ZonlyRep, ZonlyRepAutoCycle, and Milling sub-routines so that 'G1F43F50.D' will be
output before Z depth at beginning toolpath.
Moved SpinOn and Speed to line before StartPos in SameTool.
CDH}

{02/24/98,
Initial: Fadal Format 2 [LM] MV11.89.1
Created: Fadal Format 2 [LM] MV11.89.2
For: Lopardo Mfg.
Deleted Drill sub-routine calls.
Moved literal 'G84.2' call from IF Drilling to FirstOp, NewTool, and SameTool before OfstOn call.
CDH}

{04/09/98,
Initial: Fadal Format 2 [LM] MV11.89.2
Created: Fadal Format 2 [LM] MV11.89.3
For: Lopardo Mfg.

Changes to Prog:
1) doEndSub: Made sequence number non-conditional.
2) IF Drilling: Added IF PosApproach boolean to output 'M46' and 'M47'.
CDH}

{5/27/98
Initial: Fadal Format 2 [LM] MV11.89.3
Created: Fadal Format 2 [NM] Mxxx.89
ForUser: Norco Mfg
Control: Fadal
Machine: Fadal
Develop: ComPost2 1.1b3, Virtual Gibbs 4.24
Comment: New processor per marked up readout and conversation with Kurtis Hess 253-872-3634
Changed to R format arcs up 180 degrees then R- to 359 degrees.
Changed SubComment to ToolTypeComment and moved to same sine as Sub ID.
Changed IncValue OfstOff (G91G20Z0) to OfstOff (G49Z0).
Added empty line to begin tools and subs.
Added empty line to end tools and subs.
Deleted G8 from milling ops.
Changed CRC handling to standard stuff.
Deleted ckCRC sub and calls.
Added CRC handling per Fanuc 6M M001ż
updated ToolPath, FinishSub1, AutoCycCutSub2 & IF Milling?
calling CRCOffC after Z out move
Moved StrtPos to WFOStuff line.
Added optional stop, move to machine home and UnTool to end of program.
Comment: Other changes to correct or clean up.
Cleaned up 'G84.2' calls.
Cleaned Up WFOStuff sub and calls.
Changed output of EndSub from M30 to M17.
Changed output of EndSubs from M17 to M30.
Deleted doEndSub sub and replaced doEndSub call with EndSubs.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '####^##0;'
#7 = '00'
#8 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6)
FORMAT(Recall#,7)
FORMAT(RapidF#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( TOOL ' Tool# '- ' ToolDiameter# ' ' ToolType$ ' )'
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '( OPERATION ' Operation# '- ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLab '( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLab '( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLab '( TOOL ' Tool# '- ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLab '( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

CheckSeq:
IF MinimizeSequencing?
'N' Operation#
ELSE
SeqLab
END
RETURN

EntryMove:
IF FeedEntry?
SeqLab FeedC ZIn FeedEnt EOL
ELSE
SeqLab RapidC ZIn RapidF# EOL { RapidF# Forces FeedRate }
END
RETURN

StartSub:
OpenSub
SeqLab ' ' EOL
SeqLab SubIDF DoSubComment EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachRep
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextRep
SeqLab CallLab Recall# Num#('10') EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLab
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
SeqLab CRCOffC EOL
RETURN

FinishSubG92: {part 2}
SeqLab Preset ShiftRC EOL
SeqLab EndSub EOL
SeqLab ' ' EOL
CloseSub
SeqLab Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqLab Rapid StrtPos SetWFO EOL
END
SeqLab CallLab '01' EOL
IncWFO
NextWFO {simple NextPart}
ELSE
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachPart
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextPart
SeqLab CallLab Recall# Num#('10') EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLab EndSub EOL
SeqLab ' ' EOL
CloseSub
SeqLab AbsValue WFO1 EOL
ELSE
SeqLab Preset ShiftPC EOL
SeqLab EndSub EOL
SeqLab ' ' EOL
CloseSub
SeqLab Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLab AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLab MoveSXYC EOL
SeqLab CallLab '01' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLab DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqLab DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqLab DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc ArcFeedC EOL
DecelMove2
END
SeqLab FormatArc DecelFeed EOL
ELSE
SeqLab FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
'E' NewWFO#
END
ELSE
IF NOT SameTool? OR IF LAST ProgStop?
IF NeedWFO1?
'E' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLab AbsOrInc CRCOffC EOL
ELSE
SeqLab AbsOrInc
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
SeqLab CRCOffC EOL
END
SeqLab EndSub EOL
SeqLab ' ' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLab AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab FeedC IncValue StrtPosC EOL
SeqLab AbsOrInc
ELSE
SeqLab FeedC
END
ELSE
SeqLab FeedC
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLab AbsOrInc ZCP2PlusInc EOL
SeqLab FeedC ZInPlusInc FeedEnt EOL
ELSE
SeqLab AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLab Rapid ZCP2PlusInc EOL
SeqLab FeedC ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLab FeedC ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab CallLab '01' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
SeqLab Rapid ZCP2 EOL {.69}
END {.69}
SeqLab EndSub EOL
SeqLab ' ' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLab CallLab '01' EOL
NextCycle
StartSub
SeqLab EOL
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab EndSub EOL
SeqLab ' ' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
SeqLab ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
SeqLab '( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLab '( FORMAT- ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLab '( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLab '( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqLab '( PARTS PROGRAMMED- ' Parts# ' )' EOL
END
IF StartToolComment?
SeqLab '( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab ' ' EOL
SeqLab OpToolID ToolChng EOL
DoOpComments EOL
DoPostScript
CheckPass
SeqLab Rapid Plane CRCOff DrillOff AbsOrInc StrtPos WFOStuff EOL
IF Drilling? AND RigidTap?
SeqLab 'G84.2' EOL
ELSE
SeqLab Speed SpinOn EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqLab StrtPos EOL
END
SeqLab OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab CoolOff SpinOff EOL
SeqLab OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLab AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqLab 'M00' EOL
ELSE
SeqLab ProgStop EOL
END
SeqLab ' ' EOL

{Start new Operation}

SeqLab ' ' EOL
SeqLab OpToolID ToolChng EOL
DoOpComments EOL
DoPostScript
CheckPass
SeqLab Rapid Plane CRCOff DrillOff AbsOrInc StrtPos WFOStuff EOL
IF Drilling? AND RigidTap?
SeqLab 'G84.2' EOL
ELSE
SeqLab Speed SpinOn EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqLab StrtPos EOL
END
SeqLab OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab CoolOff EOL
SeqLab OfstOff SpinOff EOL
SeqLab 'M00' EOL

{Start new Operation}

GetStartOfSameTool
IF Drilling? AND RigidTap?
SeqLab 'G84.2' EOL
ELSE
SeqLab Speed SpinOn EOL
END
SeqLab Rapid PlaneC StrtPos WFOStuff EOL
SeqLab OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab CoolOff EOL
END
IF NewToolOffset?
SeqLab OfstOff SpinOff EOL

{Start new Operation}

GetStartOfSameTool
IF Drilling? AND RigidTap?
SeqLab 'G84.2' EOL
ELSE
SeqLab SpeedC EOL
END
SeqLab Rapid PlaneC StrtPos WFOStuff EOL
SeqLab OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
IF Drilling? AND RigidTap?
SeqLab 'G84.2' EOL
ELSE
SeqLab SpeedC EOL
END
SeqLab Rapid PlaneC StrtPos WFOStuff EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLab CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab ZCP3C EOL
ELSE
IF FIFO?
SeqLab FeedC ZCP3C FeedEntC EOL
ELSE
SeqLab RapidC ZCP3C EOL
END
SeqLab CRCOffC EOL
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLab AbsOrInc Rapid StrtPos EOL
END
IF PosApproach?
SeqLabC 'M46' EOL
END
GetCycle
IF Tap? AND NOT RigidTap?
SeqLab 'M49' EOL
END
SeqLab
IF RigidTap?
'G84.1'
ELSE
Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF RigidTap?
Speed
END
FeedEnt EOL
TrackZNO# FIRST SPZ#
ToolPath
SetDrillEndOpZ
IF Tap? AND NOT RigidTap?
SeqLab 'G80M48' EOL
ELSE
SeqLab 'G80' EOL
END
IF PosApproach?
SeqLabC 'M47' EOL
END
SeqLab RapidC ZCP3C EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab CoolOff SpinOff EOL
SeqLab OfstOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLab AbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqLab 'M00' EOL
ELSE
SeqLab ProgStop EOL
END
SeqLab ' ' EOL
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab Rapid AbsValue 'X0.Y0.E0' EOL
SeqLab UnTool ToolChng EOL
SeqLab EOP EOL
SeqLab EndSubs EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
Reseq
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH- ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH- ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH- ' FileMeters# ' METERS )' EOL
END
Close
END