{Change Comments ***********************************************************}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/12/91, Updated Siemens 810M M114.57 to .80 format, JR}
{5/18/96, Updated Siemens 810M M114.80 to .89 format, JR}

{5/18/96
Initial: Siemens 810M M114.89
Created: Siemens 810M Union Mxxx.89
ForUser: General Tool
Control: Siemens 810M
Machine: Union Horizontal
Develop: ComPost 4.21.37, Catalyst68K v3.04.04C
Comment: New Processor per marked up readout from David Bishop
Deleted '@100 K' Sequence# line.
Changed ' R15=' OpToolID to PreTool, added tool label to MachSpec.
Changed ZCP1 ' D= R15' to OfstOn, D now outputs 'D' ToolOffset#
Modified FormatArc to output unconditional move and arc center commands.
Changed ' L2 P1' to ToolChng, added tool change command L30 to MachSpec.
Modified Drilling parameters per conversation with David Bishop.
Jim Radcliffe}

{4/9/97
Updated & Modified: Siemens 810M Union [GT] M395.89
Created: Siemens 810M Union [GT] M395.15
For: General Tool
Versions: Catalyst v3.32C/ComPost2 MSL 68K
Updated for Catalyst v3.32C per Fanuc 6M M001.89b Format
Changes made per David Bishop, Ron Whitten and Rick Bagel of General Tool.
Changed SetMaxSeparateSubCalls from 50 to 200 at ProgStart
Deleted literal ' M86' from StrtPos block at FirstOperation and NewTool.
Added literal ' H0' prior to OfstOn at FirstOperation, NewTool and SameTool.
Allows operator to position quill to desired location.
Changed Bore from G85 to G86 in ComPost2 Drill Cycles Dialog.
Added M001.14 source.
Changed FORMAT#2 from ###.###;0. to #####.###;0 at Prog Numeric Format Definitions.
Changed FORMAT#3 from *###.###;0. to *#####.###;0 at Prog Numeric Format Definitions.
Deleted version comments.
Added CallMasterNum# to FORMAT#5 at Prog Numeric Format Definitions.
Modified WorkFixtureOffset logic.
Added Flag(2) for WFOStuff at setup and initializations.
Added SetFlag(2) for EquallySpacedOffsets at OpenMP sub.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added EOL to NewWFO MP WFOStuff sub Warning.
Deleted SeqC and EOL at WFOStuff sub.
Added Flag(2) logic at start of EachOp/NextOp Loop.
Moved WFOStuff after MP-OTAP-FU condition at FirstOperation and NewTool.
Added WFOStuff for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added AbsOrInc Rapid to StrtPos block for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SeqC and EOL at WFOStuff calls at GetStartOfSameTool, FirstOperation and NewTool.
Added SetMaxFeed(12700) for Metric VNC files.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added Flag(5) to Suppress Redundant WFO for MultipleParts WorkFixtureOffsets programs.
Only concerns OneToolAllParts ExitClearancePlane situations.
Corrections:
Added TrackZNO# to FORMAT#4 at Prog Numeric Format Definitions.
Added SPZ# to FORMAT#4 at Prog Numeric Format Definitions.
Added NextTool# to FORMAT#5 at Prog Numeric Format Definitions.
Deleted Sequence# from FORMAT#5 at Prog Numeric Format Definitions.
Added spaces to Addresses A and B at PSStuff sub.
Added ckCRC sub.
Added IF SPZMove? logic at ToolPath PointFeat for DrillSubs.
Rewrote SetSRXYtoEP logic at ZonlyRepAutoCycle sub.
Added GetStartOfSameTool sub.
Added IF NOT LastTool? condition at FirstOperation.
Post was outputting PreTool for Single Tool Programs.
Change PreTool to ' T' NextTool# at FirstOperation and NewTool.
Rewrote SameTool per Master.
Post did not output Speed or CoolOn at LAST ProgStop condition.
Deleted redundant RapidC ZCP3C at end of IF Drilling.
Updated for Catalyst v3.32C per Fanuc 6M M001.15 Format
Added and filled following subs:
OpGuts, ProgStart, InitOp, FirstOp1, FirstOp2, FirstOp3, FirstOp4, NewToolOp1, NewToolOp2,
NewToolOp3, NewToolOp4, NewToolOp5, NewToolOp6, SameToolOp1, SameToolOp2, SameToolOp3, End1,
End2, End3, MPallTools1P, MP1ToollAllPfu, MP1ToollAllPXcp and NoMPs
DWB}

{02/15/99,
Initial: Siemens 810M Union [GT] M395.15
Created: Siemens 810M Union [SE] Mxxx.15
For: Siemens Energy

Changes to Form:
1) Arcs - Changed R-Format Arc Label to U. Changed I-J-R Arc Discrimination to
By Maximum Angle. Changed I-J Maximum Arc Radius to 0.000. Changed R-Format Maximum
Arc Radius to 359.999. Checked Negative Angles > 180.

