{Fanuc 6M M001.50}

{ 6/20/88 Modified beginning of program 5 lines and end of program 3 lines }
{ Moog Hydrapath M090.54 }
{ Modified for S&L 313/543-6633 Contact Robert Steudle }
{ Jim Radcliffe }

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{10/22/90, Updated: Moog Hydrapath III M090.58 to .76.1 format, JR}
{5/19/92, Updated: Moog Hydrapath III M090.76.1 to .81 format, JR}

{5/21/92
Copied & modified: Moog Hydrapath III M090.81
Added G89 Bore with Dwell Cycle
Added 30 null characters to beginning of program.
Added 30 null characters and percent sign to beginning of subs.
Added 100 null characters at end of output.
Changed NewProg to TagInc.
Changed SubComment & to use Tag#.
Changed Sub calls to use Tag#.
Changed literal P01 at beginning of prog to Tag# after a TagInc.
Added UPT comment to beginning of subs for sub ID.
Modified output of indexing.
Added space between codes.
Changed CRC labels from G45 & G46 to G41 & G42.
Changed handling of CRCOff:
CRCOff was being done on the last feature.
That is commented out untill ncCAM 4.2 when Exit Distance will be available.
Changed to LastFeatExtend which can be deleted in favor of the above.
Jim Radcliffe}

