{Change Comments ***********************************************************}

{11/14/91
Modified: Fanuc 10T MS [-] L001.82
For: Gibbs & Associates
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Changed SetAbs to SetAbsOrInc at setup and initializations.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Modified AutoFinish Approach.
DWB}

{4/4/95
Initial: Fanuc 10T MS [-] L001.82ż
ForUser: Envirotech Pump
Control: Fagor 8030 TG
Machine: Mazak
Version: ComPost 4.21.26, ncCAD 4.33, ncCAM 4.33, ncPost 4.33.04
Created new Postprocessor per sample and manual.
Jim Radcliffe}

{
Format: Fagor 8025 TG Lxxx.81.2
5/9/95
Added spaces between all commands
TH}

{
Format: Fagor 8025 TG L342.81.3
5/17/95
Added T00.00 to start and end of prog
Removed CSS stuff from start of prog
Removed preset stuff from start of prog and NewTool?
Removed all coolant commands
TH}

{
Format: Fagor 8025 TG L342.81.4
5/22/95
Changed to NegSideLathe
TH}

{
Format: Fagor 8025 TG L342.81.5
5/31/95
Added ReverseXZArcs to prog start
TH}

{
Format: Fagor 8025 TG L342.81.6
6/15/95
For: Litton
Fixed CSS code in FirstOp
Put coolant commands back in
TH}

