{Prog Comments ****}
{2Jul97
Original: Cin Acr A2100 [REN] CY33.15.2
Created: Cin Acr A2100 Cxxx.15
For: Gibbs & Associates
Moved Colon Block up before PGM block at InitOp
Deleted redundant Rapid and ToolChng in SameToolOp2
Changed Speed to SpeedC in SameToolOp3
Charles Winston}

{7/31/97,
Initial: Acr A2100 [ALA] CX48.15
Created: Acr A2100 [ALA] CX48.15.1
Changed Speed to SpeedC in SameToolOp3 when changing CSs,
Made output of SpinOn conditional upon the SpeedRPM# changing in SameToolOp3 when not changing offsets,
MPK}

{7/31/97,
Initial: Acr A2100 [ALA] CX48.15
Created: Acr A2100 [ALA] CX48.15.1
Changes made per Scott at Bonham Metal
Changed Speed to SpeedC in SameToolOp3 when changing CSs,
Made output of SpinOn conditional upon the SpeedRPM# changing in SameToolOp3 when not changing offsets,
Made output of Speed conditional upon the SpeedRPM# changing in SameToolOp3 when not changing offsets, could not
use SpeedC because it a current bug in the command causes it to not output in some situation that it should output,
changed end of program codes to:
SeqLabC 'M26' EOP EOL
MPK}