{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{9/26/96
Updated: Moog Hydrapath III [WB] M501.87
Created: Moog Hydrapath III [WB] M501.89
For: Gibbs & Associates/Dougherty Machine/Tipton
Versions: Catalyst v3.06C/Compost 4.21.37/v1.0b1
Changes made prior to creation of post processor for Dougherty Machine
Updated for Catalyst v3.05C per Fanuc 6M M001.89 Format
DWB}

{10/8/96
Copied: Moog Hydrapath III [WB] M501.89
Created: Moog Hydrapath III [DM] MZ51.89
For: Dougherty Machine Tool/Tipton Machinery
Versions: Catalyst v3.06C/Compost 4.21.37/v1.0b1
Changes made per Randy Tarmen of Dougherty Machine Tool and Steve Taylor of Tipton Machinery.
Moved CRCOffC to block after ZCP3C at FinishSub1 and end of IF Milling.
Added FormatHelix sub to support HelicalArcs called from FormatArc sub.
Uses Type II statement (UHX, Nxx) where Nxx = number of full revolutions minus one.
Changed MoveXYZC to MoveXY MoveZC at FormatArc sub.
Changed ArcIJC to ArcIJ at FormatArc sub.
Deleted IncValue OfstOff, AbsValue and OfstOff blocks at NewTool and end of Prog.
Deleted Rapid Home SpinOff and SpinOff blocks at NewTool.
Deleted Rapid FirstHome SpinOff and SpinOff blocks at end of Prog.
Changed IncValue and OfstOff blocks to RapidC LAST ZCP1C two places at SameTool.
Added ToolChng block at end of Prog.
DWB}

{10/9/96
Modified: Moog Hydrapath III [DM] MZ51.89
Created: Moog Hydra III [DM] MZ51.89.1
For: Dougherty Machine Tool
Versions: Catalyst v3.09C/Compost 4.21.37/v1.0b1
Changes made per Woody of Dougherty Machine Tool.
Deleted all Address Spaces.
Control is limited to between 12,000 and 15,000 characters.
DWB}

{27May97
Original: Moog Hydra III [DM] MZ51.89.1
Created: Moog Hydra III [BI] Mxxx.89
For: Belfort Instruments
Changes made per: Ed Gerczak
Added
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '#.#;0.'
#7 = '###.#'
#8 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FeedEntIPR#,2)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Recall#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(FeedEntry#,7)
FORMAT(CallMasterNum#,8)
FORMAT(Program#,8)


{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
FORMAT(Program#,5)
'(( SUB NUMBER: ' Program# ' ))' EOL
FORMAT(Program#,8)
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(( OPERATION ' Operation# ': ' OperationType$ ' ))' EOL
END
IF OperationComment?
'(( ' OperationComment$ ' ))' EOL
END
IF WorkGroupComment?
'(( ' WorkGroupComment$ ' ))' EOL
END
IF ToolTypeComment?
'(( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' ))' EOL
END
IF ToolComment?
'(( ' ToolComment$ ' ))' EOL
END
RestoreScale
END
RETURN

DoIndex:
SeqLabC 'M93' EOL {open indexer}
SeqLabC 'G04 D2.' EOL {dwell during index}
SeqLabC 'M92' EOL {clamp indexer}
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
'(( INDEX ' FourthDegree# ' ))' EOL
DoIndex
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'(( INDEX ' FourthDegree# ' ))' EOL
DoIndex
FourthCCWF {reset flag}
END
IF FifthCW?
FifthCWF {reset flag}
END
IF FifthCCW?
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

ASCIIZeros10:
ASCII('00') ASCII('00') ASCII('00') ASCII('00') ASCII('00')
ASCII('00') ASCII('00') ASCII('00') ASCII('00') ASCII('00')
RETURN

ASCIIZeros30:
ASCIIZeros10
ASCIIZeros10
ASCIIZeros10
RETURN

ASCIIZeros100:
ASCIIZeros30
ASCIIZeros30
ASCIIZeros30
ASCIIZeros10
RETURN

StartSub:
OpenSub
ASCIIZeros30 EOR EOL
'(( ' PartName$ '.P' Program# ' ))' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT ))' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC ' (CLS,P' Program# ',' RepLab RepCycs ')' EOL { SubCall }
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
SeqLabC CRCOffC EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC ' (URT)' EOL { EndSub }
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
Save# Num#('1') NewWFO#
EachWFO {simple eachPart}
SeqLabC ' (UFO,F' Recall# Num#('1') ')' EOL
SeqLabC ' (CLS,P' Program# ',' RepLab OnePart ')' EOL { SubCall }
IncWFO
Save# Num#('1') Add# Num#('1') Recall# Num#('1')
NextWFO {simple NextPart}
ELSE
SeqLabC ' (CLS,P' Program# ',' RepLab Parts ')' EOL { SubCall }
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLabC ' (URT)' EOL { EndSub }
CloseSub
SeqLabC ' (UFO,F' NewWFO# ')' EOL
ELSE
SeqLabC Preset ShiftPC EOL
SeqLabC ' (URT)' EOL { EndSub }
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatHelix:
MoveXYZC ' (UHX,N0)' { N0 = Up to 1 full 360Ą Arc }
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
MoveXY ArcIJ
IF ZMove?
FormatHelix
END
ELSE
IF XZPlane?
MoveX MoveZ ArcIJ
IF YMove?
FormatHelix
END
ELSE
IF YZPlane?
MoveY MoveZ ArcIJ
IF XMove?
FormatHelix
END
END
END
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
SetFlag('2') { CRCOffsetC }
CRCOnC
END
END
RETURN

FormatLine:
DoAbsOrInc ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
IF Flag?('2')
SetFlagF('2')
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC ' (CLS,P' Program# ')' EOL { SubCall }
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatLine FeedRateC EOL
DecelMove2
END
SeqLabC FormatLine DecelFeed EOL
ELSE
SeqLabC FormatLine FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
CRCOffC
IF NOT EmptyLine?
SeqLabC FeedC LastFeatExtend FeedRateC EOL
END
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqLabC ' (UFO,F' NewWFO# ')' EOL
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
SeqLabC ' (UFO,F' NewWFO# ')' EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC ' (URT)' EOL { EndSub }
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle: {.86}
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqLabC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqLabC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqLabC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC ' (CLS,P' Program# ')' EOL { SubCall }
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
SeqLabC ' (URT)' EOL { EndSub }
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLabC ' (CLS,P' Program# ')' EOL { SubCall }
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC ' (URT)' EOL { EndSub }
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CRCOffsetC }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a comment of the + index value and codes for external indexer.' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a comment of the - index value and codes for external indexer.' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
ASCIIZeros30 EOR EOL
'(( ' ProgramName$ '))' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'(( PROGRAM: ' ProgramName$ ' ))' EOL
END
IF ProgramComment?
'(( ' ProgramComment$ ' ))' EOL
END
IF FormatNameComment?
'(( FORMAT: ' FormatName$ ' ))' EOL
END
IF TimeComment?
'(( ' Date$ ' AT ' Time$ ' ))' EOL
END
IF MovesComment?
'(( OUTPUT IN ' MoveType$ ' INCHES ))' EOL
END
IF PartsComment?
'(( PARTS PROGRAMMED: ' Parts# ' ))' EOL
END
IF StartToolComment?
'(( FIRST TOOL NOT IN SPINDLE ))' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab ToolChng OpToolID EOL
DoOpComments
SeqLabC Plane CRCOff EOL
SeqLabC DrillOff EOL
DoPostScript
WFOStuff
SeqLabC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StrtPos EOL
SeqLabC ZCP1 EOL
SeqLabC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

SeqLab ToolChng OpToolID EOL
DoOpComments
SeqLabC Plane CRCOffC EOL
SeqLabC DrillOff EOL
DoPostScript
WFOStuff
SeqLabC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StrtPos EOL
SeqLabC ZCP1 EOL
SeqLabC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC CoolOff EOL
SeqLabC RapidC LAST ZCP1C EOL { OfstOff }
SeqLabC SpinOff EOL
SeqLabC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC SpeedC SpinOn EOL
SeqLabC AbsOrInc Rapid StrtPos EOL
SeqLabC ZCP1 EOL
SeqLabC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC RapidC LAST ZCP1C EOL { OfstOff }

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC SpeedC EOL
SeqLabC AbsOrInc Rapid StrtPos EOL
SeqLabC ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC SpeedC EOL
SeqLabC AbsOrInc Rapid StrtPos EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
SeqLabC CRCOffC EOL
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle
SeqLabC
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck
IF Tap?
'E' FeedEntIPR#
ELSE
FeedEnt
END
EOL
IF CallMasterOp?
SeqLabC ' (CLS,P' CallMasterNum# ')' EOL { SubCall }
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLabC ' (CLS,P' Program# ')' EOL { SubCall }
StartSub
ToolPath
SeqLabC ' (URT)' EOL { EndSub }
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC RapidC DrillOff ZCP3C EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLabC ToolChng EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLabC EOP EOL
CloseSub
Post2 {organize Subs into one program}
ASCIIZeros100 EOR EOL
'((' EOL
'))' EOL
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'(( FILE LENGTH: ' FileBytes# ' CHARACTERS ))' EOL
END
IF FileFeetComment?
'(( FILE LENGTH: ' FileFeet# ' FEET ))' EOL
END
IF FileMetersComment?
'(( FILE LENGTH: ' FileMeters# ' METERS ))' EOL
END
Close
END