{Change Comments ***********************************************************}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{4/29/91,
Modified: Japax M026.54
For: Gibbs & Associates
Updated to new 4.0 Version per Fanuc 6M M001.80
DWB}

{8/10/92
Modified: Japax M026.79
For: Metric Tool
Changed the 'X' and 'Y' formats in the Mach Spec to output 5 places past the decimal.
**This post does not support AutoCycles.**
KLM}

{7/5/95
Updated: Japax [MT] M513.79.1
For: Gibbs & Associates/HPL Ohio Inc.
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.14.40/Compost 4.21.30/1.0a
Changes made per Pete Jackson.
Updated to Version 4.2 per Fanuc 6M M001.81.2f Format.
DWB}

{7/5/95
Copied: Japax [MT] M513.81.2
Created: Japax [HPL] M827.81.2
For: HPL Ohio Inc
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.14.40/Compost 4.21.30/1.0a
Changes made per Steve Bartnickey of HPL Ohio Inc.
Customer requested that when CutterCenter? equals TRUE, processor output G41 instead of forced G42.
Added condition to test for CutterCenter? at chCRC sub.
Added Flag(1) to toggle between output of G41 and G40.
DWB}

{8/4/95
Renamed: Japax [HPL] M827.81.2
To: Japax [HPL-G41] M827.81.3
For: HPL Ohio Inc
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.20/Compost 4.21.32/1.0a
Needed to create a second post that output standard default of G42, see changes of 7/5/95
DWB}

{8/4/95
Copied: Japax [HPL-G41] M827.81.3
Created: Japax [HPL-G42] M827.81.3
For: HPL Ohio Inc
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.20/Compost 4.21.32/1.0a
Deleted changes of 7/5/95, post is identicle to Japax [MT] M513.81.2
DWB}

{2/9/96, Updated .81 number to .84, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^##0'
#7 = '####.#####;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(OriginShiftRX#,7)
FORMAT(OriginShiftRY#,7)
FORMAT(OriginShiftPX#,7)
FORMAT(OriginShiftPY#,7)
FORMAT(OriginUSRXCTP#,7)
FORMAT(OriginUSRYCTP#,7)
FORMAT(OriginUSPXCTP#,7)
FORMAT(OriginUSPYCTP#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RETURN

PSStuff: {revised.72}
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
{ NOTE: This processor does not support ZMoves. }
RETURN

StartSub:
OpenSub
'>' SubNum EOL
DoSubComment
SeqLab
RETURN

SubWarning:
{ NOTE: This processor does not support ZMoves. }
RETURN

StdSub:
SeqLabC SubCall CallLab SubID 'R' RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
{ NOTE: This processor does not support ZMoves. }
SeqLabC CRCOffC EOL
RETURN

FinishSubG92: {part 2}
SeqLab Preset 'X' OriginShiftRX# 'Y' OriginShiftRY# EOL
'<' SubNum EOL
CloseSub
SeqLabC Preset 'X' OriginUSRXCTP#('1') 'Y' OriginUSRYCTP#('1') EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
SeqLabC SubCall CallLab SubID 'R' Parts EOL
OpenSub
'>' SubNum EOL
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLab Preset 'X' OriginShiftPX# 'Y' OriginShiftPY# EOL
'<' SubNum EOL
CloseSub
SeqLabC Preset 'X' OriginUSPXCTP#('1') 'Y' OriginUSPYCTP#('1') EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF XMove? OR YMove?
SeqLabC CkCRC FeedC MoveXYC EOL
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC SubCall CallLab SubID 'R1' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC MoveSXYC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF AutoCycle?
IF LastFeat?
CRCOffC {.70}
END
SeqLabC RapidC MoveXYC EOL
ELSE
IF XMove? OR YMove?
SeqLabC RapidC MoveXYC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqLabC CRCOffC FeedC MoveXYC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
SeqLabC FormatArc EOL
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
{ NOTE: This processor does not support ZMoves. }
SeqLab AbsOrInc EOL
{ EndSub }
'<' SubNum EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
{ NOTE: This processor does not support ZMoves. }
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC SubCall CallLab SubID 'R1' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
SeqLab 'M01' EOL { EndSub }
'<' SubNum EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
{ NOTE: This processor does not support ZMoves. }
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
SeqLabC SubCall CallLab SubID 'R1' EOL
NextCycle
StartSub
ToolPath
FinishSub1
SeqLab 'M01' EOL { EndSub }
'<' SubNum EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SkipZ
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SeqLab Plane 'G20' AbsValue Preset StrtPos EOL
SeqLabC 'A01D01' EOL
IF MultipleParts? AND OneToolAllParts?
OpenMP
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab PlaneC AbsValue Preset StrtPos EOL
IF MultipleParts? AND OneToolAllParts?
OpenMP
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
END

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC RapidC StrtPosC EOL
END
END
END {common point for all operations}
IF Milling?
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
ZonlyRep
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLabC CRCOffC EOL
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
GetCycle
ToolPath
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts?
CloseMP
END
DoEndOpPS
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLabC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END