{Change Comments ***********************************************************}

{1/11/90
Copied & modified: Deckel FP2NC Dialog 4 M248.69
For: Specialty Silicone
Changed CRCOffset Label to a 'D' in Form.
Added Spaces between Codes.
Changed Sub FORMAT to Local Subs instead of Macro Sub.
Enabled SepSubs.
Modified Start Up & End Blocks per I/O manual 4.86-/511/874 E, page 39.
NOTE: the '$' sign in the Start Block Indicates Inch Input.
Deleted literal 'N0L0N2' from beginning of prog.
Deleted Calls to Macro Sub Number 4.
JR}

{2/28/90
Modified: Deckel Dialog 4 (SS) M276.69
For: Specialty Silicone
Modified FORMAT for Axis Moves to Four Decimal Places.
Modified FORMAT for Feeds to One Trailing Decimal.
Deleted Plane Values in Form.
Modified Home & ZCP1 stuff, no 'G52'
Rapids are not modal.
Added Additional Subs to handle CutterRadiusCompensation.
CRCMove:
IF FirstFeat? = TRUE, we force Primary Plane Move, and Third Plane remains Conditional.
CRCRapid:
IF FirstFeat? = TRUE, we force Rapid.
Modified Drilling Stuff.
JR}

{4/9/90
Modified: Deckel Dialog 4 (SS) M276.69.6
Added CP1LessCP2# in Drilling.
JR}

{4/25/90
Modified: Deckel Dialog 4 (SS) M276.69.7
Updated to .71.2 FORMAT.
NOTE: the 'A' for CRC in AutoCycles still needs to be Addressed correctly to be full .70.
JR}

