{Change Comments ***********************************************************}

{11/14/91
Copied & Modified: GE2000 Sharrman M336.81.1
For: Micron Machine
Machine: Burgmaster
Control: GE Mark Century 2000 Model VTC-300
Replaced Post2 at the end of the prog with Post. To enable the sub progs to be in front of the
program.(Boolean is also checked in the form).
Added spaces to the (ID, PROG, ' Program# ').
Moved the OpenSub command in the FirstOp to above the comments, per request.
Changed the 'G71' on the 'G94' line to a 'G70' for the English post.
KM}

{12/9/91
Modified: GE2000 Burgmaster M.80
For: Micron Machine
Deleted all WorkFixtureOffset output, no support on this control.
Deleted values from Form.
Deleted #6 = '00'.
Deleted FORMAT(NewWFO#,6).
Deleted NewWFOF from PSInit.
Deleted WorkFixtureOffset handling for MultipleParts.
Replaced output of WFOStuff with Commented NOTE to developers, and call to same from
FirstOperation, NewTool and SameTool.
Deleted STWFOStuff sub and call to same from SameTool.
Deleted InitWFONum from setup & initializations.
Deleted NewWFO PostScript Comments.
Deleted WFOOff from NewTool, SameTool and end of Prog.
Deleted all handling of TCZ#.
Deleted FORMAT(TCZ#,4).
Deleted Scaling of TCZ# at setup & initializations.
Deleted TCZ# PostScript Comments.
Changed all 'Z' TCZ# with 'Z0.' at NewTool, SameTool and end of Prog.
Replaced all Tagging with NewProg.
Deleted FORMAT(Tag#,5).
Added GetNewProg Sub to suppress NewProg for FIRST Subroutine.
Changed all TagInc with call to GetNewProg Sub.
Changed all occurances Tag# with Program#.
Added literal ' ' in front of all occurances of Program# for all Subroutine output.
Changed 'N?' to 'N' in Form.
Changed all SeqLab(C) with Seq(C) in Prog.
Deleted Retag at end of Prog.
Deleted Redundant SetScale('1') in DoOpComments.
Added logic for output incremental 4thAxis at PSStuff.
Modified PostScript Comments for 4thAxis.
Added call to PSStuff at DoPostScript, and Deleted from FirstOperation, NewTool and SameTool.
Added logic to output Blank Lines between Subroutines, and ToolChange Operations.
Will suppress blank line for FIRST Subroutine, because Subs appear before Main Program.
Will output blank line between final Subroutine and FirstOperation.
Added Save# Num#('1') Program# at FirstOperation to accomplish this.
Changed all literal 'PSUB' to 'GSUB' and added space in front when 'GSUB' is second Parameter of
SubCall.
Added logic to output Primary Axis for all Planes in FormatArc.
Deleted conditionality of Primary Axis and ArcCenters.
Deleted all occurances of CRCOffsetC from StdLine and IF ArcFeat? in ToolPath.
'D' address is also used for Tool Length.
Deleted ResetCRCNum at ToolPath.
Changed all ZCP1 'D81' to OfstOn at FirstOperation, NewTool and SameTool.
Modified GetCoolant Sub to output 'M07' for Mist, 'M36' for ThruSpindle and 'M08' for Flood.
Modified PostScript Comments concerning Coolant output.
Changed SetMaxRPM from ('4200') to ('3000') at setup & initializations.
Changed SetFeed from ('500') to ('400') at setup & initializations.
Changed literal '=' to EOR at FirstOperation.
Deleted literal 'H100999' at FirstOperation.
Changed literal '(GSIB, 06) with ToolChng and moved to OpToolID line at FirstOperation and SameTool.
Deleted PreTool at FirstOperation and SameTool.
Deleted literal 'M38' at FirstOperation and SameTool.
Added literal 'G78' to Canned Drilling Cycle Line IF RetractToCP1? = TRUE.
UnCommented CloseSub at end of Prog.
Changed Post to Post2 at end of Prog.
Added literal ASCII('4') at end of Prog.
This tells control 'End of Transmission.'
DWB}

{11/16/93
Modified GE2000 Burgmaster M.80 to Mark Century 2000MC M---.--.-
Removed tool changes and added MOO at end of each tool.
KC}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.###;0.'
#5 = '########;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(Peck#,4)
FORMAT(Retract#,4)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Repeats#,5)

{Prog Subroutines **********************************************************}

GetNewProg:
IF Flag?('1') { Don't increment the First Sub's Program# }
NewProg
ELSE
SetFlag('1')
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqC '(MSG, SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqC '(MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqC '(MSG, ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC
IF AbsoluteMoves?
'B'
ELSE
'A'
END
FourthDegree# EOL
SeqC 'M70' EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC
IF AbsoluteMoves?
'B'
ELSE
'A'
END
FourthDegree# EOL
SeqC 'M70' EOL
FourthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
IF NotEqual? Program# Recall# Num#('1') { Don't output at First Sub }
' ' EOL
END
SeqC '(ID, GSUB, ' Program# ')' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(MSG, WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC '(GSUB, ' Program# ')' 'P0=' Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedRateC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftR EOL
SeqC '(END, GSUB)' EOL
CloseSub
SeqC Preset UnshiftR EOL
RETURN

OpenMP:
GetNewProg
{ This Post Processor does not support WorkFixtureOffsets }
SeqC '(GSUB, ' Program# ')' 'P0=' Parts# EOL
StartSub
RETURN

CloseMP:
SeqC Preset ShiftP EOL
SeqC '(END, GSUB)' EOL
CloseSub
SeqC Preset UnshiftP EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF ZshiftOnly? AND NoZMoves? AND NOT AutoCycle? { SkipZ set in ZRepOnly, ZMove always = TRUE }
MoveX MoveY
ELSE
IF XYPlane?
MoveX MoveY MoveZC
ELSE
IF XZPlane?
MoveX MoveYC MoveZ
ELSE
IF YZPlane?
MoveXC MoveY MoveZ
END
END
END
END
ArcIJ
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
CRCOnC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC ckCRC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC ckCRC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC '(GSUB, ' Program# ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC CRCOnC FormatArc DecelFeed EOL
ELSE
SeqC CRCOnC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
{ This Post Processor does not support WorkFixtureOffsets }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedRateC
ELSE
RapidC ZCP2
END
END
EOL
SeqC '(END, GSUB)' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
GetNewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
GetNewProg
EachCycle
IF FeedConnect?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC '(GSUB, ' Program# ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedRate EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC '(END, GSUB)' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC '(GSUB, ' Program# ')' EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
SeqC '(END, GSUB)' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetCoolant: { PostScript Options }
IF NOT CoolOff?
IF Mist?
'M07'
ELSE
IF ThruSpin?
'M36'
ELSE
CoolOn
END
END
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('3000')
SetMaxFeed('400')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' FloodCoolat, FCool' EOL
' This is the default coolant condition.' EOL
' This is a non-modal command affecting the current operation only.' EOL
' The Post Processor will output main coolant selection M08.' EOL
' SetFlood, SF' EOL
' This is the default coolant condition.' EOL
' This is a modal command affecting all following operations.' EOL
' The Post Processor will output main coolant selection M08.' EOL
' MistCoolat, MCool' EOL
' This is a non-modal command affecting the current operation only.' EOL
' The Post Processor will output spray coolant selection M07.' EOL
' SetMist, SM' EOL
' This is a modal command affecting all following operations.' EOL
' The Post Processor will output spray coolant selection M07.' EOL
' ThruSpindleCoolant, TSCool' EOL
' This is a non-modal command affecting the current operation only.' EOL
' The Post Processor will output spindle center coolant selection M36.' EOL
' SetThruSpindle, STS' EOL
' This is a modal command affecting all following operations.' EOL
' The Post Processor will output spindle center coolant selection M36.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + B move of the value you specify, if output is Absolute, example B12.5.' EOL
' generates a + A move of the value you specify, if output is Incremental, example A12.5.' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - B move of the value you specify, if output is Absolute, example B-22.5.' EOL
' generates a - A move of the value you specify, if output is Incremental, example A-22.5.' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
Save# Num#('1') Program#
EOR EOL
OpenSub
' ' EOL
SeqC '(ID, PROG, ' Program# ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqC '(MSG, PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqC '(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqC '(MSG, PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqC '(MSG, FIRST TOOL IN SPINDLE )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
SeqC 'G80' EOL
SeqC 'G70' 'G94' EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Plane AbsOrInc Rapid StrtPos Speed SpinOn EOL
SeqC OfstOn EOL
SeqC GetCoolant EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC Rapid StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC Rapid 'Z0.D00' EOL
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC AbsOrInc Rapid Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC 'M00' EOL
END

{Start new Operation}

' ' EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Plane AbsOrInc Rapid StrtPos Speed SpinOn EOL
SeqC OfstOn EOL
SeqC GetCoolant EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC Rapid 'Z0.D00' EOL
SeqC CoolOff EOL
SeqC SpinOff EOL
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC Rapid StrtPos SpeedC SpinOn EOL
SeqC OfstOn EOL
SeqC GetCoolant EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC Rapid 'Z0.D00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC Rapid StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC GetCoolant EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
GetNewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedRateC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
GetNewProg
SeqC '(GSUB, ' Program# ')' 'P0=' Repeats# EOL
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC GetCycle Cycle
IF RetractToCP1? {.81}
'G78'
END
StrtPos ZDepth RLevel
IF Peck?
'P1=' Peck#
IF Dwell?
'P3=' Dwell#
END
IF PeckChipBreaker?
'P4=' Retract#
ELSE
'P4=0' {full out}
END
END
FeedEnt EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC 'G80' EOL
IF Repeats?
FinishSubG92
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC Rapid 'Z0.D00' EOL
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC AbsOrInc Rapid FirstHome SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
SeqC '(END, PROG)' EOL
'' EOL { This is an ASCII(4) End of Transmission for Multiple Loads }
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END