{Change Comments ***********************************************************}

{11/14/91
Modified: Fanuc 10T MS [-] L001.82
For: Gibbs & Associates
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Changed SetAbs to SetAbsOrInc at setup and initializations.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Modified AutoFinish Approach.
DWB}

{4/4/95
Initial: Fanuc 10T MS [-] L001.82ż
ForUser: Envirotech Pump
Control: Fagor 8030 TG
Machine: Mazak
Version: ComPost 4.21.26, ncCAD 4.33, ncCAM 4.33, ncPost 4.33.04
Created new Postprocessor per sample and manual.
Jim Radcliffe}

{5/28/97
Updated: Fagor 8030 TG L325.81.2
Created: Fagor 8030 TG L325.85
For: Gibbs & Associates/Viewpoint Signs Corp
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Updated for Catalyst v3.35C per Fanuc 10T MS [-] L001.85.02d Format.
Updated Approach subs and Commands at Approach subs and SameTool.
Updated CSS at CheckOffset.
Added ckCRC sub.
Added CRCOffC at CheckRapid and end of Prog.
Added Metric SetMaxFeed at setup and initializations.
Updated non-Canned Cycle AutoFinish.
DWB}

{7/30/97
Modified: Fagor 8030 TG L325.85
Created: Fagor 8050 T [VS] L622.85
For: Viewpoint Signs Corp
Machine:
Control: Fagor 8050T
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Changes made per Mike Quinter of Viewpoint Signs Corp, manual and phone calls.
Changed FORMAT#2 from ###.####;0 to ####.#####;0 at Prog Numeric Format Definitions.
Changed FORMAT#5 from #.######;0 to *####.#####;0 at Prog Numeric Format Definitions.
Added ABS# to FORMAT#2 at Prog Numeric Format Definitions.
Added MUL# to FORMAT#2 at Prog Numeric Format Definitions.
Added DIV# to FORMAT#2 at Prog Numeric Format Definitions.
Added CutDepth# to FORMAT#2 at Prog Numeric Format Definitions.
Added FinishXDia# to FORMAT#2 at Prog Numeric Format Definitions.
Added FinishZ# to FORMAT#2 at Prog Numeric Format Definitions.
Added ThreadXInc# to FORMAT#2 at Prog Numeric Format Definitions.
Added RunOutX# to FORMAT#2 at Prog Numeric Format Definitions.
Added LastCutXRadius# to FORMAT#2 at Prog Numeric Format Definitions.
Added InFeedAngle# to FORMAT#2 at Prog Numeric Format Definitions.
Added Peck# to FORMAT#2 at Prog Numeric Format Definitions.
Added Retract# to FORMAT#2 at Prog Numeric Format Definitions.
Changed FeedIPR# from FORMAT#5 to FORMAT#2 at Prog Numeric Format Definitions.
Added CalcNumCuts# to FORMAT#3 at Prog Numeric Format Definitions.
Added ZDepthInc# to FORMAT#5 at Prog Numeric Format Definitions.
Changed Offsets from '.##' to 'D##'.
Changed '.00' to 'D00' at CheckOffset, NewTool and end of Prog.
Changed '.' LatheOffset to ToolOfst at CheckOffset, FirstOperation and NewTool.
Added condition to output SeqLab at FirstFeat AND CannedCycle at ToolPath.
Added StandardXZArcs at setup and initializations.
Added literal ',MX,' to EOR Program# at FirstOperation.
Modified all Canned Cycle blocks per manual.

NOTE: Developer fixes in progress:
Retract# at Canned PeckFullOut is outputting invisible Retract value.
Should output Clearance value.
Canned Threading requires CutDepth# which outputs zero for Straight Threads and ? for Tapered.
Should output value of First Depth of Cut.
? gets changed to next available Line Number during Retag pass.
Using ABS# DIV# ThreadXInc# Recall# Num#('1') FORMULA until CutDepth# is fixed.
Var(1) contains CalcNumCuts#.
DWB}

{8/1/97
Modified: Fagor 8050 T [VS] L622.85
Created: Fagor 8050 T [VS] L622.85.1
For: Viewpoint Signs Corp
Versions: Catalyst v4.10.38(mac)/ComPost2 MSL 68K
Tested and modified per Developer fixes noted on 7/30/97.
Retract# now works correctly for Canned Peck Full Out Operations.
Retract# outputs value entered into Clearance Edit Field.
CutDepth# now works correctly for Canned Threading Cycles.
Deleted ABS# from FORMAT#2 at Prog Numeric Format Definitions.
Deleted DIV# from FORMAT#2 at Prog Numeric Format Definitions.
Deleted Var(1) at setup and initializations.
Deleted Var(1) at Canned Threading.
Changed ABS# FORMAT to CutDepth# FORMAT two places at Canned Threading.
Changed ABS# DIV# ThreadXInc# Recall# Num#('1') to CutDepth# at Canned Threading.
DWB}

