{Change Comments ***********************************************************}

{3/9/89, Made minor corrections, JR}

{5/4/89
Copied & modified: Fanuc 10T-MS [-] L001.58
For: New Jersey Tool & Die.
Control: Actrion III
Machine: McDonnell Douglas
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{1/18/91, Updated to Version 3.2 per Fanuc 10T MS [-] L001.71, JR}

{4/18/91
Modified: Actrion III L098.71
For: Bio-Rad
Control: Actrion III
Machine: Southbend Cyclone
Changed axis FORMATters to have 5 trailing zeros AND decimal points in Prog and Mach Spec.
Changed FORMAT 'F' to use decimal point AND 4 trailing zeros in Mach Spec.
Control needs trailing zeros, humans need decimal point.
Control uses D label for ToolOffsets.
Changed LatheOffset to ToolOfst.
Changed LOfstOff '00' and OpToolID '00' to literal 'D00'.
Deleted GearRange, control has no gears.
Reversed M03 & M04 in MachSpec.
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80.
JR}

{4/24/91
Modified: Actrion III L098.81
For: Bio-Rad
Made changes per Dan McEachern's requests.
Dan said that the line number was not always output with address 'N'.
Changed SeqLabC to SeqC in CheckOffset, SameTool and at end of Prog.
Dan said that if program shifts from Feed to Rapid, and then back to Feed, FeedRate is needed.
He said it seemed that Feedrates were not modal.
Added IF Rapid? Boolean to ToolPath LineFeat to force FeedRate.
DWB}

{07/26/91
Modified: Actrion III L098.81.1
For: BioRad Labs
Moved 'D00' to 'CSSOff 'G97' CalcRPM2 'D00'' line.
Changed the (home) command to an 'X0Z0' after the 'G92' per request
Added 'G92' 'X0.00000 Z0.00000' line to end of post.
Kim Michelman}

{8/26/91
Modified: Actrion III L098.81.3
For: Bio Rad
Changed the Preset position from 'X0Z0' to Home values in FirstOp & NewTool on line following tool changes.
Added a Preset line after the return to index position in NewTool.
Moved Preset at end of prog to be after the return to index position line.
Corrected position of 'D00' in prog.
Updated to .82 format.
Jim Radcliffe}

{9/27/91
Modified: Actrion III L098.82
For: BioRad
Added same logic to Arcs as being used for Liners to force a FeedRate after a Rapid move.
Jim Radcliffe}

{6/5/92
Modified: Actrion III L098.82.1
For: BioRad
Changed the format for ThrdLead in the Mach Spec to output to seven digits, per request.
KLM}

{
Format: Actrion III Lxxx.82.2
5/9/95
Added 'G70' to start of output
Changed Preset 'X0.00000Z0.00000' to Preset 'X0.00000Z0.00000' in NewTool
Changed 'G92' 'X0.00000 Z0.00000' to 'G92' 'X0Z0' in end of program
Changed format so zero outputs a 0 instead of 0.
Changed format to fixed without decimals
TH}

{
Format: Actrion III L341.82.3
5/17/95
Changed format 2 from '###.00000;0' to '###^00000;0'
Changed 'D00' to 'T00' in NewTool?
Changed default formats to use 4 decimal places instead of 5
Changed Tool change sections to output M20 (Machine uses non-standard tool change methods)
Moved ToolID into AppMove (Machine uses non-standard tool change methods)
TH}

{
Format: Actrion III L341.82.4
8/24/95
Replaced all remaining occurances of D00 with T00
TH}

{
Format: Actrion III [AT] L341.82.5
1/19/96
Changed all movement formats to be ###^0000;0
Added start up codes for setting up stock condition
Split off Preset Home and MaxRPM# calls to be on seperate lines (Can't do Preset Home)
TH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###^00000;0'
#3 = '########;0'
#4 = '###^0000;0'
#5 = '###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CycleStartXRadius#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(CalcEPRPM#,5)

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

ODApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
SeqC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

IDApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL { for SameTool ApproachID }
SeqC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

FaceApproachSP:
SeqC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqC StockOff ZOpCPC EOL
SeqC Feed StockOnNoCan ZSPC FeedRate EOL
RETURN

AppMove:
ZCP CoolOn OpToolID
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC Rapid XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC Rapid XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC Rapid StockOnNoCan XSP StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC RapidC 'T00' EOL
SeqC ToolOfst EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
SeqC SpeedC EOL
ELSE
SeqC Preset MaxRPM EOL
{set CSS in main, need to move to SP first}
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' Speed EOL
ELSE
SeqC SpeedC EOL
END
END
IF LAST ProgStop?
SeqC SpinOn EOL
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G04X20000' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G04X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
IF Rapid?
SeqC FeedC MoveXC MoveZC FeedRate EOL
ELSE
SeqC FeedC MoveXC MoveZC FeedRateC EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
IF Rapid?
SeqC FormatArc FeedRate EOL
ELSE
SeqC FormatArc FeedRateC EOL
END
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
XsAreRadii
SetMaxRPM('2000')
SetMaxFeed('1500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq 'G70' EOL
SeqC AbsOrInc EOL
SeqC 'G95' EOL
SeqC Rapid Home EOL
IF NOT Drilling?
SeqC Preset MaxRPM EOL
END
SeqC 'M20' EOL
SeqC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC XCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC ZCPC EOL
DoEndOpPS
SeqC
IF LAST ConstantSurfaceFeed?
CSSOff 'G97' CalcRPM2
END
'T00' EOL
SeqC NewHome CoolOff EOL
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Seq 'G95' EOL
SeqC Rapid Home EOL
IF NOT Drilling?
SeqC Preset MaxRPM EOL
END
SeqC 'M20' EOL
SeqC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC ZCPC EOL
SeqC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC XCPC EOL
END
SeqC ZCPC EOL
SeqC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC XCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool?
IF LAST NOT ConstantSurfaceFeed?
SeqC CSSOn 'G96R' CycleStartXRadius# Speed EOL
END
ELSE
SeqC CSSOn 'G96R' CycleStartXRadius# Speed EOL
END
END
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqC RapidC StrtPos EOL
ToolPath
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G04X20000' EOL
SeqC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
RapidC
IF ApproachOD?
SeqC XCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC ZCPC EOL
DoEndOpPS
SeqC
IF ConstantSurfaceFeed?
CSSOff 'G97S' CalcEPRPM#
END
'T00' EOL
SeqC FirstHome CoolOff EOL
SeqC 'G92' 'X0Z0' EOL
IF ProgStop?
SeqC 'M00' EOL
END
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END