{Change Comments ***********************************************************}

{7/28/95,
Updated for Catalyst v2.20 per Fanuc 6M M001.85.01 Format.
Special CutterRadiusCompensation.
No MasterOp/CallMasterOp.
DWB}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}


{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '#0;0'
#7 = '###0'
#8 = '#.###;0'
#9 = '###.####;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Tag#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(SpeedRPM#,7)
FORMAT(LineLength#,8)
FORMAT(ArcR#,8)
FORMAT(CP1LessCP2#,9)

{Special Subs **************************************************************}

CRCCode:
IF RapidFeat? OR LineFeat?
' G45 A' LineLength#
ELSE
IF ArcFeat?
' G47 A' ArcR#
END
END
RETURN

TurnCRCOn:
IF CutterRadiusCompensation?
IF AutoCycle?
IF Flag?('2') { LAST ZMove }
CRCCode
END
ELSE
IF FirstFeat?
CRCCode
END
END
END
RETURN

CRCRapid:
IF CutterRadiusCompensation?
IF AutoCycle?
IF Flag?('2') { LAST ZMove }
Rapid
ELSE
FeedC
END
ELSE
IF FirstFeat?
Rapid
ELSE
FeedC
END
END
ELSE
FeedC
END
RETURN

MakeMove:
IF XYPlane?
MoveX MoveY MoveZC
ELSE
IF XZPlane?
MoveX MoveYC MoveZ
ELSE
MoveXC MoveY MoveZ
END
END
RETURN

CRCMove:
IF CutterRadiusCompensation?
IF AutoCycle?
IF Flag?('2') { LAST ZMove }
MakeMove
SetFlagF('2')
' G64 M61'
ELSE
MoveXYZC
END
ELSE
IF FirstFeat?
MakeMove
' G64 M61'
ELSE
MoveXYZC
END
END
ELSE
MoveXYZC
END
RETURN

TurnCRCOff:
IF CutterRadiusCompensation?
EACHFeat
IF LastFeat?
CRCCode
END
NEXTFeat
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
SeqC
IF FeedEntry?
Feed ZIn FeedEnt
ELSE
RapidC ZIn
END
IF CutterRadiusCompensation?
' M70' EOL
SeqC FeedRate ' M70'
END
EOL
RETURN

StartSub:
OpenSub
'%' Program# '*' Tag# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC RepLab RepCycs ' %*' Tag# EOL
StartSub
RETURN

FinishSub1: {part 1}
CRCOffC
IF NOT EmptyLine?
SeqC TurnCRCOff EOL
END
SeqC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
TagDown
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
TagUp TagInc
SeqC RepLab Parts ' %*' Tag# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqC Preset ShiftPC EOL
TagDown
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
{ MasterOp not supported }
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArc
ELSE
CCWArc
END
MakeMove ArcIJ
RETURN

CkCRC: { 4.2 }
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
IF NOT ZMove? AND NOT LastFeat?
CRCOnC
IF EmptyLine?
FeedC
ELSE
TurnCRCOn CRCRapid
END
ELSE
FeedC
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CkCRC FeedRateC CRCMove EOL
DecelMove2
END
SeqC DoAbsOrInc CkCRC DecelFeed CRCMove EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CkCRC FeedRateC CRCMove EOL
END
END
IF LastFeat? { Exit Length Feature }
CRCOffC
IF NOT EmptyLine?
SeqC CRCCode EOL
END
END
RETURN

GetSpindle:
' S'
IF CWSpindle?
'+'
ELSE
'-'
END
SpeedRPM#
RETURN

DrillSub:
TagInc
OpenSub { Put the Cycle in a Subroutine Block }
SetAbs
IF RetractToCP1?
TrackZNO# ClearancePlane1# {.81}
ELSE
TrackZNO# ClearancePlane2# {.81}
END
SetInc { NOTE: ZDepth is Incremental from ZCP2 }
'N*' Tag# Cycle FeedEnt GetSpindle MoveSZC Peck Retract
IF Dwell?
' G4 F'
IF LessThan? Dwell# Num#('1')
'0'
ELSE
Dwell#
END
END
IF RetractToCP1?
' Z' CP1LessCP2# { Incremental Value from ZCP2 to ZCP1 }
END
EOL
SetAbsOrInc
TrackZNO# SPZ# {.81}
CloseSub
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
Rapid
END
SeqC MoveSXYC EOL
SeqC ' %*' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF SPZMove?
DrillSub
END
' N*' Tag# Rapid
IF FirstFeat?
MoveSX MoveSY
END
MoveSXYC EOL
END
ELSE
IF RapidFeat?
IF AutoCycle?
SeqC DoAbsOrInc RapidC MoveXYZC EOL
IF LastFeat?
CRCOffC
IF NOT EmptyLine?
SeqC CRCCode EOL
END
END
ELSE
IF ZMove? AND NOT XMove? AND NOT YMove?
CRCOffC
IF NOT EmptyLine?
SeqC CRCCode EOL
END
END
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
CRCOffC
IF NOT EmptyLine?
SeqC CRCCode EOL
END
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{ NOTE: This Post Processor does not Support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
SetFlag('2') { To handle CRCOn }
ToolPath
SeqC AbsOrInc EOL {.69 removed Rapid}
SeqC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
SetFlagF('2') { To handle CRCOn }
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc EOL
SeqC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC ' %*' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
TagDown
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC ' %*' Tag# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
Plane {no output}
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('6300')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { AutoCycCutSub2 CRCOff }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
'($%' ProgNum '/000000"' ProgramName$ ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Plane {no output}
DoOpComments
DoPostScript
Seq AbsOrInc EOL
SeqC ' G17' OpToolID EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
Seq AbsOrInc EOL
END
CheckPass
SeqC Rapid StrtPos ZCP1 GetSpindle CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC Rapid StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC Rapid ' Z0 T0' EOL {OfstOff}
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
SeqC SpinOff
IF LAST ProgStop?
' M0'
ELSE
ProgStop
END
EOL

{Start new Operation}

Plane {no output}
DoOpComments
DoPostScript
Seq ' G17' OpToolID EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
Seq AbsOrInc EOL
END
CheckPass
SeqC Rapid StrtPos ZCP1 GetSpindle CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC Rapid ' Z0 T0' EOL {OfstOff}
SeqC SpinOff ' M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC OpToolID EOL
SeqC Rapid StrtPos ZCP1 GetSpindle CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC Rapid ' Z0 T0' EOL {OfstOff}

{Start new Operation}

GetStartOfSameTool
SeqC OpToolID EOL
SeqC Rapid StrtPos ZCP1 GetSpindle EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC Rapid StrtPos GetSpindle EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC RapidC ZCP2C EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
CRCOffC
IF NOT EmptyLine?
SeqC TurnCRCOff EOL
END
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling? { MasterOp not supported }
IF Repeats?
TagUp TagInc
StdSub
SeqC AbsOrInc EOL
SeqC Rapid StrtPos EOL
END
IF RetractToCP1?
LoadFeat Num#('0') Num#('0') ClearancePlane1#
ELSE
LoadFeat Num#('0') Num#('0') ClearancePlane2#
END
IF ZMove?
SeqC Rapid MoveZ EOL
END
GetCycle
ToolPath
SetDrillEndOpZ
SeqC Rapid ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC Rapid ' Z0 T0' EOL {OfstOff}
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome EOL
END
IF ProgStop?
SeqC SpinOff ' M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Reopen
'?' EOL
'0000' EOL
Close