Changes to Prog:
1) End3 - Deleted EOR line.
CDH}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0'
#3 = '*#####.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^##0'
#7 = 'ą###.####;+0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ZDepth#,4)
FORMAT(SPZ#,4)
FORMAT(Peck#,4)
FORMAT(FeedTapIPR#,4)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NextTool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(PartShiftX#,7)
FORMAT(PartShiftY#,7)
FORMAT(PartShiftZ#,7)
FORMAT(RepeatX#,7)
FORMAT(RepeatY#,7)
FORMAT(RepeatZ#,7)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
' G' NewWFO#
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'%SPF' Program# EOL { SubID }
DoSubComment
Seq {drop unconditional to force seq# on 1st line of sub}
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC ' V1=0 V2=0 V3=0' EOL
SeqC CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC ' V1=V1' RepeatX# ' V2=V2' RepeatY# ' V3=V3' RepeatZ# EOL
SeqC Preset ' X=V1 Y=V2 Z=V3' EOL { ShiftRC }
SeqC EndSub EOL
CloseSub
SeqC Preset ' X0 Y0 Z0' EOL { UnshftRC }
RETURN

OpenMP:
SeqC ' V1=0 V2=0 V3=0' EOL
NewProg
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SetWFO
END
SeqC CallLab RepLab OnePart EOL
IncWFO
NextWFO {simple NextPart}
ELSE
SeqC CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC ' V1=V1' PartShiftX# ' V2=V2' PartShiftY# ' V3=V3' PartShiftZ# EOL
SeqC Preset ' X=V1 Y=V2 Z=V3' EOL { ShiftPC }
SeqC EndSub EOL
CloseSub
SeqC Preset ' X0 Y0 Z0' EOL { UnshftPC }
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
MoveX MoveY MoveZC { force endpoints in proper plane }
ELSE
IF XZPlane?
MoveX MoveYC MoveZ
ELSE { YZ plane }
MoveXC MoveY MoveZ
END
END
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC CallLab RepLab OnePart EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
IF SPZMove?
SeqC DoDrillAbsOrInc EOL
SeqC ' R3=' SPZ# EOL
SeqC DoDrillAbsOrInc EOL
END
SeqC MoveSXYC EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed EOL
ELSE
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC CallLab RepLab OnePart EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC CallLab RepLab OnePart EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle
' R2=' ClearancePlane2#
' R3=' ZDepth#
IF Peck?
' R5=' Peck#
END
IF Dwell?
' R4=' Dwell#
END
Retract
IF RigidTap?
' R9=' FeedTapIPR#('1')
ELSE
FeedEnt
END
IF RetractToCP1?
' R10=' ClearancePlane1#
ELSE
' R10=' ClearancePlane2#
END
' R11=3'
EOL
IF CallMasterOp?
SeqC CallLabB CallMasterNum# RepLab OnePart EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC CallLab RepLab OnePart EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC DrillOff EOL
SeqC RapidC ZCP3C EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('200')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

InitOp:
EOR 'MPF' Program# EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
Seq Plane DrillOff CRCOff EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
SeqC WFOStuff ' G64' Speed SpinOn
IF NOT LastTool?
' T' NextTool# { PreTool }
END
EOL
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
SeqC ' H0' EOL { Positions Quill to desired location }
RETURN

FirstOp3:
SeqC OfstOn EOL
SeqC CoolOn EOL
RETURN

FirstOp4:
SeqC WFOStuff Speed SpinOn EOL
SeqC AbsOrInc Rapid StrtPos EOL
RETURN

NewToolOp1:
SeqC CoolOff EOL
RETURN

NewToolOp2:
DoEndOpPS
SeqC ToolChng
IF LAST ProgStop?
EOL
SeqC ' M0'
ELSE
IF OptionalStops?
EOL
SeqC ProgStop
END
END
ASCII('13') EOL
RETURN

NewToolOp3: {Start new Operation}
Seq Plane DrillOff CRCOff EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
SeqC WFOStuff ' G64' Speed SpinOn ' T' NextTool# EOL
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
SeqC ' H0' EOL { Positions Quill to desired location }
RETURN

NewToolOp5:
SeqC OfstOn EOL
SeqC CoolOn EOL
RETURN

NewToolOp6:
SeqC WFOStuff Speed SpinOn EOL
SeqC AbsOrInc Rapid StrtPos EOL
RETURN

SameToolOp1:
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC Rapid OfstOff ' D0' EOL
DoEndOpPS
SeqC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC Rapid OfstOff ' D0' EOL
END
DoEndOpPS
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqC WFOStuff Speed SpinOn EOL
SeqC PlaneC AbsOrInc Rapid StrtPos EOL
SeqC ' H0' EOL { Positions Quill to desired location }
SeqC OfstOn EOL
SeqC CoolOn EOL
ELSE
SeqC WFOStuff SpeedC EOL
SeqC PlaneC AbsOrInc Rapid StrtPos EOL
IF NewToolOffset?
SeqC ' H0' EOL { Positions Quill to desired location }
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
SeqC CoolOff EOL
SeqC ' G53' Rapid ' Z0 D0' EOL
RETURN

End2:
DoEndOpPS
IF NOT FirstTool?
SeqC ToolChng EOL
END
IF MultipleParts? AND AllToolsOnePart?
IF ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END
END
RETURN

End3:
SeqC ' T0' EOL
SeqC ' G53 Y0' EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp4 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp6 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END