{12/15/88 TF change XYZ from conditional, 'T0Z1.' from T0Z0}
{6/4/89 force EPs on arcs, and in proper planes, WFG}
{7/16/89 cust requests, for Visual Technics, also Metric, Postscript, multiple parts}
{7/27/89, G29 before all E's, WFG}
{9/11/89, repeats with weird origin shift WFG}
{9/14/89, fix SepSubs, WFG}
{10/30/89, shift of arc IJ's with long hand repeats & rapid/feed prob, WFG}
{10/30/89, needs 3.19alpha6 to run, WFG}

{4/20/90
Modified: Anilam Crusader (VT) M220.67
Re-Wrote drilling section to include more cycles & retract to ZCP1
Moved DoPostScript to before TCZ# command for proper operation.
Fix problem, missing G1 for RepZ op feed connect.
Jim Radcliffe}

{4/24/90, Update: Anilam Crusader (VT) M220.68 to .71.2 format, JR}
{4/27/90, Modified: Anilam Crusader (VT) M220.71.2, added 'ENGLISH' to Moves header comment, JR}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{3/7/91
Modified: Anilam Crusader (VT) M220.72
Added ###.##;0. in the Default Formats dialog in the form, for FeedEnt and FeedRate.
There was no FORMAT for these two commands, and the result was a bunch of zeros on one line, and
all EOLs were ignored until ncPost exited ToolPath, and output the move to ZCP3.
DWB}

{4/03/91
Modified: Anilam Crusader (VT) M220.72.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{11/13/91
Modified: Anilam Crusader (VT) M220.79
For: Visual Technic
Added FORMAT #7 = '00' for TLNum# to output 4 digits at all times. And changed
the literal 'G29T100' to 'G29T0'.
Kim Michelman}

{03/18/92
Modified: Anilam Crusader (VT) M220.79.1
For: Visual Technic
Retyped the 'G29E' at the end of the prog, for some reason was only reading the 'E'.
Kim Michelman}

{03/19/92
Modified: Anilam Crusader (VT) M220.79.2
For: Visual Technic
Changed the EndSub in the form to read G29, and added a literal 'E' at the
end of the the subs being called and changed the literal 'G29E' at end of the program.
Kim Michelman}

{8/14/92
Modified: Anilam Crusader (VT) M220.79.3
For: Visual Technic
Changed PeckValue to Peck# and Formated to #2.
Changed the Dwell# Format to #2.
Updated the PSStuff.
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Kim Michelman}

{9/18/92
Modified: Anilam Crusader (VT) M220.81.1
For: Visual Technic
Added OptCyc1 boolean for postscript. Customer requested 'M1000' & 'M2000'.
Kim Michelman}

{11/13/92
Copied & modified: Anilam Crusader (VT) M220.81.3
For: Hughes Aircraft Co / Mike D
Control: Anilam Crusader Series M
Machine: Bridgeport
Moved Home to line by itself after TCZ#.
Changed TCZ default to 0.
Turn of CRC on last feature in tool path, using ncCAM 4.19.13
Added DoOpComments for 1st operation MultiplePart OneToolAllParts ExitClearancePlane.
Jim Radcliffe}

{8/2/94
Copied & modified: Anilam Series M M530.81.4
For: Precision Enhanced Products
Control: Anilam Crusader Series M
Machine: Bridgeport
Moved Z approach move to line after XY approach.
Change tool dia. and length info at start of program.
Eliminate M1313 and M1314. These are only for Crusader II.
Forced OptCyc1.
Changed Seq to SeqLab to force renumber upon Reseq.
Dan Pilone}

{19Jan98
Original: Anilam Series M [PEP] M698.81.5
Created: Anilam Series M [PEP] M698.89
For: Pasco Scientific
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Updated to .89 Format
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '0.00'
#2 = '###.####;0.'
#3 = '###;0'
#4 = '##^'
#5 = '###.###;0.'
#6 = '*###.###;0.'
#7 = '00'
#8 = '#######0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(TLDia#,2)
FORMAT(TLLength#,2)
FORMAT(TCZ#,2)
FORMAT(ClearancePlane1#,2)
FORMAT(ToolLength#,2)
FORMAT(FeedEntry#,2)
FORMAT(ClearancePlane2#,2)
FORMAT(CurOriginPosX#,2)
FORMAT(CurOriginPosY#,2)
FORMAT(Peck#,2)
FORMAT(Tool#,8)
FORMAT(TLNum#,7)
FORMAT(CallMasterNum#,8)
FORMAT(PartNum#,8)
FORMAT(Tag#,8)
FORMAT(Program#,8)
FORMAT(Operation#,8)
FORMAT(Parts#,8)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
{OptCyc1F} { M1000/M2000 Look Ahead Mode }
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,5)
SeqLab 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,6)
SeqLab 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,5)
SeqLab 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,6)
SeqLab 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab Feed ZIn FeedEnt EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

ExitMove:
SeqLab
IF FeedConnect?
IF NOT AutoCycle?
IF NOT NoZMoves?
FeedC ZInC FeedEntC
END
END
ELSE
CRCOffC
IF FIFO? { .81 }
FeedC
ELSE
RapidC
END
PRIME ZCP2C
IF FIFO? { .81 }
FeedEntC
END
END
EOL
RETURN

StartSub:
OpenSub
DoSubComment
SeqLab 'G29S' Tag# EOL
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

SubWarning:
IF NOT FeedConnect? AND UseComments?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
EachRep
IF NOT FirstCycle?
SeqLab 'M1101' EOL
SeqLab 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' ToolLength# EOL
END
SeqLab 'G29C' Tag# EOL
NextRep
StartSub
RETURN

FinishSub1: {part 1}
SeqLab CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLab EndSub 'E' EOL
TagDown
CloseSub
SeqLab 'M1101' EOL
SeqLab 'X0Y0Z' ToolLength# EOL
RETURN

ATOPSubs: { AllToolsOnePart }
EachPart
EachOp
IF FirstOperation? OR NewTool?
TagInc
IF FirstOperation?
IF UseComments?
'( Part# ' PartNum# ' )' EOL
END
IF NOT FirstPart?
SeqLab 'M1101' EOL
SeqLab 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' ToolLength# EOL
END
ELSE
IF LAST ProgStop?
SeqLab 'M0' EOL
ELSE
SeqLab ProgStop EOL
END
END
SeqLab 'G29C' Tag#
IF UseComments? AND ToolTypeComment?
' ( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
EOL
END
IF Milling?
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
TagInc
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
TagInc
END
END
END {end Auto Cycle IF}
ELSE
IF AutoCycle?
TagInc
END
END {end Z only IF}
ELSE
IF AutoCycle?
TagInc
END
END
END
NextOp
TagInit TagInc
NextPart
RETURN

OpenMP:
IF EquallySpacedOffsets?
TagUp TagInc
IF OneToolAllParts?
EachPart
IF NOT FirstPart?
SeqLab 'M1101' EOL
SeqLab 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' ToolLength# EOL
END
SeqLab 'G29C' Tag# EOL
NextPart
END
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLab EndSub 'E' EOL
TagDown
CloseSub
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLab AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArc
ELSE
CCWArc
END
IF XYPlane?
MoveX MoveY MoveZC { force endpoints in proper plane }
ELSE
IF XZPlane?
MoveX MoveZ MoveYC
ELSE
MoveY MoveZ MoveXC { YZ plane }
END
END
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

FormatLine:
DoAbsOrInc ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
{ Not Supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLab MoveSXYC EOL
SeqLab 'G29C' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLab DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
IF Tap? {uses subs}
SeqLab 'G29C' Tag# EOL
END
END
ELSE
IF RapidFeat?
IF OptCyc1? AND Flag?('2')
SetFlagF('2')
SeqLab 'M2000' EOL { Look Ahead Off }
END
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF OptCyc1? AND NOT Flag?('2')
SetFlag('2')
SeqLab 'M1000' EOL { Look Ahead On }
END
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatLine FeedRateC EOL
DecelMove2
END
SeqLab FormatLine DecelFeed EOL
ELSE
SeqLab FormatLine FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastFeat? AND LastQuadrant?
SeqLab CRCOffC FormatArc ArcFeedC EOL
ELSE
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab CRCOnC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLab CRCOnC FormatArc DecelFeed EOL
ELSE
SeqLab CRCOnC FormatArc ArcFeedC EOL
END
END
NEXTQuadrant
END
END
END
END
NEXTFeat
IF OptCyc1? AND Flag?('2')
SetFlagF('2')
SeqLab 'M2000' EOL { Look Ahead Off }
END
RestoreAbsOrInc
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLab AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLab EndSub 'E' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

XYZRep:
CycleWarning
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
CRCOffC
IF FeedConnect?
SeqLab FeedC StrtPosC FeedEntC EOL
IF ZShiftOnly?
EntryMove
END
ELSE
SeqLab RapidC StrtPosC EOL
IF FeedEntry?
SeqLab ZCP2C EOL
END
EntryMove
END
END
ToolPath
ExitMove
NextRep
RETURN

G92Sub:
IF MultipleParts? AND EquallySpacedOffsets? { LongHand, no double Shifting }
IF AutoCycle?
SubWarning
Milling
SetPass2
TagUp
EachRep
IF NOT FirstCycle?
EACHFeat
SeqLab MoveSX MoveSY EOL
SeqLab 'G29C' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
NEXTFeat
END
NextRep
TagDown
ELSE
IF UseComments?
' ' EOL
'( THIS REPEAT OP WILL BE LONGHAND DUE TO MULTIPLE PARTS )' EOL
' ' EOL
END
XYZRep
END
ELSE
TagUp TagInc
SubWarning
StdSub
SeqLab AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
END
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Feed IncValue StrtPosC EOL
SeqLab AbsOrInc
ELSE
SeqLab Feed
END
ELSE
SeqLab Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLab AbsOrInc ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLab Rapid ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab 'G29C' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLab Feed ZCP2 FeedEnt EOL
ELSE
SeqLab Rapid ZCP2 EOL
END
END
SeqLab 'G29E' EOL
TagDown
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab Connect StrtPos EOL {added Connect}
END
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL {changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLab 'G29C' Tag# EOL
NextCycle
SetStatusRapid {force next G1,G2,G3,etc.}
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab 'G29E' EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
TagInc
ReverseXZArcs
SetTCZ('0')
OptCyc1F
UseSeparateSubCalls
SetMaxSeparateSubCalls('1000')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { OptCyc1 M1000/M2000 Look Ahead Mode }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' TCZ(), TOOLCHANGEZ() -' EOL
' Set the Toolchange Z value. Modal, changes all following OPs.' EOL
' Value is set to Z0 as a default.' EOL
' OptCyc1, OptionalCycle1 -' EOL
' For the selected operation to use look ahead.' EOL
END

EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
END
OpenSub
RestoreScale
Plane { No Output }
{'N0'} SeqLab Rapid Plane 'G70' AbsValue EOL
EachTool
SeqLab 'G29T10' TLNum# 'X0.' {TLDia#} 'Z0.' {TLLength#} EOL
NextTool
SeqLab 'T0' EOL
EachOp
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
DoPostScript
SeqLab 'Z' TCZ# EOL
IF ToolChangeAtHome?
SeqLab Home EOL
END
END
NextOp

IF MultipleParts?
IF WorkFixtureOffsets?
' ' EOL
'( THIS POST PROCESSOR DOES NOT SUPPORT WORKFIXTURE OFFSETS )' EOL
'( PLEASE SELECT EQUALLY SPACED OFFSETS )' EOL
' ' EOL
ELSE { EquallySpacedOffsets }
IF AllToolsOnePart?
ATOPSubs
END
END
END

EachOp {Start of post processing *********************}
IF FirstOperation?
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
SeqLab OpToolID EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab AbsOrInc StrtPos EOL
SeqLab 'Z' ClearancePlane1# EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqLab Rapid StrtPos EOL
END
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab 'T0' EOL
DoEndOpPS
DoPostScript
SeqLab 'Z' TCZ# EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF ToolChangeAtHome?
SeqLab Rapid Home EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END

{Start new Operation}

Plane { No Output }
IF MultipleParts? AND AllToolsOnePart?
OpenMP
DoOpComments
ELSE
DoOpComments
IF LAST ProgStop?
SeqLab 'M0' EOL
ELSE
SeqLab ProgStop EOL
END
END
SeqLab OpToolID EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab Rapid StrtPos EOL
SeqLab 'Z' ClearancePlane1# EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqLab Rapid StrtPos EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab OfstOff EOL
SeqLab 'G4' EOL

{Start new Operation}

GetStartOfSameTool
SeqLab Plane Rapid StrtPos EOL {add plane}
SeqLab OfstOn EOL
ELSE
IF NewToolOffset?
SeqLab OfstOff EOL

{Start new Operation}

GetStartOfSameTool
SeqLab Plane Rapid StrtPos EOL {add plane}
SeqLab OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLab Plane Rapid StrtPos EOL {add plane}
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
TagUp TagInc
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
TagUp TagInc
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLab FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqLab RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqLab AbsOrInc Connect StrtPos EOL
END
SeqLab DrillCP EOL
GetCycle
IF Tap?
TagUp TagInc
StartSub
SeqLab Feed ZDepth 'F' FeedEntry# EOL
SeqLab 'M4' EOL
SeqLab 'Z' ClearancePlane2# EOL
SeqLab 'M3' EOL
SeqLab Rapid EOL
SeqLab 'G29E' EOL
CloseSub
TrackZNO# FIRST SPZ#
ToolPath
SetDrillEndOpZ
SeqLab Rapid ZCP3C EOL
TagDown
ELSE
SeqLab 'G29LV20 ' FeedEntry# EOL
SeqLab 'G29LV21 ' ClearancePlane2# EOL
IF Dwell?
SeqLab 'G29LV22 ' Dwell# EOL
END
IF Peck?
SeqLab 'G29LV23 ' Peck# EOL
END
IF RetractToCP1?
SeqLab 'G29LV24 ' ClearancePlane1# EOL
END
IF FIFO? AND Dwell?
SeqLab 'G89' EOL
ELSE
SeqLab Cycle EOL
END
SeqLab 'G1' ZDepth EOL
SeqLab StrtPos EOL
IF CallMasterOp?
SeqLab 'G29C' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
TagUp
NewMasterTag
SeqLab 'G29C' Tag# EOL
StartSub
ToolPath
SeqLab EndSub 'E' EOL
TagDown
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLab 'G80' EOL
SeqLab Rapid ZCP3C EOL
END
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab 'T0' EOL
DoEndOpPS
SeqLab 'Z' TCZ# EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLab Rapid FirstHome EOL
END
IF ProgStop?
SeqLab 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab EndSub 'E' EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END