{Change Comments ***********************************************************}

{10/12/95, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, MPS}

{10/12/95,
modified: Fadal [J&S] M637.85
For: J&S Fabrication, Inc.
Repaired Tapping.
Setup sub calls to start with 'L100' and work correctly
MPS}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{24Dec97
Original: Fadal [J&S] M637.89
Created: Fadal [J&S] M637.89.1
For: J & S Fabrication
Changes made per: Larry Solheim
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added support for FADAL Format 2 Style Rigid Tap
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '#####.###;0.'
#7 = '###;0'
#8 = '####.####;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(SUB#,7)
FORMAT(DirectTapFeed#,8)
FORMAT(CRCOffset#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' SUB# Program# Program2# ' )' EOL
{SUB# Program# Program2# = the Correct Sub. Number. -MPS}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqLabC 'L' SUB# Program# Program2# '00' EOL
{SUB# Program# Program2# = the Correct Sub. Number. -MPS}
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLabC '* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC 'L' SUB# Program# Program2# RepCycs EOL
{SUB# Program# Program2# = the Correct Sub. Number. -MPS}
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftR EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshiftR EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLabC SetWFO EOL
SeqLabC 'L' SUB# Program# Program2# OnePart EOL
{SUB# Program# Program2# = the Correct Sub. Number. -MPS}
IncWFO
NextWFO
ELSE
SeqLabC 'L' SUB# Program# Program2# Parts EOL
{SUB# Program# Program2# = the Correct Sub. Number. -MPS}
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLabC EndSub EOL
CloseSub
SeqLabC WFO1 EOL
ELSE
SeqLabC Preset ShiftP EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshiftP EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdLine:
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC CRCOffsetC FeedRateC EOL
DecelMove2
END
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC CRCOffsetC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc CRCOnC FeedC MoveXYZC CRCOffsetC FeedRateC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC 'L' SUB# Program# Program2# OnePart EOL
{SUB# Program# Program2# = the Correct Sub. Number. -MPS}
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle?
SeqLabC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle?
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS'
ELSE
'E' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'E' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLabC AbsOrInc EOL
ELSE
IF FIFO?
SeqLabC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqLabC AbsOrInc RapidC ZCP2 EOL
END
END
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC EOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC 'L' SUB# Program# Program2# '01' EOL
{SUB# Program# Program2# = the Correct Sub. Number. -MPS}
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect?
IF FIFO?
SeqLabC Feed ZCP2 FeedRate EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
SeqLabC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL
END
END
SeqLabC 'L' SUB# Program# Program2# '01' EOL
{SUB# Program# Program2# = the Correct Sub. Number. -MPS}
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN


GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetMaxSeparateSubCalls ('50')
SetMaxRPM('15000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
SeqLabC 'O' Program#

SaveProgNum2 { to be used to output subs starting with 'L100'}

IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
SeqLabC Rapid Plane CRCOff DrillOff AbsOrInc EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab OpToolID ToolChng EOL
DoOpComments
DoPostScript
IF Drilling? AND RigidTap?
SeqLabC Speed '.2' EOL
SeqLabC 'G84.2' EOL
ELSE
SeqLabC Speed SpinOn EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC PlaneC Rapid StrtPos WFOStuff EOL
SeqLabC OfstOn
IF Milling?
'D' CRCOffset#
END
CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
EOL
CloseMP
SeqLabC
END
CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC Rapid Home EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

SeqLab OpToolID ToolChng EOL
DoOpComments
DoPostScript
IF Drilling? AND RigidTap?
SeqLabC Speed '.2' EOL
SeqLabC 'G84.2' EOL
ELSE
SeqLabC Speed SpinOn EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC PlaneC Rapid StrtPos WFOStuff EOL
SeqLabC OfstOn
IF Milling?
'D' CRCOffset#
END
CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF SameTool?
EOL
DoEndOpPS
IF LAST ProgStop?
SeqLabC CoolOff EOL
SeqLabC SpinOff EOL
SeqLabC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
IF Drilling? AND RigidTap?
SeqLabC Speed '.2' EOL
SeqLabC 'G84.2' EOL
ELSE
SeqLabC SpeedC SpinOn EOL
END
SeqLabC PlaneC Rapid StrtPos WFOStuff EOL
SeqLabC OfstOn
IF Milling?
'D' CRCOffset#
END
CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqLabC SpeedC EOL
SeqLabC PlaneC Rapid StrtPos WFOStuff EOL
SeqLabC OfstOn
IF Milling?
'D' CRCOffset#
END
EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLabC SpeedC EOL
SeqLabC PlaneC Rapid StrtPos WFOStuff EOL
SeqLabC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C
ELSE
IF FIFO?
SeqLabC FeedC CRCOffC ZCP3C FeedEntC
ELSE
SeqLabC RapidC CRCOffC ZCP3C
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle
SeqLabC
IF RigidTap?
'G84.1'
ELSE
Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF Tap?
'F' DirectTapFeed#
IF RigidTap?
Speed '.2'
END
ELSE
FeedEnt
END
EOL
IF CallMasterOp?
SeqLabC SubCall 'L' SUB# CallMasterNum# Program2# '01' EOL
{SUB# CallMasterNum# Program2# = the Correct Sub. Number. -MPS}
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLabC 'L' SUB# Program# Program2# '01' EOL
{SUB# Program# Program2# = the Correct Sub. Number. -MPS}
StartSub
ToolPath
SeqLabC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC Rapid 'G80' ZCP3
IF Repeats?
EOL
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
EOL
CloseMP
SeqLabC
END
CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLabC Rapid FirstHome SpinOff EOL
ELSE
SeqLabC SpinOff EOL
END
IF ProgStop?
SeqLabC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLabC Rapid IncValue 'G28G49Z0' EOL
SeqLabC AbsValue 'X0Y0' WFOOff EOL
SeqLabC UnTool ToolChng EOL
SeqLabC EOP EOL
EndSubs
CloseSub
Post2 {organize Subs into one program}
EOR EOL
'BYE' EOL
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END