{Change Comments ***********************************************************}

{2/1/91
Copied & modified: Siemens 810T L040.69.3
For: Oskar Vatterott, Inc
Machine: Emco Meyer #340
Control: Siemens Sinumeric 810T
Replaced all occurances of the obsolete StockXDiameter# command with StockXRadius#.
Added InverseSpinOn for Tapping Operation in ToolPath.
SK}

{4/23/91
Modified: Siemens 810T EM L155.71.2
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Only Canned Cycles supported are RoughContour, Threading and PeckChipBreaker.
DWB}

{7/13/92
Modified: Siemens 810T EM L155.80
For: Apollo Precision
Updated to Version 4.0 per Fanuc 6M M001.82.1 Format.
Changed all 'G95' to 'G97'.
Changed start-up code to customer specifications.
Deleted 'M51' from the prog.
Moved the ConstantSurfaceFeed? to the Common Point for all operations.
Removed all home (& variations thereof) from the prog.
Removed the Progstop from the end of the prog.
KLM}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####.####;0'
#3 = '########;0'
#4 = '#####.###;0'
#5 = '0000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CycleStartXDia#,2)
FORMAT(CycleStartZ#,2)
FORMAT(StockXRadius#,2)
FORMAT(StockZ#,2)
FORMAT(CutDepth#,2)
FORMAT(FeedIPR#,2)
FORMAT(FinishXDia#,2)
FORMAT(FinishZ#,2)
FORMAT(ThreadXInc#,2)
FORMAT(Retract#,2)
FORMAT(Peck#,2)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(Program#,5) {.72}

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

ODApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
SeqC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

IDApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL { for SameTool ApproachID }
SeqC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

FaceApproachSP:
SeqC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqC StockOff ZOpCPC EOL
SeqC Feed StockOnNoCan ZSPC FeedRate EOL
RETURN

AppMove:
ZCP
IF NOT CoolOff?
CoolOn
END
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC StockOnNoCan XSP StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC OpToolID 'D' ToolOffset# EOL
END
IF ConstantSurfaceFeed? AND LAST NOT ConstantSurfaceFeed?
CSSOn 'G96'
ELSE
IF NOT ConstantSurfaceFeed? AND LAST ConstantSurfaceFeed?
CSSOff 'G97'
END
END
SeqC SpeedC EOL
IF LAST ProgStop?
SeqC SpinOn EOL
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
InverseSpinOn
ELSE
IF Dwell?
SeqC 'G4X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR 'MPF' Program# EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
'H1025 R1 = R2 = ' EOL {R-values will be entered by the programmer at random}
Seq Rapid EOL
IF ConstantSurfaceFeed?
SeqC 'G54' CalcRPM1 SpinOn CoolOn EOL
ELSE
SeqC 'G54' Speed SpinOn CoolOn EOL
END
SeqC 'L1P1' EOL {Safe Start-up}
SeqC OpToolID 'D' ToolOffset# EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC XCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC ZCPC EOL
DoEndOpPS
SeqC 'L2P1' EOL {Safe Start Block}
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Seq Rapid EOL
IF ConstantSurfaceFeed?
SeqC 'G54' CalcRPM1 SpinOn CoolOn EOL
ELSE
SeqC 'G54' Speed SpinOn CoolOn EOL
END
SeqC 'L1 P1' EOL
SeqC OpToolID 'D' ToolOffset# EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC ZCPC EOL
SeqC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC XCPC EOL
END
SeqC ZCPC EOL
SeqC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC XCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqC Preset MaxRPM EOL
SeqC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughContour?
NewProg
SeqC
FORMAT(Program#,6)
'R20=' Program#
'R21=' CycleStartXDia#
'R22=' CycleStartZ#
'R24=' StockXRadius#
'R25=' StockZ#
'R26=' CutDepth#
'R27=40'
IF ApproachOD?
'R29=11'
ELSE
IF ApproachID?
'R29=13'
ELSE {OD ApproachFace}
'R29=12' {R29=14 is for ID ApproachFace}
END
END
EOL
SetPass2
SeqC 'L95P1' Feedrate EOL
OpenSub
'L' Program# EOL
DoSubComment
SeqC StepMove StrtPos EOL
ToolPath
SeqC 'M17' EOL
CloseSub
IF AutoFinish?
SeqC 'R24=0R25=0'
IF ApproachID?
'R29=22'
ELSE
'R29=21'
END
EOL
SeqC 'L95P1' Feedrate EOL
END
END
ELSE
IF Threading?
SeqC
'R20=' FeedIPR#
'R21=' FinishXDia#
'R22=' CycleStartZ#
IF AutoFinish?
'R23=2'
ELSE
'R23=1'
END
IF ApproachID?
'R24=' ThreadXInc#
ELSE
'R24=-' ThreadXInc#
END
'R25=' StockXRadius#
'R26=.05' {Thread in amount}
'R27=.05' {Thread out amount}
EOL
SeqC
'R28=' CalcNumCuts
IF SingleEdgeCut?
'R29=30'
ELSE
'R29=0'
END
'R31=' FinishXDia#
'R32=' FinishZ#
'L97P1'
EOL
ELSE
IF Drilling?
IF PeckChipBreaker?
SeqC
'R22=' CycleStartZ#
'R24=' Retract# {Peck decrease amount}
'R25=' Peck#
'R26=' FinishZ#
'R27=' Dwell# {Dwell at start}
'R28=' Dwell# {Dwell at end}
'L98P1' Feedrate
EOL
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning? {OR RoughSimple?}
SetPass1
IF ApproachOD?
SeqC RapidC XOpECDC EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC RapidC XOpECDC EOL
IDApproachSP
ELSE {ApproachFace}
SeqC RapidC ZOpECPC EOL
FaceApproachSP
END
END
ELSE
SetPass2
END
SeqC RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqC SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqC XCPC EOL
END
SeqC ZCPC EOL
DoEndOpPS
SeqC 'L2P1' EOL {Safety Code}
SeqC CoolOff EOP EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END