{4/9/91
New Processor from: Anilam Crusader (VT) M220.79
For: Excell Mold
Control: Anilam Series GXM
Machine: Eagle Supercut (Knee Type Mill)
Too many changes to mention, same basic format idea used.
Does not use tool offsets, uses the tool number only.
TO cancels all offsets
Any T call cancels Origin Offsets
Cannot do a Z origin shift.
Jim Radcliffe}

{7/15/91
For: National Research Council
Put all 'G17' on a line by itself, per request
Removed all 'M44'
Changed 'M00' to 'M05'
Replaced:
EachTool
SeqLab 'T100' TLNum# 'X' TLDia# 'Z' TLLength# EOL
NextTool
With:
SeqLab 'M1401' EOL
SeqLab 'M1000' EOL
Kim Michelman}

{2Jul97, Updated to .89 Format per M995.89, Charles WInston }

{11Jul97
Original: Anilam GXM [NRC] M443.80.1
Created: Anilam GXM [NRC] M443.89
For: National Research Council
Changes made per: Serge Bouchard
Updated to .89 per Anilam Crusader II G&C M995.89
Added support for Coolant
Changed CoolOn to 'M7' in MachSpec
Changed all comments to begin with '*'
Deleted IF ProgStop? Boolean at End of program and made 'M05' Output unconditional
Charles Winston}

{20Aug97
Original: Anilam GXM [NRC] M443.80.1
Created: Anilam GXM [NRC] M443.89
For: National Research Council
Changes made per: Serge Bouchard
Changed CoolOff to 'M8' in MachSpec
Charles Winston}

