{Change Comments ***********************************************************}

{3/9/89 minor corections by JR}

{4/25/89
Copied & Modified; Fanuc 10T-MS [-] L001.58, for Brunswick.
Machine is a Cincinnati Series 208 Turning Center, Acramatic 850TC
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{5/17/91, Updated Cincinnati Acr 850TC L102.56 to .81 format, JR}

{8/6/91
Updated: Cincinnati Acr 850TC L102.81
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.82 Format.
Kim Michelman}

{8/6/91
Using "Reference Rewind Stop" characters (:) unstead of SeqLab (N) at beginning of operations.
Changed the startup code per the manual, ':' Program# Rapid Plane 'G62G70' AbsOrInc 'G95' Home GearRange EOL.
Added the GetSpinOn sub to differentiate the 'M13' from 'M03' and 'M14' from 'M04'.
The GetSpinOn replaced the SpinOn command throughout the processor.
Added the missing NextOp at the end of the prog.
Put the EOP on the same line as the FirstHome, per the manual.
Deleted the ProgStop and the Untool ToolChng from the end of the prog.
Kim Michelman}

{6/8/93
Copied & modified: Cincinnati Acr 850TC L102.82.1
For: Braden Eng / Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
Use sequence number for colon blocks.
Added leading zero supression on G & M & T codes.
Changed ToolChng from M26 to M6.
Modified GearRanges.
Added XsAreRadii to initializations.
Added CoolOff at end of tool.
Reduce RPM to 125 at end of tool if next tool has a new gear or spindle direction.
Changed to use absolute arc centers.
Added spaces between codes.
Deleted "XatFinZ ThrdHeight" line before thread cycle.
This was to position to the major dia,
set CAM document to have Start X and Major Ż set the same.
Jim Radcliffe}

{8/6/93
Modified: Cin Acr 850 TC [IM] L289.82.1
For: Braden Eng / Illiana Machine
Control: Acramatic 850 TC
Machine: Cincinnati Milicron Cinturn 18" Universal Turning Center
Modified retract to index position.
Machine has 2 turrets: Lower = Tools 1 thru 6 Upper = Tools 11 thru 16
When indexing from Lower to Upper retract Z to NewHome + 20"
When indexing from Upper to Lower retract X to NewHome + 13"
Unconditional axis output in FormatArc.
Deleted extra Rapid from Approach.
Moved callout of CSSOn for FirstOp and NewTool.
Changed format of output from 0. to 0 for a zero output.
Due to a recent visit to the Twilite Zone,
I had to start with a fresh Form (I used L001) to get this to work.
Colon block must imediatly follow a program stop.
Moved ProgStop to a line by itself after DoOpComments in same tool.
Rewrote CheckOffset to add Colon Block if ProgStop.
Modified R value for Threading by .050 for clearance
Jim Radcliffe}

{11/1/94
Copied & modified: Cin Acr 850 TC [IM] L289.82.2
For: Accurate Tool Co.
Control: Acramatic 850 SX
Machine: Cincinnati Milicron Avenger
Changed G76 to G33 for Threading Canned Cycle.
Moved EOP down to line by itself.
Added 1 NULL character to end of program.
Added X and I values for Tapered threading.
Jim Radcliffe}

{3/2/95
Updated: Cin Acr 850 SX L315.82.2
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Compost 4.21.27
Changes made per Pete Jackson
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1c Format.
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Added XSPC ZSPC at AutoFinish for NOT CannedCycle AND NOT Turning Operations.
Changed RapidC StrtPos to StockOff StrtPosC at AutoFinish for NOT CannedCycle Operations.
Modified non-CannedCycle AutoFinish.
Method of testing for IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple? AND NOT Threading?
did not allow for AutoFinish pass of IF Turning?
Rewrote to test for IF Turning? ELSE IF Roughing? AND NOT RoughSimple?
Added support for AutoFinish of non-Canned Threading Cycle.
Miscellaneous other changes.
DWB}

{3/15/95
Modified: Cin Acr 850 SX L315.82.3
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Catalyst v2.14.30/Compost 4.21.27
Added Address Spaces to Canned Tap and Peck Drilling Cycles in Mach Spec Drilling Dialog.
Added '##.0####;0 Format back in Address K of Mach Spec Threading Dialog.
Somehow, this disappeared.
Added call to RestoreScale prior to SafeStart Home block at beginning of FirstOperation.
Prior to calling RestoreScale, we were outputting Home on the SafeStart block, which did not get
correctly scaled during Metric>English conversion, and vice-versa.
DWB}

{7/27/95, Updated Cin Acr 850 SX L315.82.4 to .85 format, JR}

{10/15/95, WS
Cin Acr 850 SX-IDS LXXX.85 (From Cin Arc SX L315.85)
Changed SetMaxRPM('1600') to SetMaxRPM('4000') at setup and initializations.
Added Rapid move before CSS line so R word equals x direction of tooltip postion.
Modified Thread comment so that the Tool Angle is truncated.
Modified colon block per CMI.
}

{1/2/95, WS
Acr A2100-Generic Lxxx.85
Cin Acr 850 SX-IDS LXXX.85a (From Cin Acr 8850 SX-IDS LXXX.85)
Moved CSS line to Approach Sub so R word equals X postion.
Added A2100 InitOp Sub w/ PGM block
modified colon block to be A2100 style

1/3/96 [ws]
Acr A2100-Generic Lxxx.85(003) ( from - Acr A2100-Generic Lxxx.85(002) )
Modified to provide ToolTipOff output when CRC is turned on.
A2100 Only changes
Modified to Use CMIOpComments
Removed line numbers preceding MSG blocks.
Removed G97 block before tool change

1/3/96 [ws]
Acr A2100-Generic Lxxx.85(004) ( from - Acr A2100-Generic Lxxx.85(003) )
Modified Form to have required Drill Cycles.
A2100 Only changes
Removed G97 block before pretool to first tool at the end of the program
Modified Drill Cycles to be compatible with the the way A2100-Mill output a canned drill cycle.

1/11/96 [ws]
Acr A2100-Generic Lxxx.85(005) ( from - Acr A2100-Generic Lxxx.85(004) )
fixed arc I and J output problem but using arci# and arcj#
Removed support for CRC since output required 'imaginary tool point' assuming a zero 'tool nose radius' which we don't support.
A2100 Only changes
Added G61 to the colon block which specifies Contouring Mode.
Added G63 to the colon block which specifies radius mode programming
Added AbsOrInc to the colon block to specify Absolute/Incremental
modified Program# output to be format 3 from format 6
modifed MaxRPM to have value of 10000 instead of 4000
modified colon block so T-word and toolchange command would be on separate line following tool change position move.
modified canned cycle drilling to match A2100 Milling - previous fix only a partial A2100 mill output

1/15/96 [ws]
Acr A2100-Generic Lxxx.85(006) ( from - Acr A2100-Generic Lxxx.85(005 ) )
changed CCS G96 block so R value is hardcoded to 1.0
changed so post output is in Diameter values instead of Radius Values.
changed so 1st MSG block doesn't output on the same line as the initial tool change.
changed so arcs output I and K values instead of I and J.
changed drilling so Z value is Tip Depth minus Z surface.
changed CMI_Wvalue so W value is Exit clearance minus Z surface.
changed so G80 drill cancel command is omitted.
changed so Drill Pecking cycle always posts as a canned cycle.

1/16/96 [ws]
Acr A2100-Generic Lxxx.85(007) ( from - Acr A2100-Generic Lxxx.85(006 ) )
changed so Tap process will always output in a canned cycle output
changed Tool change block so it will use M6, M6.1, or G98.1, based on Tool Change.
changed so only Spindle Start will be output on the colon block - No combo Spindle + Coolant code
changed so Coolant on/off is on the Tool change line
added format for ABS# and TrackZNO#
added spaces between R,W, and Z values for G80 drilling cycles
added space before G84.1, G89, J, and K letters.
added TrackZNO# in drilling cycle to have post recognize the retract position (W value)


1/18/96 [ws]
Acr A2100-Generic Lxxx.85(008) ( from - Acr A2100-Generic Lxxx.85(007 ) )
changed so G0 is always output on rapid move to part clearance following a toolchange
changed Approach moves to use ThisOpEntry conditional commands
modified tool change to alway rapid to part clearance or tool change position except w/ M6.1 on first operation
modified I arc value to be two times the arcI# value so value will be a diameter value
fixed Tap and Rigid Tap F-word by using FeedIPR#
added space before G84.1
added Rapid code back to colon block
added D-word w/ ToolOffset# to rapid move following a toolchange
added FORMAT(ThisOpEntryZCP#,2) and FORMAT(FeedIPR#,2)

1/19/96 [ws]
Acr A2100-Generic Lxxx.85(009) ( from - Acr A2100-Generic Lxxx.85(008 ) )
added space before G98.1
added rapid move to the clearance plane before G98.1 tool change move
added rapid move to the clearance plane before the last tool change (UnTool ToolChng)
will force a Rapid code in CheckRapid if last cycle was a Peck, Tap, or Rigid Tap

1/22/96 [ws]
Acr A2100-Generic Lxxx.85(010) ( from - Acr A2100-Generic Lxxx.85(009 ) )
modified colon block so the ToolChange block is separate from the colon block
modified canned thread to be like uncanned thread
added UnToolChange function for doing tool change back to first tool at the end of the program
removed rapid move to clearance plane before issuing the M6.1 and M98.1 tool change block.

1/23/96 [ws]
Acr A2100-Generic Lxxx.85(011) ( from - Acr A2100-Generic Lxxx.85(010 ) )
modified the colon block so no clearance move for M6.1 and M98.1 on first op only
modified the colon block so that the initial move to clearance is done before the colon block
modified the colon block so that all operations but the first will have a move to the clearance plane before the tool change
modified so that the colon block will be with all operations and LastToolChange minus move to clearance after tool change
removed ToolChange call since now the colon block will include the tool change
removed the M8 on the LastToolChange
renamed UnToolChange to LastToolChange

1/23/96 [ws]
Acr A2100-Generic Lxxx.85(012) ( from - Acr A2100-Generic Lxxx.85(011) )
added colon block for same tool operations
modified CMI_Wvalue to use ThisOpEntryXCP and ZCP instead of Clearance3

1/25/96 [ws]
Acr A2100-Generic Lxxx.85(013) ( from - Acr A2100-Generic Lxxx.85(012) )
changed so colon block has the operations feedrate
changed so w-value for drill cycles is Op exit clearance if no AutoClearance and Part Clearance if AutoClearance
changed so colon block will be before the any MSG blocks
made the clearance move after the tool change recognized
added support for M82 and M83 (Cutoff part catcher commands)

1/26/96 [ws]
Acr A2100-Generic Lxxx.85(014) ( from - Acr A2100-Generic Lxxx.85(013) )
worked on M83 command output twice if second to last op and not output if cutoff is last op
added SetMaxSS for output of preset and max spindle speed on non-CSS operations
added SetMaxSS to same tool operations
changed SetMaxRPM speed to 50,000 from 10,000
changed so ActualColonBlock is first second line of program for first operation
removed R-word on CSS G96 line

1/29/96 [ws]
Acr A2100-Generic Lxxx.85(015) ( from - Acr A2100-Generic Lxxx.85(014) )
added space before S-word in SetMaxSS
added logic so will output a M5 on colon block if it is the Last Colon Block in the program
added SeqLabC before M83 line
added logic so G96 will be on the colon block with R-word and speed-SFPM
fixed M83 command output
removed rapid move to clearance position after colon block when tool change is not specified for the last tool change

1/30/96 [ws]
Acr A2100-Generic Lxxx.85(016) ( from - Acr A2100-Generic Lxxx.85(015) )
added FORMAT(CycleStartXDia#,2)
added check so if R word is less than or equal to 0.1 the r-word equals 0.1
changed CCS r-word to only use the XDiameter value
modified CCS preset output logic

2/1/96 [ws]
Acr A2100-Generic L421.85 ( from - Acr A2100-Generic Lxxx.85(016) )
changed G63 to G62 in the colon block
post to be used for beta testing only
there are still some post issues that needs to be resolved, but it is good enough for testing

2/13/96 [ws]
Acr A2100-Generic L421.85.01 ( from - Acr A2100-Generic L421.85.00 )
removed GearRange (M42) from colon block.
removed newgear? logic from function CheckOffset

2/15/96 [ws]
Acr A2100-Generic L421.85.02 ( from - Acr A2100-Generic L421.85.01 )
(L421.85.02a ) - 3/18/96
fixed canned section so if pref canned selected from the dlog non-canned out will be used for all but drilling.
fixed so no G0 and G33 on same line.
removed last tool change.
removed spindle from colon block and moved it to the toolchange line.
(L421.85.02b ) - 3/18/96
moved G92 block before the Tool Change Block and removed all other calls to SetMaxSS.
removed newgear? logic from function CheckOffset.
adds "G83" parts catcher code to the end of program section if Cutoff.
(L421.85.02c ) - 3/19/96
forces rapid code before going to tool change position.
initialized cutoff Flag('1') to False.
fixed so G83 only output when Cutoff is used.
(L421.85.02 - 3/19/96 ) - release version

2/21/96 [ws]
Acr A2100-Generic L421.85.03 ( from - Acr A2100-Generic L421.85.02 )
(L421.85.03a ) - 3/21/96
added IValue function to Thread line.
(L421.85.03b ) - 3/21/96
changed IValue function so it outputs a radius IValue.
(L421.85.03c ) - 3/22/96
changed format #2 to output 6 decimal places.
changed form to output 6 decimal places.

3/29/96 [ws]
Acr A2100-Generic L421.85.04 ( from - Acr A2100-Generic L421.85.03 )
(L421.85.04a ) - 3/29/96
modified StartSpeed to use CycleStartXRadius# instead of CycleStartXDia#
(L421.85.04b ) - 3/29/96
removed Rvalue from the colon block and the logic that went with it.
moved StartSpeed, feedrate, and SpinOn after the tool change code.
}

{9/13/96,
Initial: Acr A2100-Generic L421.85.04
Created: Acr A2100 Lxxx.85
Changed Colon block to not not perform a tool change in same tool situations,
Deleted ASCII ('00') at program end,
MPK}

{9/26/96,
Initial: AAcr A2100 [GCS] L517.85
Created: Acr A2100 [GCS] L517.85.1
Commented out ColonBlock call in SameTool,
Uncommented out LastToolChange at program end,
MPK}


{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '###.0#####;0'
#3 = '#######0'
#4 = '##.#0'
#5 = '+#.0###;0'
#6 = '0000'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(SUB#,2)
FORMAT(MUL#,2)
FORMAT(DIV#,2)
FORMAT(ABS#,2)
FORMAT(Num#,2)
FORMAT(HomeX#,2)
FORMAT(HomeX#,2)
FORMAT(HomeZ#,2)
FORMAT(FirstHomeX#,2)
FORMAT(FirstHomeZ#,2)
FORMAT(StartPosX#,2)
FORMAT(ThisOpEntryXCP#,2)
FORMAT(ThisOpEntryZCP#,2)
FORMAT(ArcI#,2)
FORMAT(ArcJ#,2)
FORMAT(CalcZSurf#,2)
FORMAT(TrackZNO#,2)
FORMAT(FeedIPR#,2)
FORMAT(ClearancePlane1#,2)
FORMAT(CycleStartXDia#,2)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(XCutDepth#,5)
FORMAT(ZCutDepth#,5)
FORMAT(CycleStartXRadius#,5)
FORMAT(Program#,3) {.72 }
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

{***** A2100 specific Subroutines *****}

SetMaxSS:
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
ELSE
SeqLabC Preset ' S50000' EOL {see SetMaxRPM}
END
RETURN

StartSpeed:
IF ConstantSurfaceFeed?
CSSOn ' G96' Speed
ELSE
CSSOff ' G97' Speed
END
RETURN

GetSpinOn:
IF Not Flag?('1') { if not Colon Block for Last Tool Change }
IF CWSpindle?
' M3'
ELSE
' M4'
END
ELSE
' M5' {Spindle Stop}
END
RETURN

CMI_Wvalue:
IF AutoClearance?
IF ApproachFace?
IF NotEqual? SUB# ThisOpEntryZCP# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ThisOpEntryZCP# CalcZSurf# Num#('0')
' W' SUB# ThisOpEntryZCP# CalcZSurf#
END
END
ELSE
IF NotEqual? SUB# ThisOpEntryXCP# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ThisOpEntryXCP# CalcZSurf# Num#('0')
' W' SUB# ThisOpEntryXCP# CalcZSurf#
END
END
END
ELSE
IF NotEqual? SUB# ClearancePlane3# CalcZSurf# Num#('0')
IF GreaterThan? SUB# ClearancePlane3# CalcZSurf# Num#('0')
' W' SUB# ClearancePlane3# CalcZSurf#
END
END
END
RETURN

CMIOpComments:
IF FIFO? AND Dwell?
'Bore/Ream w/ Dwell'
ELSE
IF RigidTap?
'Rigid Tap'
ELSE
IF Tap?
'Tap'
ELSE
IF FIRO? AND Dwell?
'Drill w/ Dwell'
ELSE
IF FIFO?
'Bore/Ream'
ELSE
IF Peck?
IF PeckFullRetract?
IF GreaterThan? Peck# Num#('0')
'FixPeck, FullOut' {J13}
ELSE
'VarPeck, FullOut' {J3}
END
ELSE {Chip Break}
IF GreaterThan? Peck# Num#('0')
IF GTEqual? Retract# Num#('0')
'FixPeck, ChipBreak' {J11}
ELSE
'FixPeck, ChipClear' {J12}
END
ELSE
IF GTEqual? Retract# Num#('0')
'VarPeck, ChipBreak' {J1}
ELSE
'VarPeck, ChipClear' {J2}
END
END
END
ELSE
OperationType$ { Drill, Contour, Rough, Thread }
END
END
END
END
END
END
RETURN

ActualColonBlock:
IF Metric?
':?' Rapid ' G61' ' G62' AbsOrInc ' G95' ' G71' EOL
ELSE
':?' Rapid ' G61' ' G62' AbsOrInc ' G95' ' G70' EOL
END
RETURN

ColonBlockBTC: {Before Tool Change}
IF FirstOperation?
ActualColonBlock
IF ToolChangeAtHome? OR AutoClearance?
{Don't Output a move to the clearance plane}
ELSE
SeqLabC Rapid ' X' ThisOpEntryXCP# ' Z' ThisOpEntryZCP# EOL
END
ELSE
IF AutoClearance?
SeqLabC Rapid ' X' LAST ThisOpEntryXCP# ' Z' LAST ThisOpEntryZCP# EOL
ELSE
SeqLabC Rapid ' X' ThisOpEntryXCP# ' Z' ThisOpEntryZCP# EOL
END

IF Last CutOff? AND Not Flag?('1') AND Not Last Threading?
SeqLabC ' M83' EOL {retracts the parts catcher}
ELSE
IF CutOff? AND Flag?('1')
SeqLabC ' M83' EOL {retracts the parts catcher}
END
END
ActualColonBlock
END

RETURN

ColonBlock:
ColonBlockBTC
SetMaxSS
IF NOT SameTool?
IF ToolChangeAtHome?
IF LTEqual? HomeX# Num#('0') AND LTEqual? HomeZ# Num#('0')
SeqLabC OpToolID ' M6.1' CoolOn EOL
ELSE
SeqLabC ' G98.1 X' HomeX# ' Z' HomeZ# EOL
SeqLabC OpToolID ToolChng CoolOn EOL
END
ELSE
IF AutoClearance?
SeqLabC OpToolID ' M6.1' CoolOn EOL
ELSE
SeqLabC OpToolID ToolChng CoolOn EOL
END
END
END
SeqLabC StartSpeed Feedrate GetSpinOn EOL

IF Cutoff? AND RoughContour? {M82 advances the parts catcher}
SeqLabC Rapid ' X' ThisOpEntryXCP# ' Z' ThisOpEntryZCP# ' D' ToolOffset# ' M82' EOL
ELSE
SeqLabC Rapid ' X' ThisOpEntryXCP# ' Z' ThisOpEntryZCP# ' D' ToolOffset# EOL
END

TrackXNO# ThisOpEntryXCP#
TrackZNO# ThisOpEntryZCP#
RETURN

LastToolChange:
SetFlag('1')
ColonBlockBTC
IF ToolChangeAtHome?
IF LTEqual? HomeX# Num#('0') AND LTEqual? HomeZ# Num#('0')
SeqLabC UnTool ' M6.1' EOL
ELSE
SeqLabC ' G98.1 X' HomeX# ' Z' HomeZ# EOL
SeqLabC UnTool ToolChng EOL
END
ELSE
IF AutoClearance?
SeqLabC UnTool ' M6.1' EOL
ELSE
SeqLabC UnTool ToolChng EOL
END
END
RETURN

InitOp:
'(PGM, '

IF ProgramComment?
'NAME="' ProgramComment$ '",'
ELSE
'NAME="' PartName$ '",'
END

IF GTEqual? Program# Num#('0')
' ID="' Program# '",'
END
' TYPE="A2100_274" )'
EOL

IF ToolChangeAtHome?
SetHome
END
ColonBlock

IF UseComments?

'(MSG, PART: ' PartName$ ' )' EOL

IF ProgramNameComment?
'(MSG, PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
IF Metric?
'(MSG, OUTPUT IN ' MoveType$ ' MM )' EOL
ELSE
'(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
END
OpenSub
{RestoreScale}
RETURN

{***** End A2100 specific Subroutines *****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(MSG, OPERATION ' Operation# ': ' CMIOpComments ' )' EOL
END
IF OperationComment?
'(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'(MSG, TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'(MSG, ' ToolComment$ ' )' EOL
END
{RestoreScale}
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP:
{ IF CannedCycle? AND Threading?
{back off 2 threads from start point}
SeqLabC StockOnNoCan ' Z' ADD# CycleStartZ# MUL# NUM#('2') DIV# NUM#('1') Thread# EOL
ELSE
}
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
{ IF CannedCycle? AND Threading?
{back off 2 threads from start point}
SeqLabC StockOnNoCan ' Z' ADD# CycleStartZ# MUL# NUM#('2') DIV# NUM#('1') Thread# EOL
ELSE
}
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ThisOpEntryZCPC
RETURN

CSSline: {To be removed once post is finalized}
IF ConstantSurfaceFeed?
SeqLabC CSSOn ' G96' Speed EOL
END
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC StockOff ThisOpEntryXCPC AppMove EOL
{CSSline}
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
{CSSline}
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
{CSSline}
FaceApproachSP
END
END
RETURN

CheckOffset:
IF LAST ProgStop?
SeqLabC ' M0' EOL
ColonBlock
DoPostScript
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
{tool offsets not used in this processor}
END
{ IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SetMaxSS
END
ELSE
SetMaxSS
{set in main after StrtPos}
END
END
}
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
DoPostScript
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveX MoveZ
IF ArcIJFormat?
{ArcIJ}
' I' MUL# ArcJ# NUM#('2') ' K' ArcI#
ELSE
ArcR
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
IF CutterRadiusCompensation?
SetTTOff
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
IF CutterRadiusCompensation?
SetTTOk
END
END
RETURN

IValue:
Save# Num#('30') Abs# Sub# SPX# EPX#
Save# Num#('31') Abs# Sub# SPZ# EPZ#
' I' DIV# MUL# DIV# Num#('1') Thread# DIV# Recall# Num#('30') Recall# Num#('31') Num#('2') { (Zlead * slope of line) /2}
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat? AND Drilling?
IF Dwell?
SeqLabC ' G4 F' Dwell# EOL
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
{SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL}
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G33' MoveXC MoveZC IValue ThrdLead EOL
IF NEXT RapidFeat?
Rapid
END
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle? OR LAST Peck? OR LAST Tap? OR LAST RigidTap? OR LAST ThreadFeat?
Rapid
ELSE
RapidC
END
RETURN

GoNewHome:
IF ToolOver?('10') AND LAST NOT ToolOver?('10') {lower to upper turret index}
' X' NewHomeX# ' Z' ADD# Num#('20.0') NewHomeZ#
ELSE
IF NOT ToolOver?('10') AND LAST ToolOver?('10') {upper to lower turret index}
' X' ADD# Num#('13.0.') NewHomeX# ' Z' NewHomeZ#
ELSE {index on same turret}
NewHome
END
END
RETURN

GoFirstHome:
IF FIRST ToolOver?('10') AND NOT ToolOver?('10') {lower to upper turret index}
' X' FirstHomeX# ' Z' ADD# Num#('20.0') FirstHomeZ#
ELSE
IF NOT FIRST ToolOver?('10') AND ToolOver?('10') {upper to lower turret index}
' X' ADD# Num#('13.0.') FirstHomeX# ' Z' FirstHomeZ#
ELSE {index on same turret}
FirstHome
END
END
RETURN

NonCannedCycle:
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Threading?
SetPass1
SeqLabC ' X' ADD# FinishXRadius# Taper# EOL
SeqLabC ' G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
{XsAreRadii}
SetMaxRPM('50000')
SetMaxFeed('500')
SetFlagF('1') {Sets Cutoff Flag to False}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
InitOp
StockOff {.71.2}
DoOpComments
DoPostScript
{SetMaxSS}
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
{CheckRapid}
IF LAST ApproachOD?
SeqLabC Rapid LAST OpExitXCPC CoolOff EOL
SeqLabC LAST OpExitZCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC Rapid LAST XOpECDC CoolOff EOL
SeqLabC LAST OpExitZCPC EOL
ELSE
SeqLabC Rapid LAST OpExitZCPC CoolOff EOL
END
END
DoEndOpPS

{Start new Operation}

IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
SeqLabC ProgStop EOL
END
ColonBlock
DoOpComments
DoPostScript
{SetMaxSS}
Approach
ELSE
IF SameTool? {.62}
DoEndOpPS

{Start new Operation}

StockOff
{ColonBlock}
DoOpComments
{SetMaxSS}
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF PreferCan? OR Peck? OR Tap?
StockOff
IF Drilling?
SeqLabC
IF FIFO? AND Dwell? { Bore/Ream with Dwell }
' G89'
ELSE
IF RigidTap?
' G84.1'
ELSE
LCycle
END
END
' Z' Sub# Zdepth# CalcZSurf# { Z = tip depth - "Z" Surface}
IF AbsValue?
' R' CalcZSurf#
ELSE
SetAbs
' R' CalcZSurf#
SetInc
END

{' Z' Zdepth# ' R'ThisOpEntryZCP#}
CMI_Wvalue
IF Peck?
IF NotEqual? Peck# Num#('0')
' K' ABS# Peck#
END
END
IF RigidTap? OR Tap? { F value}
' F' FeedIPR#
ELSE
FeedEnt
END
IF Peck?
IF PeckFullRetract?
IF GreaterThan? Peck# Num#('0')
' J13'
ELSE
' J3'
END
ELSE {Chip Break}
IF GreaterThan? Peck# Num#('0')
IF GTEqual? Retract# Num#('0')
' J11'
ELSE
' J12'
END
ELSE
IF GTEqual? Retract# Num#('0')
' J1'
ELSE
' J2'
END
END
END
END
EOL
TrackZNo# SUB# ClearancePlane3# CalcZSurf# {W value}
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC RLevel EOL
END
ELSE
NonCannedCycle
END
ELSE
NonCannedCycle
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle? OR LAST Peck? OR LAST Tap? OR LAST RigidTap? OR LAST ThreadFeat?
Rapid
ELSE
RapidC
END

IF ApproachOD?
SeqLabC OpExitXCPC ' M5' EOL
SeqLabC OpExitZCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC ' M5' EOL
SeqLabC OpExitZCPC EOL
ELSE
SeqLabC OpExitZCPC ' M5' EOL
END
END
DoEndOpPS
IF CutOff?
SeqLabC ' M83' EOL {retracts the parts catcher}
END
LastToolChange
SeqLabC EOP EOL
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
'(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Post
Close
Retag