{11/7/97
Modified: Fagor 8050 T [VS] L622.85.1
Created: Fagor 8050 T [VS] L622.85.1
For: Viewpoint Signs Corp
Versions: Catalyst v4.21.11(mac)/ComPost2 MSL 68K
Changes made per Willie of Fagor and Mark Winlund of Viewpoint Signs
Changed all Comments from Parentheses style to Semi-Colon style.
DWB}

{12/1/97,
Changed to Metric.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '#####.###;0'
#3 = '#######0'
#4 = '##.##;0'
#5 = '*#####.###;0'
#6 = '###0'
#7 = '#'
#8 = '00000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(CutDepth#,2)
FORMAT(FinishXDia#,2)
FORMAT(FinishZ#,2)
FORMAT(ThreadXInc#,2)
FORMAT(RunOutX#,2)
FORMAT(LastCutXRadius#,2)
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Peck#,2)
FORMAT(Retract#,2)
FORMAT(FeedIPR#,2)
FORMAT(CalcNumCuts#,3)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(ZDepthInc#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(Program#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') {change to Metric, this is a Metirc post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
SeqLabC '; ' OperationComment$ EOL
END
IF WorkGroupComment?
SeqLabC '; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
SeqLabC '; TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ EOL
END
IF ToolComment?
SeqLabC '; ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff 'D00' EOL
SeqLabC OpToolID ToolOfst EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF LAST ProgStop?
CSSOn 'G96' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
CSSOn 'G96' Speed
END
END
ELSE
SeqLabC Preset MaxRPM EOL
CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
'G97' Speed
ELSE
IF LAST ProgStop?
'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G97' Speed
END
END
END
END
IF LAST ProgStop?
SeqLabC {SpeedC} SpinOn EOL
SeqLabC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04K2.' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G04K' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
ELSE
IF FirstFeat? AND CannedCycle?
SeqLab
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbsOrInc
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR Program# ',MX,' EOL
IF UseComments?
IF ProgramNameComment?
SeqLabC '; ' ProgramName$ EOL
END
IF ProgramComment?
SeqLabC '; ' ProgramComment$ EOL
END
IF FormatNameComment?
SeqLabC '; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
SeqLabC '; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
SeqLabC '; OUTPUT IN ABSOLUTE MILLIMETERS' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLab Preset Home MaxRPM EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID ToolOfst SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC NewHome LOfstOff 'D00' EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab Preset Home MaxRPM EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID ToolOfst SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle StrtPos CutDepth 'D0' XStkLeft ZStkLeft
IF AutoFinish?
'H' FeedIPR#
END
'SÅ‚' Tag# 'E²' Tag# EOL
ELSE
IF RoughPatternShift?
SeqLabC LCycle StrtPos 'I' ABS# MUL# CalcNumCuts# CutDepth# 'C' ABS# CutDepth#
IF ApproachFace?
'A1'
ELSE
'A0'
END
XStkLeft ZStkLeft
IF AutoFinish?
'H' FeedIPR#
END
'SÅ‚' Tag# 'E²' Tag# EOL
END
END
RapidF# { Force FeedRate }
'>' Tag# EOL
ToolPath
'<' Tag# EOL
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SeqLabC LCycle
'X' FinishXDia# ZSP 'Q' MUL# Num#('2') SUB# FinishXRadius# Taper# 'R' FinishZ#
IF ApproachID?
FORMAT(ThreadXInc#,5)
END
'I' ThreadXInc#
IF Equal? CalcNumCuts# Num#('1') { One Finish Pass }
FORMAT(ThreadXInc#,5)
'B' ThreadXInc#
ELSE
FORMAT(ThreadXInc#,2)
IF NOT ConstantVolumeCut?
FORMAT(CutDepth#,5)
END
'B' CutDepth#
END
FORMAT(CutDepth#,2)
FORMAT(ThreadXInc#,2)
'L' LastCutXRadius# 'C' FeedIPR# 'J' RunOutX# 'A' InFeedAngle# EOL
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'L' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G04K2.' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
SeqLabC LCycle XSP ZSP 'I' ZDepthInc#
IF Peck?
'B' Peck#
END
IF Dwell?
'K' Dwell#
END
IF Peck?
IF PeckChipBreaker?
'H' Retract#
END
'C' Retract#
END
EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G04K' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04K2.' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC FirstHome OpToolID 'D00' SpinOff EOL
SeqLabC UnTool 'D00' EOL
IF ProgStop?
SeqLabC 'M00' EOL
END
SeqLabC EOP EOL
Post
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
SeqLabC '; FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
SeqLabC '; FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
SeqLabC '; FILE LENGTH: ' FileMeters# ' METERS' EOL
END
END
ASCII('27') EOL
Close
Retag
ÍÍÍÍ