{Fanuc 6M M001.50}

{ 6/20/88 Modified beginning of program 5 lines and end of program 3 lines }
{ Moog Hydrapath M090.54 }
{ Modified for S&L 313/543-6633 Contact Robert Steudle }
{ Jim Radcliffe }

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{10/22/90, Updated: Moog Hydrapath III M090.58 to .76.1 format, JR}
{5/19/92, Updated: Moog Hydrapath III M090.76.1 to .81 format, JR}

{2/23/95
Copied & modified: Moog Hydrapath III M090.81
For: QTE Manufacturing Solutions /
Control: Moog Hydropath III
Removed the EOR line between the UJB and UPT lines at the beginning of the program.
Added 'G99' Home line in FirstOp.
Deleted OfstOff and tool change positions.
This processor does not support SameTool NewToolOffsets.
This processor does not support Multiple Parts Full Up as there is no full up command.
Added UnTool & ToolChng to end of program.
Added 30 NULL characters and a percent sign to the beginning of each sub.
Added EOR to the end of each sub, as well as the main.
Added spaces between codes.
Jim Radcliffe}

{5/16/95
Initial: Moog Hydrapath III RTM M774.81
ForUser: QTE Manufacturing Solutions / Reiss Tool & Machine
Created: Moog Hydrapath III RTM M774.82
Comment: Fine tuning processor per marked up readout.
Changed ASCII('00') to ASCII('42')
Deleted EOR from beginning and end of subroutines.
Deleted EOR from end of main program.
Changed '((' and '))' lines at end of program to output 100 ASCII('42')s.
Modified saftey start block at beginning of tools.
Changed OfstOn to ZCP1 CheckOffset, to suppress output if Tool# equals ToolOffset#
Changed CRCOffsetC to CheckCRCOffset, to suppress output if Tool# equals CRCOffset#
WFO output only in FirstOperation and by request, NewWFO or MPs.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '#.#;0.'
#7 = '###.#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(FeedEntry#,7)


{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'(( SUB NUMBER: ' Program# ' ))' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(( OPERATION ' Operation# ': ' OperationType$ ' ))' EOL
END
IF OperationComment?
'(( ' OperationComment$ ' ))' EOL
END
IF WorkGroupComment?
'(( ' WorkGroupComment$ ' ))' EOL
END
IF ToolTypeComment?
'(( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' ))' EOL
END
IF ToolComment?
'(( ' ToolComment$ ' ))' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
EOL
DoSubComment
RETURN

FinishSub:
SeqC '(URT)' EOL
CloseSub
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT ))' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC '(CLS,' CallLab ',' RepLab RepCycs ')' EOL
StartSub
RETURN

FinishSub1: {part 1}
UnSkipZ
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedRateC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
FinishSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC '(UFO,F' SetWFO ')' EOL
SeqC '(CLS,' CallLab ',' RepLab OnePart ')' EOL
IncWFO
NextWFO
ELSE
SeqC '(CLS,' CallLab ',' RepLab Parts ')' EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
FinishSub
SeqC '(UFO,F' WFO1 ')' EOL
ELSE
SeqC Preset ShiftPC EOL
FinishSub
SeqC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CheckCRCOffset:
IF NotEqual? Tool# CRCOffset#
CRCOffsetC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC CheckCRCOffset EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed CheckCRCOffset EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC FeedRateC CheckCRCOffset EOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC '(CLS,' CallLab ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF AutoCycle? {.70}
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
ELSE
StdLine
END
END
ELSE
IF ArcFeat?
IF LastFeat?
SeqC CRCOffC FormatArc ArcFeedC EOL
ELSE
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC '(UFO,F' NewWFO# ')' EOL
END
ELSE
IF FirstOperation?
IF NeedWFO1?
SeqC '(UFO,F' NewWFO# ')' EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqC AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqC AbsOrInc FeedC ZCP2 FeedRateC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
FinishSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
IF FeedConnect?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC '(CLS,' CallLab ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedRate EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
FinishSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC '(CLS,' CallLab ')' EOL
NextCycle
StartSub
SkipZ
ToolPath
FinishSub1
FinishSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

CheckOffset:
IF NotEqual? Tool# ToolOffset#
ToolOfst
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50') {?}
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
'(( UJB,J01,' ProgramName$ ' ))' EOL
'(( UPT,P01 ))' EOL
'(( ' ProgramName$ ' ))' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'(( PROGRAM: ' ProgramName$ ' ))' EOL
END
IF ProgramComment?
'(( ' ProgramComment$ ' ))' EOL
END
IF FormatNameComment?
'(( FORMAT: ' FormatName$ ' ))' EOL
END
IF TimeComment?
'(( ' Date$ ' AT ' Time$ ' ))' EOL
END
IF MovesComment?
'(( OUTPUT IN ' MoveType$ ' INCHES ))' EOL
END
IF PartsComment?
'(( PARTS PROGRAMMED: ' Parts# ' ))' EOL
END
IF StartToolComment?
'(( FIRST TOOL NOT IN SPINDLE ))' EOL
END
END
OpenSub
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
{ The foolowing line programs the M6 canned tool change command with the tool change position }
{ Note that the M6 tool change command also retracts the tool on Z to the tool change position}
SeqC ' G99' Home EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq ToolChng OpToolID EOL
DoOpComments
SeqC Plane AbsOrInc ' G27 G70' EOL
DoPostScript
WFOStuff
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 CheckOffset EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Seq ToolChng OpToolID EOL
DoOpComments
SeqC Plane AbsOrInc ' G27 G70' EOL
DoPostScript
WFOStuff
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 CheckOffset EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC SpinOff EOL
SeqC ' M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC SpeedC SpinOn EOL
SeqC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 CheckOffset EOL
SeqC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC SpeedC EOL
SeqC AbsOrInc Rapid StrtPos EOL
SeqC ZCP1 CheckOffset EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC SpeedC EOL
SeqC AbsOrInc Rapid StrtPos EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedRateC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck
IF Tap?
' E' FeedEntry# EOL
ELSE
FeedEnt EOL
END
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff EOL
IF Repeats?
FinishSubG92
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF MultipleParts? AND AllToolsOnePart?
IF ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END
CloseMP
END
IF NOT FirstTool?
SeqC ToolChng UnTool EOL
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42') ASCII('42')
EOL
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
'(( FILE LENGTH: ' FileBytes# ' CHARACTERS ))' EOL
END
IF FileFeetComment?
'(( FILE LENGTH: ' FileFeet# ' FEET ))' EOL
END
IF FileMetersComment?
'(( FILE LENGTH: ' FileMeters# ' METERS ))' EOL
END
END
Close