{4/3/91
Modified: Deckel Dialog 4 (SS) M276.72
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{11/22/91
Modified: Deckel Dialog 4 (SS) M276.79
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 6M M001.81 Format.
Added Flag('1') to handle CRC in AutoCycles.
DWB}

{12/18/91
Modified: Deckel Dialog 4 (SS) M276.81
For: Specialty Silicone
Changed MoveXYZC (in ArcFeat in ToolPath) to MoveXY MoveZC, per request.
Deleted 'M70' from the FeedRate line in the EntryMove.
Changed logic in the CRCCode SubRoutine.
Changed IF LastFeat? in TurnCRCOff Subroutine to IF FirstFeat?
Added IF FirstFeat?.... to IF ArcFeat? in the ToolPath.
Kim Michelman}

{5/27/92
Modified: Deckel Dialog 4 (SS) M276.81.1
For: Specialty Silicone
Added SPX#,SPY#,SPZ# formats.
Changed the DoSubComment to output a double quote before output.
Changed the EntryMove to the standard.
Added the Sub comment to the Program# line.
Added the TurnCRCOff sub to output a literal 'G45 A0' instead of linelength.
Removed the MakeMove, CRCCode, TurnCRCOn, CRCRapid, CRCMove, StartCRC, TurnCRCOff subs and returned to the standard
literal output. Post was not working properly.
Changed the CWArcC and CCWArcC to unconditional.
Added the FormatArcMove sub to force enpoint moves in the proper plane.
Added the OutputCurrentPosition.
Added CRC info to the StdLine sub.
Added CRC info to the Toolpath - IF RapidFeat?
Kim Michelman}

{2/1/96
Initial: Deckel Dialog 4 (SS) M276.81.2
Created: Deckel Dialog 4 (SS) M276.81.3
ForUser: CNCCS / Specialty Silicone Fabricators
Develop: ComPost 4.21.33, ncCAD 4.33.01, ncCAM 4.33, ncPost 4.33.08
Comment: Modified per maerked up readouts and conversation with Steve Garelli
Added Tool List to beginning of program.
Jim Radcliffe}

{2/5/96
Initial: Deckel Dialog 4 (SS) M276.81.3
Created: Deckel Dialog 4 (SS) M276.81.4
ForUser: CNCCS / Specialty Silicone Fabricators
Develop: ComPost 4.21.33, ncCAD 4.33.01, ncCAM 4.33, ncPost 4.33.08
Comment: Added ProgNum to 1st line of output.
Jim Radcliffe}

{8/7/98,
Initial : Deckel Dialog 4 (SS) M276.81.4
Created: Deckel Dialog 4 [SS] M276.89
Customer: Specialty Silicone Fabricators, Ken Brown 805/239-4284 ex 2290

Changes to "Prog":

1. Updated to .89 with the exception of MasterOp support.
2. Added TagInit and FORMAT to Tag#.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '#0;0'
#7 = '###0'
#8 = '#.###;0'
#9 = '###.####;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(TLNum#,5)
FORMAT(Dwell#,6) {.72}
FORMAT(SpeedRPM#,7)
FORMAT(Tag#,7)
FORMAT(LineLength#,8)
FORMAT(ArcR#,8)
FORMAT(CP1LessCP2#,9)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(SPZ#,4)
FORMAT(TCZ#,4)

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( "SUB NUMBER: ' Tag# ' )'
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
RotateF
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
IF CutterRadiusCompensation?
SeqC FeedRate EOL
END
RETURN

StartSub:
OpenSub
'%' Program# '*' Tag# DoSubComment EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC RepLab RepCycs ' %*' Tag# EOL
StartSub
RETURN

TurnCRCOff:
SeqC CRCOffC
IF NOT EmptyLine?
' G45 A0'
END
EOL
RETURN

FinishSub1: {part 1}
SeqC TurnCRCOff EOL
IF NOT FeedConnect?
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedRateC EOL
ELSE
SeqC Rapid ZCP3C EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
TagInc
SeqC RepLab Parts ' %*' Tag# EOL
StartSub
RETURN

CloseMP:
SeqC Preset ShiftPC EOL
CloseSub
SeqC Preset UnshftPC EOL
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
{ MasterOp not supported }
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArc
ELSE
CCWArc
END
RETURN

FormatArcMove:
IF XYPlane?
MoveX MoveY MoveZC { force endpoints in proper plane }
ELSE
IF XZPlane?
MoveX MoveZ MoveYC
ELSE
MoveY MoveZ MoveXC { YZ plane }
END
END
ArcIJ
RETURN

OutputCurrentPosition:
IF XYPlane?
' X' SPX# ' Y' SPY#
ELSE
IF XZPlane?
' X' SPX# ' Z' SPZ#
ELSE
' Y' SPY# ' Z' SPZ#
END
END
RETURN

StdLine: {enables CRC on first call, .70}
SeqC CRCOnC
IF NOT EmptyLine?
CRCOffsetC ' G45 A0' OutputCurrentPosition Feed ' G64 M61'
END
EOL
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC DoAbsOrInc FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

GetSpindle:
' S'
IF CWSpindle?
'+'
ELSE
'-'
END
SpeedRPM#
RETURN

DrillSub:
TagInc
StartSub { Put the Cycle in a Subroutine Block }
IF RetractToCP1?
TrackZNO# ClearancePlane1# {.81}
ELSE
TrackZNO# ClearancePlane2# {.81}
END
SetInc { NOTE: ZDepth is Incremental from ZCP2 }
SeqC Cycle FeedEnt GetSpindle MoveSZC Peck Retract
IF Dwell?
' G4 F'
IF LessThan? Dwell# Num#('1')
'0'
ELSE
Dwell#
END
END
IF RetractToCP1?
' Z' CP1LessCP2# { Incremental Value from ZCP2 to ZCP1 }
END
EOL
SetAbsOrInc
TrackZNO# SPZ# {.81}
CloseSub
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
Rapid
END
SeqC MoveSXYC EOL
SeqC ' %*' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
IF NotEqual? SPZ# LAST SPZ#
DrillSub
END
Rapid
END
SeqC MoveSXYC EOL
SeqC ' %*' Tag# EOL
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC DoAbsOrInc Rapid MoveXYZC EOL
SeqC TurnCRCOff EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc Rapid MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
SeqC TurnCRCOff EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC FormatArcMove EOL
DecelMove2
END
SeqC FormatArc DecelFeed FormatArcMove EOL
ELSE
SeqC FormatArc ArcFeedC FormatArcMove EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{ NOTE: This Post Processor does not Support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
{SetFlag('1')} {Removed - JHE}
ToolPath
SeqC AbsOrInc EOL {.69 removed Rapid}
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP2 FeedRateC EOL
ELSE
SeqC Rapid ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc EOL
SeqC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC ' %*' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedRate EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to Rapid, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to Rapid, reads better}
END
END
SeqC ' %*' Tag# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
SeqC TurnCRCOff EOL
FinishSub1
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
Plane {no output}
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('6300')
SetMaxFeed('500')
SetTCZ('3.')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' ToolChangeZ(10.0), TCZ(10.0) -' EOL
' The value in parenthese establishes the value the spindle will retract to' EOL
' at the end of the tool or program stop. It is Modal and 3 inches is the default.' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
'$%' ProgNum ASCII('13') EOL
EachTool
'T' TLNum# ' R0. A L0. A' EOL
NextTool
ASCII('13') EOR EOL
'($%' ProgNum '/000000"' ProgramName$ ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Plane {no output}
DoOpComments
DoPostScript
Seq AbsOrInc EOL
SeqC ' G17' OpToolID EOL
SeqC Rapid Home ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
Seq AbsOrInc EOL
END
CheckPass
SeqC Rapid StrtPos GetSpindle CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC Rapid StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC Rapid ' Z' TCZ# EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
IF LAST ProgStop?
SeqC SpinOff ' M0' EOL
ELSE
IF OptionalStops?
SeqC SpinOff ProgStop EOL
END
END

{Start new Operation}

Plane {no output}
DoOpComments
DoPostScript
Seq AbsOrInc EOL
SeqC ' G17' OpToolID EOL
SeqC Rapid Home ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
Seq AbsOrInc EOL
END
CheckPass
SeqC Rapid StrtPos GetSpindle CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC Rapid ' Z' TCZ# EOL
SeqC SpinOff ' M0' EOL
SeqC CoolOff EOL

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc EOL
SeqC OpToolID EOL
SeqC Rapid StrtPos GetSpindle CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc EOL
SeqC OpToolID EOL
SeqC Rapid StrtPos GetSpindle EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC Rapid StrtPos GetSpindle EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC Rapid ZCP2C EOL
IF Repeats?
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqC TurnCRCOff EOL
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedRateC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling? { MasterOp not supported }
IF Repeats?
TagInc
StdSub
SeqC AbsOrInc EOL
SeqC Rapid StrtPos EOL
END
IF NOT RetractToCP1?
SeqC Rapid ZCP2 EOL
END
GetCycle
DrillSub { Put the Cycle in a Subroutine Block }
TrackZNO# ZDepth# {.81}
ToolPath
TrackZNO# ClearancePlane2# {.81}
SeqC Rapid ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC Rapid ' Z' TCZ# EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome EOL
END
IF ProgStop?
SeqC ' M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Reopen
'?' EOL
'0000' EOL
Close