{9/7/95, Updated Fagor 8025 TG L342.81.6 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{14/May/97
Original: Fagor 8025 TG L342.85
Created: Fagor 8025 TG L342.85.1
For: Astro Machine
Changes made per: Al Boothe
Corrected CheckOffset: to prevent redundant output of Speed
Charles Winston}

{10/20/97
Updated & Modified: Fagor 8025 TG L342.85.1
Created: Fagor 8025T [VS-] L654.85
For: Viewpoint Signs
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Changes made per Mark Winlund, fax dated 10/14/97 and phone call.
Customer reported that G02/G03 codes were wrong.
Customer requested that G02/G03 be reversed.
Changed ReverseXZArcs to StandardXZArcs at setup and initializations.
Updated for Catalyst v3.35C per Fanuc 10T MS [-] L001.85.02d Format.
Modified output of Speed at CheckOffset sub.
Added additional conditions for output of Speed at CheckOffset sub.
Commented out SpeedC to suppress redundant output of Speed for LAST ProgStop at CheckOffset sub.
Corrected output of G0 only block at end of Manual Thread Cycle.
Added IF LAST ThreadFeat? at ToolPath RapidFeat?
Forces Rapid.
Deleted forced Rapid at ToolPath ThreadFeat.
Added OR LAST Threading? at CheckRapid.
Added OR Threading? at end of Prog.
Correction made on 6/4/97 was causing Virtual files to not output G00 after exiting ToolPath.
Gibbs System files now output Rapid a second time.
Added SetMaxFeed(12700) condition for Metric Files at setup and initializations.
Modified CkCRC sub.
Added missing Address spaces per notes of 5/9/95.
Added space between all occurances of G04 K.
Added space for X and G32 at non-canned Threading AutoFinish.
Added space for G97 S at end of prog.
DWB}

{10/23/97
Copied: Fagor 8025T [VS-] L654.85
Created: Fagor 8025T [VS+] L655.85
For: Viewpoint Signs
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Changes made per Mark Winlund, fax dated 10/14/97 and phone call.
Customer requested positive X output.
Changed NegSideLathe to PosSideLathe at setup and initializations.
DWB}

{11/7/97
Modified: Fagor 8025T [VS+] L655.85
Created: Fagor 8025T [VS+] L655.85.1
For: Viewpoint Signs
Versions: Catalyst v4.21.11(mac)/ComPost2 MSL 68K
Changes made per Mark Winlund of Viewpoint Signs, phone calls, manuals and 00050.VNC file.
Verification made via conversations with Yarek, Waikay and Willie of Fagor.
Customer reported that some blocks were breaking rule that limits number of characters per block.
Manual states that blocks shall contain no more than 43 characters per block.
Changed FORMAT of X Address from ' ####.####;0' to '####.####;0' in Compost2 Default Formats Dialog.
Changed FORMAT of Z Address from ' ####.####;0' to '####.####;0' in Compost2 Default Formats Dialog.
Space was causing leading zeros to be output, in some tests up to 5 leading zeros.
This contributed to exceeding limit.
Broke up ToolTypeComment into two separate blocks at DoOpComments.
Added ELSE EOL condition at end of CheckOffset sub.
Avoids concatanation of Speed, SpinOn and/or CoolOn output with any possible PostScript usage.
Deleted 'FORMAT: ' from FormatNameComment output at FirstOperation.
Customer requested deletion of ASCII(27) at end of output.
Reported that control would not load program until this escape character was removed.
Waikay of Fagor explained that some communications software output this code as part of Protocol
and processor output results in this code being sent twice which the control does not accept.
Customer reported that he is loading via floppy but 286 processor in control massages the program.
Verification of cause has not been established.
Deleted ASCII(27) at end of Prog.
Fagor informed me that Minimize Sequencing is not an option on the 8025 control.
Changed all SeqLabC commands to SeqLab.
DWB}

{11/26/97
Modified: Fagor 8025T [VS+] L655.85.1
Created: Fagor 8025T [VS+] L655.85.2
For: Viewpoint Signs
Versions: Catalyst v4.21.16(mac)/ComPost2 MSL 68K
Changes made per Mark Winlund of Viewpoint Signs and phone call.
Customer reported that a G97 block was not outputting a Line Number.
Fagor 8025T rules require every block to contain an unconditional LineNumber.
Problem was caused by customer changing Speeds at SameTool Operation.
Added IF NOT EmptyLine condition at CheckOffset sub.
Added output of SeqLab when condition is met.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '##.##;0'
#5 = '#.######;0'
#6 = '###0'
#7 = '#'
#8 = '00000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(Program#,8) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab ' ( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLab ' ( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLab ' ( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLab ' ( TOOL ' Tool# ' )' EOL
SeqLab ' ( ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLab ' ( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLab StockOnNoCan XSPC EOL
SeqLab StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLab FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLab StockOnNoCan ZSPC EOL
SeqLab StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLab FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLab ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLab XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLab StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLab ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab CoolOff EOL
END
END
IF NewToolOffset?
SeqLab LOfstOff '.00' EOL
SeqLab OpToolID '.' LatheOffset EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLab Preset MaxRPM EOL
END
IF LAST ProgStop?
CSSOn ' G96' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
CSSOn ' G96' Speed
END
END
ELSE
SeqLab Preset MaxRPM EOL
CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
' G97' Speed
ELSE
IF LAST ProgStop?
' G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
' G97' Speed
END
END
END
END
IF LAST ProgStop?
SeqLab {SpeedC} SpinOn EOL
SeqLab CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLab CoolOn EOL
ELSE
IF NOT EmptyLine?
SeqLab EOL { Needed to avoid concatanation of PostScript Literals for 43 character block limit }
END
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLab SpinOff EOL
SeqLab ' G04 K2.' EOL
SeqLab Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLab ' G04 K' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLab MoveSXYC EOL
ELSE
IF RapidFeat?
IF LAST ThreadFeat?
Rapid
END
SeqLab RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLab CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLab FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLab ' G33' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle? OR LAST Threading?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR Program# EOL
IF UseComments?
IF ProgramNameComment?
SeqLab ' ( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLab ' ( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLab ' ( ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLab ' ( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLab ' ( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLab ' T00.00' EOL
SeqLab OpToolID '.' LatheOffset EOL
SeqLab FeedRate CSSOff
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLab LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLab LAST XOpECDC EOL
END
END
SeqLab LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLab CSSOff ' G97' CalcRPM2 EOL
END
SeqLab NewHome LOfstOff '.00' EOL
IF LAST ProgStop?
SeqLab ' M00' EOL
ELSE
SeqLab ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID '.' LatheOffset SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLab StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLab LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLab LAST XOpECDC EOL
END
SeqLab LAST OpExitZCPC EOL
SeqLab LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLab LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLab LAST OpExitXCPC EOL
END
SeqLab LAST OpExitZCPC EOL
SeqLab XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLab LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLab LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLab LAST XOpECDC EOL
END
SeqLab LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLab CSSOn ' G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLab LCycle
IF ApproachFace?
' Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLab LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ELSE
IF RoughPatternShift?
SeqLab LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLab ' G70' ' PÅ‚' Tag# ' Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Chamfer?
SeqLab ' M23' EOL
END
SeqLab LCycle XatFinZ FinZ XTapAtZ CutMethod ThrdHeight CutDepth ThrdLead ' A' InFeedAngle# EOL
IF AutoFinish?
SeqLab ' G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
IF Chamfer?
SeqLab ' M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLab LCycle ZDepth ' E' FeedIPR# EOL
SeqLab SpinOff EOL
SeqLab ' G04 K2.' EOL
SeqLab Speed InverseSpinOn EOL
SeqLab ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLab LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLab DrillOff EOL
IF AutoFinish?
SeqLab Feed ZDepth EOL
IF Dwell?
SeqLab ' G04 K' Dwell# EOL
END
SeqLab Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLab StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLab RapidC ZOpECPC EOL
ELSE
SeqLab RapidC XOpECDC EOL
END
ApproachSP
SeqLab StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLab RapidC XSPC ZSPC EOL
SeqLab StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLab ' X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLab ' G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLab Rapid XSP EOL
SeqLab ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLab SpinOff EOL
SeqLab ' G04 K2.' EOL
SeqLab Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle? OR Threading?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLab OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLab XOpECDC EOL
END
END
SeqLab OpExitZCPC EOL
DoEndOpPS
SeqLab CoolOff EOL
IF ConstantSurfaceFeed?
SeqLab CSSOff ' G97 S' CalcEPRPM# EOL
END
SeqLab FirstHome ' T00.00' SpinOff EOL
IF ProgStop?
SeqLab ' M00' EOL
END
SeqLab EOP EOL
Post
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
SeqLab ' ( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLab ' ( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLab ' ( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close
Retag