{Change Comments ***********************************************************}

{2/7/90, Updated to Version 3.2 per Fanuc 6M M001.70 Format, DWB}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{8/10/90, Updated: Fanuc 3M M010.71 to .74 format, JR}

{4/3/91
Modified: Fanuc 3M M010.74
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
NOTE: v.79 Not tested.
DWB}

{8/13/93
Modified: Fanuc 3M M010.79
For: Pete Jackson
Added G98 to Drill From Clearance Plane 1 in Composts Commands 5 Dialog.
Added G99 to Drill From Clearance Plane 2 in Composts Commands 5 Dialog.
DWB}

{9/27/96, updated to .13 format per Fanuc 6M M001.13.1, MPK}

{5/4/98,
Initial : Fanuc 3M M010.13
Created: Fanuc 3M Tree [HC] MV72.13
Customer: Harris Corp (Texas Offline), Duane Smith or Carlos 210/561-7300

**** CUSTOM SUPPORT - DO NOT GIVE THIS POST TO OTHER CUSTOMERS ****
**** WITHOUT CHECKING THE OUTPUT FOR SINGLE AND MULI PART SUPPORT ****

Changes to "Prog":

1. Changes to InitOp and FirstOp subs to match the customer output.
2. Changes to NewToolOp subs to match the customer output.
3. Changes to SameToolOp subs to match the customer output.
4. Changes to End subs to match the customer output.
5. Added SetProgNum('8000').
6. Changed motions to Tool Change to be included in the customer's P7000 sub.
7. Changed program ID address from O to : and added a space line.
8. Added #8 format and FORMAT for HomeX# and HomeY#.
9. Added IF WorkFixtureOffsets? check and output warning.
10. In MP1ToollAllPfu sub, added OfstOn motion after OpenMP and OfstOff before CloseMP.
Also Moved OpenMP one step down and CloseMP one step up.
11. In MP1ToollAllPXcp sub, moved OpenMP one step down (the Z-axis moves 1st outside
the sub and the X & Y inside the sub).
JHE}