{6/30/98
Initial: Acr A2100 [ALA] CX48.15.1
Created: Acr A2100 [AB] CU30.15
For: Armstrong-Blum
Made several changes per customer request, added web drill and dead spindle retract, MPK
}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.####;0.'
#3 = '*#####.####;0.'
#4 = '#####.####;0.'
#5 = '#######0'
#6 = '##.##;0'
#7 = '0000'
#8 = '+#####.####;0'
#9 = '####0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,5)
FORMAT(CSOffsetB#,5)
FORMAT(CP1LessCP2#,4)
FORMAT(ABS#,4)
FORMAT(SUB#,4)
FORMAT(Num#,4)
FORMAT(FourthDegree#,4)
FORMAT(CalcZSurf#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(SPZ#,4)
FORMAT(Repeats#,5)
FORMAT(ADD#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(Program#,7)
FORMAT(HelixPitch#,8)
FORMAT(Program#,9)


csWFOVarOut:
{In order to avoid reoutputting info if a CS is used more than once, variables
2-32 are used. Each variable corresponds to the same # CS. Each used CS # variable is initialized
to 0. When an operation uses it, it is checked whether the corresponding variable = 0. If
so, the info is output. The variable is then set to 1. If the variable does not = 0, this
means that the info has already been output and nothing is output, MPK }

IF GreaterThan? NumOfCS# Num#('1')
EachOp
IF NOT GreaterThan? CS# Num#('32')
Save# CS# Num#('0')
END
NextOp

'(MSG, "SET FIXTURE OFFSET" )' EOL
EachOp
IF Equal? Recall# CS# Num#('0') AND NOT Equal? CS# Num#('1') {Do Not output info ofr CS#1}
'[$FIXTURE(' CS# ')X]=' CSOffsetX# EOL
'[$FIXTURE(' CS# ')Y]=' CSOffsetY# EOL
'[$FIXTURE(' CS# ')Z]=' CSOffsetZ# EOL
Save# CS# Num#('1')
END
NextOp
END
RETURN

{Prog Subroutines ****}

{***** CMI specific Subroutines *****}

ToolCRCOfst:
IF CutterRadiusCompensation?
'D' ToolOffset# 'O' CRCOffset#
ELSE
'D' ToolOffset#
END
RETURN

CMI_Wvalue:
IF RetractToCP1?
IF NOT Equal? ClearancePlane1# ClearancePlane2#
IF GreaterThan? ClearancePlane1# ClearancePlane2#
FORMAT(ADD#,4)
'W' Add# Num#('.1)' SUB# ClearancePlane1# ClearancePlane2#
FORMAT(ADD#,5)
END
END
ELSE
'W.1'
END
RETURN

{***** End A2100 specific Subroutines *****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post *** CW}
END
RETURN

CSPartNum#:
ADD# CS# MUL# NumOfCS# SUB# PartNum# Num#('1')
RETURN

CSWFO:
'H' CSPartNum#
RETURN

WFO:
'H' PartNum#
RETURN

WFOStuff:
IF Flag?('2')
IF WFOCS?
CSWFO
ELSE
WFO
END
END
SetFlagF('2')
RETURN

CSG52:
RETURN

G52Stuff:
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'(MSG, "SUB NUMBER: ' Program# '" )' EOL
END
RETURN

DoCSComment:
IF GreaterThan? NumOfCS# Num#('1')
IF FirstOperation? OR ChangeCS?
'( MSG, "CS#' CS# ' - ' CSComment$ '" )' EOL
END
END
RETURN

DoCSWFOComment:
IF GreaterThan? NumOfCS# Num#('1')
IF FirstOperation? OR ChangeCS?
'( MSG, "' CSWFO ' = X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# '" )' EOL
END
ClearCSOffset
END
RETURN

CSComments:
IF WFOCS?
IF MultipleParts?
IF OneToolAllParts? AND ExitClearancePlane?
ClearCSOffset { Necessary for correct StrtPos in Main }
END
ELSE
DoCSComment
DoCSWFOComment
END
ELSE
DoCSComment
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(MSG, "OPERATION ' Operation# ': ' OperationType$ '" )' EOL
END
IF OperationComment?
'(MSG, "' OperationComment$ '" )' EOL
END
IF WorkGroupComment?
'(MSG, "' WorkGroupComment$ '" )' EOL
END
IF ToolTypeComment?
'(MSG, "TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ '" )' EOL
END
IF ToolComment?
'(MSG, "' ToolComment$ '" )' EOL
END
RestoreScale
END
CSComments
RETURN

CSAngleA:
IF AAxisAvail?
'A'
IF Equal? Num#('0') SUB# CSOffsetA# MUL# TRUNC# DIV# CSOffsetA# NUM#('360') NUM#('360')
'0'
ELSE
IF GreaterThan? CSOffsetA# Num#('0')
FORMAT(SUB#,5)
ADD# Num#('360') MUL# Num#('-1') SUB# CSOffsetA# MUL# TRUNC# DIV# CSOffsetA# NUM#('360') NUM#('360')
FORMAT(SUB#,4)
ELSE
SUB# ABS# CSOffsetA# MUL# TRUNC# DIV# ABS# CSOffsetA# Num#('360') Num#('360')
END
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
'B'
IF Equal? Num#('0') SUB# CSOffsetB# MUL# TRUNC# DIV# CSOffsetB# NUM#('360') NUM#('360')
'0'
ELSE
IF GreaterThan? CSOffsetB# Num#('0')
ADD# Num#('360') MUL# Num#('-1') SUB# CSOffsetB# MUL# TRUNC# DIV# CSOffsetB# NUM#('360') NUM#('360')
ELSE
FORMAT(SUB#,5)
SUB# ABS# CSOffsetB# MUL# TRUNC# DIV# ABS# CSOffsetB# Num#('360') Num#('360')
FORMAT(SUB#,4)
END
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCoolOn:
IF ThruSpin?
'M27'
ELSE
CoolOn {M8}
END

{ To Be Used When Support is Added for additional Coolant Types and CMI says what the M codes mean
There is also a 5th Coolant Type they want supported M7
_________________________
IF Pulse?
'M28'
ELSE
IF Mist?
'M29'
ELSE {Flood}
CoolOn {M8}
END
END
END
__________________________
}
RETURN

PSInit: {reset flags}
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
ResetCool
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'(DFS, "SUB' Program# '")' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'(MSG, "WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT" )' EOL
' ' EOL
END
END
RETURN

StdSub: {not used in Virtual, only used in non SepSub Repeats}
SeqLabC '( CLS, "SUB' Program# '",' RepCycs ')' EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC '(ENS)' EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

DoWFOOps:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqLabC SetWFO EOL
END
SeqLabC '( CLS, "SUB' Program# '", 1)' EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF WFOCS?
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
StartSub
END
ELSE
SeqLabC '( CLS, "SUB' Program# '", ' Parts# ')' EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
StartSub
END
RETURN

DoCSWFOOps:
EachCSOp
DoCSComment
DoCSWFOComment
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqLabC CSWFO EOL
END
SeqLabC '( CLS, "SUB' CSSubID# '", 1)' EOL
NextCSOp
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqLabC '(ENS)' EOL
CloseSub
IF WFOCS?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoCSWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoCSWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
END
ELSE
SeqLabC Preset ShiftPC EOL
SeqLabC '(ENS)' EOL
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqLabC '(ENS)' EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
IF ZMove?
MoveX MoveY MoveZ ArcIJ 'K' HelixPitch#
ELSE
MoveX MoveY ArcIJ
END
ELSE
{ ??? what about incr subs here ??? }
IF XZPlane?
IF YMove?
MoveX MoveY MoveZ ArcIJ 'J' HelixPitch#
ELSE
MoveX MoveZ ArcIJ
END
ELSE { YZPlane }
IF XMove?
MoveX MoveY MoveZ ArcIJ 'I' HelixPitch#
ELSE
MoveY MoveZ ArcIJ
END
END
{ ??? }
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC '(CLS, "SUB' Program# '")' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF Drilling?
IF SPXMove? OR SPYMove? OR SPZMove?
SeqLabC MoveSXYZC
CMI_Wvalue
EOL
END
ELSE
SeqLabC MoveSXYZC EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed EOL
ELSE
SeqLabC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC '(ENS)' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqLabC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqLabC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqLabC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC '(CLS,L' Program# ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
SeqLabC '(ENS)' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL
END
END
SeqLabC '( CLS, "SUB' Program# '", 1)' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC '(ENS)' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

DoPreTool:
IF NOT LastTool?
PreTool
END
RETURN

doZdepth:
'Z' SUB# ZDepth# SUB# ClearancePlane2# Num#('.1') {cp2 should be part surface plus .1 inch gage height}
RETURN

OpGuts:
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO?
SeqLabC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF MultipleParts? AND WorkFixtureOffsets?
ELSE
SetFlag('2')
END
GetCycle
SeqLabC
IF FIFO? AND FourthCW?
'G88' {Web Drill}
ELSE
IF FIRO? AND OptCyc1? {Dead spindle Retract}
'G86'
ELSE
IF Tap? AND OptCyc1?
'G84.1'
ELSE
Cycle
END
END
END
StrtPos
doZdepth CSAngleA CSAngleB
'R' SUB# ClearancePlane2# Num#('.1') { Entry Clearance Plane - gage height }
CMI_Wvalue
IF FIFO? AND FourthCW?
'I' ABS# ADD# Num#('.1') SUB# CalcZSurf# FourthDegree#
'K' ABS# SUB# SUB# ClearancePlane2# Num#('.1') FourthDegree#

END
IF Peck?
IF NotEqual? Peck# Num#('0')
'K' ABS# Peck#
END
END
FeedEnt
IF Peck?
IF PeckFullRetract?
IF GreaterThan? Peck# Num#('0')
'J13'
ELSE
'J3'
END
ELSE {Chip Break}
IF GreaterThan? Peck# Num#('0')
IF GTEqual? Retract# Num#('0')
'J11'
ELSE
'J12'
END
ELSE
IF GTEqual? Retract# Num#('0')
'J1'
ELSE
'J2'
END
END
END
END
IF FIRO? AND OptCyc1?
'V-.005'
ELSE
IF FIFO? AND FourthCW?
'V-.005'
END
END

ToolCRCOfst Speed SpinOn
IF MultipleParts? AND WorkFixtureOffsets?
ELSE
WFOStuff
END
DoPreTool EOL
TrackZNO# FIRST SPZ#
ToolPath
SetDrillEndOpZ
SeqLabC DrillOff
IF RetractToCP1?
'R' ClearancePlane1#
ELSE
'R' ClearancePlane2#
END
EOL
SeqLabC Rapid ZCP3C EOL
END
END
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('500')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlag('3') { True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP }
SetFlag('4') { True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
IF PSComment? AND UseComments?
'Utility Data:' EOL
' AT OP START / AT OP END' EOL
' all literals and commands in AT OP START box' EOL
' will appear at the beginning of the operation. ' EOL
' All literals and commands in AT OP END box' EOL
' will appear at the end of the operation. ' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: OptCyc1 with a FIRO drill cycle will output a G86 cycle' EOL
' 4ACW(n) with a FIFO drill cycle will output a G88 cycle, n is the upper hole depth.' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('32')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to non WFO output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('32')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to non WFO output. )' EOL
END
END
END
RETURN

InitOp:
':G17G70G90' EOL
'(PGM, '

IF ProgramComment?
'NAME="' ProgramComment$ '",'
ELSE
'NAME="' PartName$ '",'
END

IF GTEqual? Program# Num#('0')
' ID="' Program# '",'
END
' TYPE="A2100_274" )'
EOL

IF UseComments?

'(MSG, "PART: ' PartName$ '" )' EOL

IF ProgramNameComment?
'(MSG, "PROGRAM: ' ProgramName$ '" )' EOL
END
IF ProgramComment?
'(MSG, "' ProgramComment$ '" )' EOL
END
IF FormatNameComment?
'(MSG, "FORMAT: ' FormatName$ '" )' EOL
END
IF TimeComment?
'(MSG, "' Date$ ' AT ' Time$ '" )' EOL
END
IF MovesComment?
'(MSG, "OUTPUT IN ' MoveType$ ' INCHES" )' EOL
END
IF PartsComment?
'(MSG, "PARTS PROGRAMMED: ' Parts# '" )' EOL
END
IF StartToolComment?
'(MSG, "FIRST TOOL NOT IN SPINDLE" )' EOL
END
END
csWFOVarOut
OpenSub
RestoreScale
RETURN

FirstOp1:
IF ToolChangeAtHome?
SetHome
END
DoOpComments
':?' Plane 'G70' AbsOrInc Rapid { Inch }
'T' Tool# ToolChng EOL
DoPostScript
RETURN

FirstOp2:
CheckPass
SeqLabC Rapid StrtPos ZCP1 CSAngleA CSAngleB ToolCRCOfst Speed SpinOn FeedEnt WFOStuff DoPreTool EOL
RETURN

FirstOp3:
SeqLabC DoCoolOn EOL
RETURN

NewToolOp1:
IF OneToolAllParts? AND FullUp?
SeqLabC 'M26' EOL
END
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
DoOpComments
':?' Plane 'G70' AbsOrInc Rapid { Inch }
'T' Tool# ToolChng EOL
DoPostScript
RETURN

NewToolOp4:
CheckPass
SeqLabC Rapid StrtPos ZCP1 CSAngleA CSAngleB ToolCRCOfst Speed SpinOn FeedEnt WFOStuff DoPreTool EOL
RETURN

NewToolOp5:
SeqLabC EOL
SeqLabC DoCoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC SpinOff EOL
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF ChangeCS?
SeqLabC 'M26' EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
':?' Plane 'G70' AbsOrInc { Inch } EOL
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqLabC
PlaneC Rapid StrtPos ZCP1 CSAngleA CSAngleB ToolCRCOfst Speed SpinOn FeedEnt WFOStuff DoPreTool EOL
SeqLabC DoCoolOn EOL
RETURN

End1:
IF OneToolAllParts? AND FullUp?
SeqLabC 'M26' EOL
END
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLabC AbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqLabC 'M0' EOL
END
RETURN

End3:
SeqLabC 'M26' EOP EOL { End of Program }
CloseSub
Post2 {organize Subs into one program}
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
'(MSG, "FILE LENGTH: ' FileBytes# ' CHARACTERS" )' EOL
END
IF FileFeetComment?
'(MSG, "FILE LENGTH: ' FileFeet# ' FEET" )' EOL
END
IF FileMetersComment?
'(MSG, "FILE LENGTH: ' FileMeters# ' METERS" )' EOL
END
END
Close
ReTag
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
InitOp
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
InitOp
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
InitOp
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
OpenMP
SeqLabC StrtPos Speed EOL {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
SeqLabC StrtPos Speed EOL {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
InitOp
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END