{Change Comments ***********************************************************}

{10/31/95, M738.81.8, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, DWB}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed varsion # to .89, MPK}

{1/2/97, Copied from Anilam 1100 [NOAO] M738.89 to Anilam 1100 [SMAC] MZ96.89.
This post is the same as M738.89 except the 'MCode 5 and Dwell 0.0' have been
removed since there is no tool changer.
KC}

{1/17/97, Separated ZCP1 move from StrtPos move. (Customer prefers safer approach).
Modified Anilam 'ReturnHgt' command to activate with ZCP1 selection. (In canned cycles).
Modified to drill first hole at sub routine, not main program.
Changed literal '#Loop' RepCycs' to '#Loops' Parts#' in OpenMP. (The number of loops).
Added 'SetZero' ShiftPC EOL and 'SetZero' UnshftPC EOL to CloseMP. (SetZero = G92).
KC}

{4/23/98, Changed 'Inc' to 'Incr' where Incr is output in posted file. Machine reads these commands
and in "Anilam" language incremental must be spelled Incr. e.g. 'Dim Incr'.
KC}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(ClearancePlane1#,4);
FORMAT(ClearancePlane2#,4);
FORMAT(ClearancePlane3#,4);
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(FeedContour#,4)
FORMAT(FeedEntry#,4)
FORMAT(ArcFeed#,4)
FORMAT(DecelFeed#,4)
FORMAT(ZDepth#,4);
FORMAT(Peck#,4);
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(Dwell#,4) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'* SUB NUMBER: ' Program# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'* OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'* ' OperationComment$ EOL
END
IF WorkGroupComment?
'* ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'* TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'* ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
'Line' ZIn ' Feed' FeedEntry# EOL
ELSE
'Rapid' ZIn EOL
END
RETURN

StartSub:
OpenSub
'Sub' Program# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
'* ' EOL
'* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
'* ' EOL
END
END
RETURN

StdSub:
'Loop Sub#' Program# ' #Loops' RepCycs ' XIncr' RepeatX# ' YIncr' RepeatY# EOL
StartSub
RETURN

ckCRCOffC:
IF CutterRadiusCompensation? { does this operation use CRC? }
IF Flag?('2') { does CRC need to be turned off? }
SetFlagF('2')
' ToolComp Off'
END
END
RETURN

FinishSub1: {part 1}
IF FeedConnect?
ckCRCOffC EOL
ELSE
IF AutoCycle?
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
'Rapid' ZCP3C
END
ckCRCOffC EOL
ELSE
IF FIFO? {.81}
'Line' ZCP3C ckCRCOffC ' Feed' FeedEntry# EOL
ELSE
'Rapid' ZCP3C ckCRCOffC EOL
END
END
END
RETURN

FinishSubG92: {part 2}
'EndSub' EOL
CloseSub
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
'Loop Sub#' Program# ' #Loops' Parts# ' XIncr' PartShiftX# ' YIncr' PartShiftY# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
'SetZero' ShiftPC EOL
'EndSub' EOL
CloseSub
'SetZero' UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
'Dim Incr' EOL
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
'Dim Abs' EOL
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
SetInc
'Dim Incr' EOL
ELSE
IF NOT SPZMove? AND NOT AbsValue?
SetAbs
'Dim Abs' EOL
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
'Dim Abs' EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
'Arc Cw'
ELSE
'Arc Ccw'
END
MoveXYZC
IF XYPlane?
' XCenter' ArcI# ' YCenter' ArcJ#
ELSE
IF XZPlane?
' XCenter' ArcI# ' ZCenter' ArcJ#
ELSE
' YCenter' ArcI# ' ZCenter' ArcJ#
END
END
' Feed'
RETURN

ckCRC:
IF CutterRadiusCompensation? { does this operation use CRC? }
IF LastFeat? { Exit Length Feature }
IF Flag?('2') { does CRC need to be turned off? }
SetFlagF('2')
MoveXYZC
' ToolComp Off'
END
ELSE
IF NOT ZMove?
IF NOT Flag?('2') { does CRC need to be turned on? }
SetFlag('2')
MoveXYZC
IF CRCLeft?
' ToolComp Left'
ELSE
' ToolComp Right'
END
END
END
END
END
RETURN

FormatLine:
DoAbsOrInc 'Line' ckCRC MoveXYZC ' Feed'
RETURN

ckCRCNum:
{ Not Supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
MoveSXYC EOL
'Call' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
DoAbsOrInc 'Rapid' ckCRC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
FormatLine FeedContour# EOL
DecelMove2
END
FormatLine DecelFeed# EOL
ELSE
FormatLine FeedContour# EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
FormatArc ArcFeed# EOL
DecelMove2
END
FormatArc DecelFeed# EOL
ELSE
FormatArc ArcFeed# EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{ Note: This Post Processor does not support Work Fixture Offsets }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
'Dim Incr' EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbsOrInc
IF AbsoluteMoves?
'Dim Abs' EOL
END
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
'Line' ZCP2 ' Feed' FeedEntry# EOL
ELSE
'Rapid' ZCP2 EOL
END
END
'EndSub' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
IF FeedConnect?
'Line' StrtPos EOL
ELSE
'Rapid' StrtPos EOL
END
Milling
FinishSub1
FinishSubG92
RETURN

AbsOrInc:
IF AbsoluteMoves?
' Dim Abs'
ELSE
' Dim Incr'
END
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
'Line Feed' FeedEntry# ' Dim Incr' StrtPosC EOL
END
'Line' AbsOrInc ZInPlusInc ' Feed' FeedEntry# EOL
ELSE
'Line' ZInPlusInc ' Feed' FeedEntry# EOL
END
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
'Rapid Dim Incr' StrtPosC EOL
IF FeedEntry?
'Rapid' AbsOrInc ZCP2PlusInc EOL
'Line' ZInPlusInc ' Feed' FeedEntry# EOL
ELSE
'Rapid' AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
'Rapid' ZCP2PlusInc EOL
'Line' ZInPlusInc ' Feed' FeedEntry# EOL
ELSE
'Rapid' ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
'Line' ZInPlusInc ' Feed' FeedEntry# EOL
ELSE
'Rapid' ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
'Call' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
'Line' ZCP2 ' Feed' FeedEntry# EOL {.69}
ELSE
'Rapid' ZCP2 EOL {.69}
END
END {.69}
'EndSub' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
IF FeedConnect?
'Line' StrtPos EOL
ELSE
'Rapid' StrtPos EOL
END
END
IF FeedConnect?
'Line' ZInPlusInc ' Feed' FeedEntry# EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
'Rapid' ZCP2PlusIncC EOL
END
'Line' ZInPlusInc ' Feed' FeedEntry# EOL
ELSE
'Rapid' ZInPlusInc EOL
END
END
'Call' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
'EndSub' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
SetLowerCaseOK
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CutterRadiusCompensation }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
'* ' EOL
'* This Post Processor does not support WorkFixture Offsets.' EOL
'* Please select Equally Spaced Offsets.' EOL
'* ' EOL
END
END

EachOp {Start of post processing *********************}
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'* PROGRAM: ' ProgramName$ EOL
END
IF ProgramComment?
'* ' ProgramComment$ EOL
END
IF FormatNameComment?
'* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'* OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'* FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SetAbsOrInc
IF AbsoluteMoves?
'Dim Abs' EOL
ELSE
'Dim Incr' EOL
END
IF ToolChangeAtHome?
'Rapid' Home EOL
END
'Tool#' Tool# EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
'Rapid' StrtPos EOL
ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
'Rapid' StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
'Tool# 0' EOL
'Rapid' ' Z0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
'Rapid' Home EOL
END

{Start new Operation}

'Tool#' Tool# EOL
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
'Rapid' StrtPos EOL
ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
'Rapid' StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
'Tool# 0' EOL
'Rapid' ' Z0' EOL

{Start new Operation}

GetStartOfSameTool
'Rapid' StrtPos ZCP1 EOL
ELSE
IF NewToolOffset?
'Tool# 0' EOL
'Rapid' ' Z0' EOL

{Start new Operation}

GetStartOfSameTool
'Rapid' StrtPos EOL
ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
'Rapid' StrtPos EOL
END
END
END
END
END {common point for all operations}
IF Milling?
ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
'Rapid' ZCP3C EOL
ELSE
IF FIFO? {.81}
'Line' ZCP3C ckCRCOffC ' Feed' FeedEntry# EOL
ELSE
'Rapid' ZCP3C ckCRCOffC EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
'Rapid' StrtPos EOL
END
GetCycle
IF PeckFullRetract? or PeckChipBreaker?
'PeckDrill ZDepth' ZDepth# ' StartHgt' ClearancePlane2# ' Peck' Peck# ' Feed' FeedEntry#
ELSE
IF Dwell?
'Boring ZDepth' ZDepth# ' StartHgt' ClearancePlane2# ' Dwell' Dwell# ' Feed' FeedEntry#
ELSE
'BasicDrill ZDepth' ZDepth# ' StartHgt' ClearancePlane2# ' Feed' FeedEntry#
END
END
IF RetractToCP1?
' ReturnHgt' ClearancePlane1#
END
EOL
IF CallMasterOp?
'Call' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
'Call' Program# EOL
StartSub
StrtPos EOL
ToolPath
'EndSub' EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
StrtPos EOL
ToolPath
END
END
SetDrillEndOpZ
'DrillOff' EOL
'Rapid' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
'Tool# 0' EOL
'Rapid' ' Z0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
'Rapid' FirstHome EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
'EndMain' EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'* FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'* FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'* FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END