{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '0000'
#8 = '*####.####;0.' {Added - JHE}

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(Program#,7)
FORMAT(HomeX#,8) {Added - JHE}
FORMAT(HomeY#,8) {Added - JHE}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
' ' EOL {Added space line - JHE}
':' Program# EOL {Changed from SubID - JHE}
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall RepLab RepCycs Sub3M EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
SeqC SubCall RepLab Parts Sub3M EOL
StartSub
RETURN

CloseMP:
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
SetFlag('5')
END
END
RETURN

FormatLine:
DoAbsOrInc ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
IF Flag?('5')
SetFlagF('5')
CRCOffsetC
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall RepLab '1' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC FormatLine DecelFeed ckCRCNum EOL
ELSE
SeqC FormatLine FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FormatArc ArcFeedC CRCOffsetC EOL
DecelMove2
END
SeqC CRCOnC FormatArc DecelFeed CRCOffsetC EOL
ELSE
SeqC CRCOnC FormatArc ArcFeedC CRCOffsetC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
SeqC StrtPosC EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall RepLab '1' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {added Rapid, reads better} {changed to RapidC, reads better}
END
END
SeqC SubCall RepLab '1' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('5') {True = need CRCOffset }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall 'P' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

WFOStuff:
RETURN

InitOp:
EOR EOL
':' Program# {Changed from ProgID1 - JHE}
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
SetProgNum('8000') {Added - JHE}
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
SeqC Rapid Plane CRCOff 'G49G80' AbsValue 'G94G99' EOL
{Added Rapid AbsValue G49 G94 G99 - JHE}
SeqC 'M98P7000' EOL {Added this line - JHE}
{:7000 (Return Home)}
{G92X0.Y0.M9}
{G0M5}
{G28Z0.H0}
{G28X0.Y0.}
{G92X0.Y0.Z0.}
{M99}
RETURN

FirstOp1:
SeqC OpToolID ToolChng EOL
{SeqC ToolChng EOL} {Moved up - JHE}
{SeqC Preset 'Z0' EOL} {Removed - JHE}
DoOpComments
DoPostScript
RETURN

FirstOp2:
CheckPass
{SeqC Speed SpinOn EOL} {Moved to motion block - JHE}
SeqC Rapid AbsOrInc 'X' HomeX# 'Y' HomeY# Speed SpinOn EOL {Added this lines - JHE}
RETURN

FirstOp3:
SeqC OfstOn CoolOn EOL
SeqC Preset 'X0.Y0.' EOL {Added this lines - JHE}
RETURN

FirstOp4:
SeqC Rapid StrtPos Speed EOL {Moved Z motion before this line - JHE}
{SeqC CoolOn EOL} {Moved up - JHE}
RETURN

NewToolOp1:
{SeqC CoolOff EOL} {Removed - JHE}
{SeqC IncValue OfstOff 'H0' CoolOff EOL} {Removed - JHE}
SeqC 'M98P7000' EOL {Added this line - JHE}
{:7000 (Return Home)}
{G92X0.Y0.M9}
{G0M5}
{G28Z0.H0}
{G28X0.Y0.}
{G92X0.Y0.Z0.}
{M99}
RETURN

NewToolOp2:
DoEndOpPS
{IF ToolChangeAtHome?} {Removed, always go home with P7000 - JHE}
{SeqC AbsOrInc Rapid Home SpinOff EOL}
{ELSE}
{SeqC AbsValue SpinOff EOL} {Removed - JHE}
{END}
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqC OpToolID ToolChng EOL
{SeqC ToolChng EOL} {Moved up - JHE}
{SeqC Preset 'Z0' EOL} {Removed - JHE}
{SeqC Plane 'G80' CRCOffC EOL} {Removed - JHE}
DoOpComments
DoPostScript
RETURN

NewToolOp4:
CheckPass
{SeqC Speed SpinOn EOL} {Moved to motion block - JHE}
SeqC Rapid AbsOrInc 'X' HomeX# 'Y' HomeY# Speed SpinOn EOL {Added this lines - JHE}
RETURN

NewToolOp5:
SeqC PlaneC OfstOn CoolOn EOL {Added PlaneC - JHE}
SeqC Preset 'X0.Y0.' EOL {Added this lines - JHE}
RETURN

NewToolOp6:
SeqC Rapid StrtPos Speed EOL {Moved Z motion before this line - JHE}
{SeqC CoolOn EOL} {Moved up - JHE}
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
{SeqC CoolOff EOL} {Moved down - JHE}
SeqC IncValue OfstOff 'H0' CoolOff EOL {Added CoolOff & H0 - JHE}
SeqC AbsValue SpinOff EOL {Added AbsValue - JHE}
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC IncValue OfstOff 'H0' EOL {Added 'H0' - JHE}
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqC Rapid PlaneC AbsOrInc StrtPos SpeedC SpinOn EOL
SeqC OfstOn CoolOn EOL
{SeqC CoolOn EOL} {Moved up - JHE}
ELSE
SeqC Rapid PlaneC AbsOrInc StrtPos SpeedC EOL
IF NewToolOffset?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
{SeqC CoolOff EOL} {Reoved - JHE}
{SeqC IncValue OfstOff EOL} {Removed - JHE}
SeqC 'M98P7000' EOL {Added this line - JHE}
RETURN

End2:
DoEndOpPS
{IF FIRST ToolChangeAtHome?} {Removed, always go home with P7000 - JHE}
{SeqC AbsOrInc Rapid FirstHome SpinOff EOL}
{ELSE}
{SeqC SpinOff EOL} {Removed - JHE}
{END}
IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL {Added - JHE}
END
RETURN

End3:
{'/G91G28X0Y0' EOL} {Removed - JHE}
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
WFOStuff
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp3
OpenMP {Moved one step down - JHE}
FirstOp4
SeqC OfstOn EOL {Added this line - JHE}
ELSE
IF NewTool?
SeqC RapidC IncValue OfstOff EOL {Added this line - JHE}
SeqC AbsOrInc EOL {Added this line - JHE}
CloseMP {Moved one step up - JHE}
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
OpenMP {Moved one step down - JHE}
NewToolOp6
SeqC OfstOn EOL {Added this line - JHE}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
SeqC RapidC IncValue OfstOff EOL {Added this line - JHE}
SeqC AbsOrInc EOL {Added this line - JHE}
CloseMP {Moved one step up - JHE}
End1 {End of program}
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp3 {Added - JHE}
OpenMP {Moved one step down - JHE}
FirstOp4
{FirstOp3} {Removed - JHE}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5 {Added - JHE}
OpenMP {Moved one step down - JHE}
NewToolOp6
{NewToolOp5} {Removed - JHE}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
WFOStuff
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ************************}

ProgStart {setup and initializations}

IF MultipleParts?
IF WorkFixtureOffsets? {Added this check and warning - JHE}
' ' EOL
'( warning: this post does not support work fixtures option. )' EOL
'( select equally spaced option. )' EOL
' ' EOL
ELSE {implies equally spaced}
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
END
ELSE
NoMPs
END