{5/12/89
Copied & modified; Fanuc 3000C M013.53, for Grand Valley.
Machine is a Hitachi Seiki 60" Horizantal with Fanuc 3000C control.
Change G43 G46 for OfstOn.
Change G28 to G46 for OfstOff and literal 'Z400000' with tool offset.
Move tool change to same line as tool call. Add PreTool.
If OptionalStops, SameTool like NewTool exept for tool change.
Add SetHome to beginnig of prog if ToolChangeAtHome.
Change Home at end of prog to FirstHome. Delete RunTimeComments.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{1/16/91, Updated "Fanuc 3000C HS M197.56" to ".76.1", JR}

{1/16/91
Copied & modified: Fanuc 3000C HS M197.76.1
For: Norco
Added to program start block.
Added G45 origin blocks.
Move Speed & tool change to StrtPos line.
Delete PreTool.
Move coolant to OfstOn Line.
OfstOn in Incremental.
Preset ZCP1 after OfstOn, move SpinOn to this line.
Change OfstOn code to G45.
Add AbsOrInc to ZCP2 in line milling & DrillCP line in drilling.
Delete saftey start G code block from NewTool.
Add M19.
Jim Radcliffe}

{9/10/91, Updated Fanuc 3000C HS [NI] M384.76.1 to .80 format, JR}
{8/18/94, Updated Fanuc 3000C HS [NI] M384.80 to .85 format per Fanuc 6M M001.85.01.02, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{6/26/96, created .13 version, but did not modify CRC handling. MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###^##0'
#3 = '*###^##0'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '###^###0'
#8 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Tag#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Parts#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6)
FORMAT(CRCNormalVectorX#,7)
FORMAT(CRCNormalVectorY#,7)
FORMAT(ToolOffset#,8)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

CSAngleA:
IF AAxisAvail?
IF WFOCS?
'A0.'
ELSE
'A' CSOffsetA#
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
IF WFOCS?
'B0.'
ELSE
'B' CSOffsetB#
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

PSInit:
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
SeqLab {drop unconditional for proper tagging}
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC 'M98Pł' Tag# 'R' Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
{ .85 update, left CRCOff stuff here as a just in case }
{ it should output here unless the last tool path feature was an arc! }
IF FeedConnect?
SeqLabC CRCOffC EOL
ELSE
IF NOT FeedConnect?
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
END
SeqLabC CRCOffC
IF NOT EmptyLine?
LastFeatExtend
END
EOL
END
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
TagInc
SeqLabC 'M98Pł' Tag# 'R' Parts# EOL
StartSub
RETURN

CloseMP:
SeqLabC Preset ShiftPC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftPC EOL
RETURN

SubCSMP:
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC 'M98Pł' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqLabC CRCOffC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC CRCOnC
IF EmptyLine? {no CRC used or its already activated}
DoAbsOrInc RapidC MoveXYZC EOL
ELSE {CRC needed and not yet activated, need vectors & offset}
DoAbsOrInc RapidC MoveXYZC 'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst EOL
END
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqLabC CRCOffC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC CRCOnC
IF EmptyLine? {no CRC used or its already activated}
DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE {CRC needed and not yet activated, need vectors & offset}
DoAbsOrInc FeedC MoveXYZC 'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst FeedRateC EOL
END
DecelMove2
END
SeqLabC CRCOnC
IF EmptyLine? {no CRC used or its already activated}
DoAbsOrInc FeedC MoveXYZC DecelFeed EOL
ELSE {CRC needed and not yet activated, need vectors & offset}
DoAbsOrInc FeedC MoveXYZC 'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst DecelFeed EOL
END
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC CRCOnC
IF EmptyLine? {no CRC used or its already activated}
DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE {CRC needed and not yet activated, need vectors & offset}
DoAbsOrInc FeedC MoveXYZC 'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst FeedRateC EOL
END
END
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC EOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC 'M98Pł' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLabC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLabC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqLabC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLabC 'M98Pł' Tag# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
TagInit
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50') {?}
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('0')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
{
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
}
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('0') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
{
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
}
END
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLabC AbsOrInc ZCP2C EOL
IF Repeats?
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END
ELSE
G92Sub
END
ELSE
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
SeqLabC CRCOffC
IF NOT EmptyLine?
LastFeatExtend
END
EOL
ELSE
IF Drilling?
SeqLabC AbsOrInc DrillCP EOL
IF Repeats?
TagInc
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
GetCycle
SeqLabC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqLabC 'M98Pł' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterTag
SeqLabC 'M98Pł' Tag# EOL
StartSub
ToolPath
SeqLabC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC DrillOff EOL
SeqLabC RapidC ZCP3C EOL
IF Repeats?
FinishSubG92
END
SeqLabC RapidC ZCP3C EOL
END
END
RETURN

DefaultWFO:
{Post does not support WFOs}
RETURN

DoCSG52:
{Post does not support G52s}
RETURN

DefaultCSG52:
{Post does not support G52s}
RETURN

DefaultCSWFO:
{Post does not support WFOs}
RETURN

WFOStuff:
{Post does not support WFOs}
RETURN

InitOp:
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
IF MultipleParts? AND WorkFixtureOffsets?
'( This Procesor does not Support Work Fixture Offsets! )' EOL
'( The Multiple Parts are being processed with the Equally Spaced )' EOL
'( Offsets values! I suggest you make sure that they are set properly! )' EOL
END
IF ToolChangeAtHome?
SetHome
END
OpenSub
RestoreScale
RETURN

FirstOp1:
SeqLab Plane DrillOff CRCOff 'G98' IncValue Rapid EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
SeqLabC 'G45X-0H30' EOL
SeqLabC 'G45Y-0H31' EOL
SeqLabC Preset 'X0Y0' EOL
CheckPass
SeqLabC AbsOrInc Rapid StrtPos Speed CSAngleA CSAngleB OpToolID ToolChng EOL
RETURN

FirstOp3:
RETURN

FirstOp4:
SeqLabC IncValue OfstOn 'Z-0' CoolOn EOL
SeqLabC Preset SetAbs ZCP1 SetAbsOrInc SpinOn EOL
RETURN

NewToolOp1:
SeqLabC CoolOff EOL
SeqLabC IncValue OfstOff 'Z-0' LastToolOffset EOL
RETURN

NewToolOp2:
SeqLabC 'M19' EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3:
DoOpComments
DoPostScript
CheckPass
SeqLab Plane AbsOrInc Rapid StrtPos Speed CSAngleA CSAngleB OpToolID ToolChng EOL
RETURN

NewToolOp4:
RETURN

NewToolOp5:
RETURN

NewToolOp6:
SeqLabC IncValue OfstOn 'Z-0' CoolOn EOL
SeqLabC Preset SetAbs ZCP1 SetAbsOrInc SpinOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC CoolOff EOL
SeqLabC IncValue OfstOff 'Z-0' LastToolOffset SpinOff EOL
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
SeqLabC 'M00' EOL
ELSE
IF OptionalStops?
SeqLabC CoolOff EOL
SeqLabC IncValue OfstOff 'Z-0' LastToolOffset SpinOff EOL
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
SeqLabC ProgStop EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC IncValue OfstOff 'Z-0' LastToolOffset EOL
END
END
END
RETURN

SameToolOp2:
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3:
IF LAST ProgStop?
SeqLabC Plane AbsOrInc Rapid StrtPos CSAngleA CSAngleB Speed EOL
SeqLabC IncValue OfstOn 'Z-0' CoolOn EOL
SeqLabC Preset SetAbs ZCP1 SetAbsOrInc SpinOn EOL
ELSE
IF OptionalStops?
SeqLabC Plane AbsOrInc Rapid StrtPos CSAngleA CSAngleB Speed EOL
SeqLabC IncValue OfstOn 'Z-0' CoolOn EOL
SeqLabC Preset SetAbs ZCP1 SetAbsOrInc SpinOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB SpeedC EOL
SeqLabC IncValue OfstOn 'Z-0' EOL
SeqLabC Preset SetAbs ZCP1 SetAbsOrInc EOL
ELSE
SeqLabC PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
END
RETURN

End1:
SeqLabC CoolOff EOL
SeqLabC IncValue OfstOff 'Z-0' ToolOfst EOL
RETURN

End2:
SeqLabC 'M19' EOL
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLabC AbsOrInc Rapid FirstHome EOL
END
IF NOT Equal? CSOffsetA# Num#('0') OR NOT Equal? CSOffsetB# Num#('0')
IF AAxisAvail?
SeqC CSAngleA
END
IF BAxisAvail?
SeqC CSAngleB
END
EOL

SeqC 'G92'
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
IF ProgStop?
SeqLabC 'M00' EOL
END
RETURN

End3:
SeqLabC 'M30' EOL
EOR EOL
nullfoot EOL
EOR EOL
Post
EOR EOL
Close
Retag
IF UseComments?
Reopen
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
WFOStuff
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
OpenMP
FirstOp3
SeqLabC AbsOrInc Rapid StrtPos Speed CSAngleA CSAngleB EOL
FirstOp4
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
OpenMP
NewToolOp5
SeqLab Plane AbsOrInc Rapid StrtPos Speed CSAngleA CSAngleB EOL
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp4
OpenMP
FirstOp3 {can't XY position before WFO}
SeqLabC AbsOrInc Rapid StrtPos Speed CSAngleA CSAngleB EOL
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp6
OpenMP
NewToolOp5 {can't XY position before WFO}
SeqLab Plane AbsOrInc Rapid StrtPos Speed CSAngleA CSAngleB EOL
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
WFOStuff
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, top level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END