{4/21/98
Updated & Modified: Anilam GXM [NRC] M443.89.1
Created: Anilam GXM [NRC] M443.89.2
For: National Research Council
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Changes made per Serge Bouchard of National Research Council.
Per Customer Request:
Added Rapid to Home block during EachOp/NextOp at setup and initializations.
Updated for Catalyst v3.35C per Fanuc 6M M001.89b Format.
Eliminated unused Number Commands at Prog Numeric Format Definitions.
Changed Dwell# from old FORMAT#4, "##^", to updated FORMAT#4 at Prog Numeric Format Definitions.
Corrected output of V22 R Parameter at IF Drilling.
Added Peck# to updated FORMAT#4 at Prog Numeric Format Definitions.
Changed PeckValue to Peck# at IF Drilling?
Corrected output of V23 R Parameter at IF Drilling.
DWB}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '###.####;0.'
#5 = '#######0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ToolLength#,4)
FORMAT(FeedEntry#,4)
FORMAT(CurOriginPosX#,4)
FORMAT(CurOriginPosY#,4)
FORMAT(Dwell#,4)
FORMAT(Peck#,4)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'* SUB NUMBER: ' Program# EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'* CYCLE START' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'* OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'* ' OperationComment$ EOL
END
IF WorkGroupComment?
'* ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'* TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'* ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab Feed ZIn FeedEnt EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

ExitMove:
IF NOT FeedConnect?
CRCOffC
IF FIFO?
FeedC PRIME ZCP2C FeedEntC
ELSE
RapidC PRIME ZCP2C
END
END
RETURN

StartSub:
OpenSub
DoSubComment
SeqLab 'G98S' Program# EOL
RETURN

CycleWarning: { For XYZRep }
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

SubWarning:
IF NOT FeedConnect? AND UseComments?
IF AnyZshift?
' ' EOL
'* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

StdSub:
EachRep
IF NOT FirstCycle?
SeqLab 'M1101' EOL { Absolute Zero Shift }
SeqLab 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z0' EOL
END
SeqLab SubCall CallLabB Program# EOL
NextRep
StartSub
RETURN

FinishSub1: {part 1}
SeqLab CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLab EndSub EOL
CloseSub
SeqLab 'M1101' EOL { Absolute Zero Restore }
SeqLab 'X0Y0Z0' EOL
RETURN

ATOPsubs: { AllToolsOnePart }
EachPart
EachOp
IF FirstOperation? OR NewTool?
NewProg
IF FirstOperation?
IF UseComments?
'* Part# ' PartNum# EOL
END
IF NOT FirstPart?
SeqLab 'M1101' EOL { Absolute Zero Shift }
SeqLab 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' ToolLength# EOL
END
ELSE
IF LAST ProgStop?
SeqLab 'M0' EOL
ELSE
SeqLab ProgStop EOL
END
END
SeqLab SubCall CallLabB Program# EOL
IF UseComments? AND ToolTypeComment?
' ( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
EOL
END
IF Milling?
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
NewProg
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
NewProg
END
END
END {end Auto Cycle IF}
ELSE
IF AutoCycle?
NewProg
END
END {end Z only IF}
ELSE
IF AutoCycle?
NewProg
END
END
END
NextOp
SetProgNum('0')
NextPart
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
IF OneToolAllParts?
EachPart
IF NOT FirstPart?
SeqLab 'M1101' EOL { Absolute Zero Shift }
SeqLab 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z0' EOL
END
SeqLab SubCall CallLabB Program# EOL
NextPart
END
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLab EndSub EOL
CloseSub
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLab AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArc
ELSE
CCWArc
END
IF XYPlane?
MoveX MoveY MoveZC { force endpoints in proper plane }
ELSE
IF XZPlane?
MoveX MoveZ MoveYC
ELSE
MoveY MoveZ MoveXC { YZ plane }
END
END
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLab MoveSXYC EOL
SeqLab SubCall CallLabB Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLab DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLab DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed EOL
ELSE
SeqLab DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc ArcFeedC EOL
DecelMove2
END
SeqLab FormatArc DecelFeed EOL
ELSE
SeqLab FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLab AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLab EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

XYZRep:
CycleWarning
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
CRCOffC
IF FeedConnect?
IF SPXMove? OR SPYMove?
SeqLab FeedC MoveSXYC EOL
END
IF ZShiftOnly?
EntryMove
ELSE
IF NOT NoZMoves?
EntryMove
END
END
ELSE
IF SPXMove? OR SPYMove?
SeqLab RapidC MoveSXYC EOL
END
IF FeedEntry?
SeqLab ZCP2C EOL
END
EntryMove
END
END
ToolPath
SeqLab ExitMove EOL
NextRep
RETURN

G92Sub:
IF MultipleParts? AND EquallySpacedOffsets? { LongHand, no double Shifting }
IF AutoCycle?
SubWarning
Milling
SetPass2
EachRep
IF NOT FirstCycle?
EACHFeat
SeqLab MoveSX MoveSY EOL
SeqLab SubCall CallLabB Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
NEXTFeat
END
NextRep
ELSE
IF UseComments?
' ' EOL
'* THIS REPEAT OP WILL BE LONGHAND DUE TO MULT PARTS OR Z SHIFT' EOL
' ' EOL
END
XYZRep
END
ELSE
NewProg
SubWarning
StdSub
SeqLab AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
END
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab IncValue StrtPosC EOL
AbsOrInc
END
END
SeqLab ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqLab IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqLab ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqLab RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab SubCall CallLabB Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLab Feed ZCP2 FeedEnt EOL
ELSE
SeqLab Rapid ZCP2 EOL
END
END
SeqLab EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab Connect StrtPos EOL
END
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusIncC EOL
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab RapidC ZInPlusInc EOL
END
END
SeqLab SubCall CallLabB Program# EOL
NextCycle
SetStatusRapid {force next G1,G2,G3,etc.}
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
PlaneC { No Output }
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
UseSeparateSubCalls
SetMaxSeparateSubCalls('1000')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

EOR EOL
SeqLab 'G37J' Program# EOL
SetProgNum('0')
IF UseComments?
IF ProgramNameComment?
'* PROGRAM: ' ProgramName$ EOL
END
IF ProgramComment?
'* ' ProgramComment$ EOL
END
IF FormatNameComment?
'* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'* OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'* FIRST TOOL IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
SeqLab 'M1401' EOL { Feed Percentage Override }
SeqLab 'M1000' EOL { Contouring - no deceleration }
SeqLab 'G70' AbsOrInc EOL
EachOp
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
DoPostScript
IF ToolChangeAtHome?
SeqLab Rapid Home EOL
END
END
NextOp

IF MultipleParts?
IF WorkFixtureOffsets?
' ' EOL
'* THIS POST PROCESSOR DOES NOT SUPPORT WORKFIXTURE OFFSETS' EOL
'* PLEASE SELECT EQUALLY SPACED OFFSETS ' EOL
' ' EOL
ELSE { EquallySpacedOffsets }
IF AllToolsOnePart?
ATOPsubs
END
END
END

EachOp {Start of post processing *********************}
IF FirstOperation?
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab OpToolID EOL
DoOpComments
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqLab Speed SpinOn EOL
SeqLab Plane EOL
SeqLab CoolOn EOL
CheckPass
SeqLab Rapid StrtPos EOL
SeqLab ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqLab Speed SpinOn EOL
SeqLab Rapid StrtPos EOL
END
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab Rapid OfstOff EOL {cancels tool & origin offsets, full up}
SeqLab SpinOff EOL
SeqLab CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqLab Rapid Home EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
IF LAST ProgStop?
SeqLab ProgStop EOL
END

{Start new Operation}

IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab 'M05' EOL {change tools}
SeqLab OpToolID EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqLab Speed SpinOn EOL
SeqLab CoolOn EOL
CheckPass
SeqLab Plane EOL
SeqLab Rapid StrtPos EOL
SeqLab ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqLab Speed SpinOn EOL
SeqLab Rapid StrtPos EOL
END
END
ELSE
IF SameTool?
IF LAST ProgStop?
SeqLab SpinOff EOL
SeqLab CoolOff EOL
DoEndOpPS
SeqLab 'M05' EOL

{Start new Operation}

GetStartOfSameTool
SeqLab SpeedC SpinOn EOL
SeqLab CoolOn EOL
SeqLab Rapid StrtPos EOL
SeqLab ZCP1 EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab CoolOff EOL
END
DoEndOpPS
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqLab Rapid StrtPos EOL
SeqLab ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLab Rapid StrtPos EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLab CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
NewProg
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
NewProg
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab ZCP3C EOL
ELSE
IF FIFO?
SeqLab FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqLab RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLab AbsOrInc Rapid StrtPos EOL
END
GetCycle
SeqLab 'V20R' FeedEntry# EOL
SeqLab 'V21R' ClearancePlane2# EOL
IF Dwell?
SeqLab 'V22R' Dwell# EOL
END
IF Peck?
SeqLab 'V23R' Peck# EOL
END
IF RetractToCP1?
SeqLab 'V24R' ClearancePlane1# EOL
ELSE
SeqLab 'V24R' ClearancePlane2# EOL
END
IF Tap?
SeqLab 'V26R0' EOL
END
IF FIFO? AND Dwell?
SeqLab 'G89' EOL
ELSE
SeqLab Cycle EOL
END
SeqLab ZDepth EOL
IF CallMasterOp?
SeqLab SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLab SubCall CallLabB Program# EOL
StartSub
SeqLab StrtPos EOL
ToolPath
SeqLab EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
SeqLab StrtPos EOL
ToolPath
END
END
SetDrillEndOpZ
SeqLab 'G80' EOL
SeqLab Rapid ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab SpinOff EOL
SeqLab Rapid OfstOff EOL
SeqLab CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLab Rapid FirstHome EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab EOP ProgID1 EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'* FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'* FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'* FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END