{Change Comments ***********************************************************}

{10/30/95, M530.81.5, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, DWB}
{1/17/96 - Updated .85 to .86 format, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Recall#,4)
FORMAT(CurOriginPosX#,4)
FORMAT(CurOriginPosY#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(FeedEntry#,4)
FORMAT(Peck#,4)
FORMAT(TCZ#,4)
FORMAT(TLDia#,4)
FORMAT(TLLength#,4)
FORMAT(ToolLength#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(PartNum#,5)
FORMAT(Tag#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(TLNum#,6)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
RotateF
{OptCyc1F} { M1000/M2000 Look Ahead Mode }
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
Seq 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
Seq 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
Seq 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
Seq 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
Seq PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
Seq EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
Seq Feed ZIn FeedEnt EOL
ELSE
Seq RapidC ZIn EOL
END
RETURN

ExitMove:
Seq
IF FeedConnect?
IF NOT AutoCycle?
IF NOT NoZMoves?
FeedC ZInC FeedEntC
END
END
ELSE
CRCOffC
IF FIFO? { .81 }
FeedC
ELSE
RapidC
END
PRIME ZCP2C
IF FIFO? { .81 }
FeedEntC
END
END
EOL
RETURN

StartSub:
OpenSub
DoSubComment
Seq 'G29S' Tag# EOL
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

SubWarning:
IF NOT FeedConnect? AND UseComments?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
EachRep
IF NOT FirstCycle?
Seq 'M1101' EOL
Seq 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' ToolLength# EOL
END
Seq 'G29C' Tag# EOL
NextRep
StartSub
RETURN

FinishSub1: {part 1}
Seq CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
Seq EndSub 'E' EOL
TagDown
CloseSub
Seq 'M1101' EOL
Seq 'X0Y0Z' ToolLength# EOL
RETURN

ATOPsubs: { AllToolsOnePart }
EachPart
EachOp
IF FirstOperation? OR NewTool?
TagInc
IF FirstOperation?
IF UseComments?
'( Part# ' PartNum# ' )' EOL
END
IF NOT FirstPart?
Seq 'M1101' EOL
Seq 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' ToolLength# EOL
END
ELSE
IF LAST ProgStop?
Seq 'M0' EOL
ELSE
Seq ProgStop EOL
END
END
Seq 'G29C' Tag#
IF UseComments? AND ToolTypeComment?
' ( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
EOL
END
IF Milling?
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
TagInc
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
TagInc
END
END
END {end Auto Cycle IF}
ELSE
IF AutoCycle?
TagInc
END
END {end Z only IF}
ELSE
IF AutoCycle?
TagInc
END
END
END
NextOp
TagInit
NextPart
RETURN

OpenMP:
IF EquallySpacedOffsets?
TagUp TagInc
IF OneToolAllParts?
EachPart
IF NOT FirstPart?
Seq 'M1101' EOL
Seq 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' ToolLength# EOL
END
Seq 'G29C' Tag# EOL
NextPart
END
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
Seq EndSub 'E' EOL
TagDown
CloseSub
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
Seq AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArc
ELSE
CCWArc
END
IF XYPlane?
MoveX MoveY MoveZC { force endpoints in proper plane }
ELSE
IF XZPlane?
MoveX MoveZ MoveYC
ELSE
MoveY MoveZ MoveXC { YZ plane }
END
END
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

FormatLine:
DoAbsOrInc ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
{ Not Supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
Seq MoveSXYC EOL
Seq 'G29C' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
Seq DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
IF Tap? {uses subs}
Seq 'G29C' Tag# EOL
END
END
ELSE
IF RapidFeat?
IF OptCyc1? AND Flag?('2')
SetFlagF('2')
Seq 'M2000' EOL { Look Ahead Off }
END
IF XMove? OR YMove? OR ZMove?
Seq DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF OptCyc1? AND NOT Flag?('2')
SetFlag('2')
Seq 'M1000' EOL { Look Ahead On }
END
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
Seq FormatLine FeedRateC EOL
DecelMove2
END
Seq FormatLine DecelFeed EOL
ELSE
Seq FormatLine FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastFeat? AND LastQuadrant?
Seq CRCOffC FormatArc ArcFeedC EOL
ELSE
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
Seq CRCOnC FormatArc ArcFeedC EOL
DecelMove2
END
Seq CRCOnC FormatArc DecelFeed EOL
ELSE
Seq CRCOnC FormatArc ArcFeedC EOL
END
END
NEXTQuadrant
END
END
END
END
NEXTFeat
IF OptCyc1? AND Flag?('2')
SetFlagF('2')
Seq 'M2000' EOL { Look Ahead Off }
END
RestoreAbsOrInc
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
Seq AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{removed RapidC}
{removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
Seq EndSub 'E' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

XYZRep:
CycleWarning
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
CRCOffC
IF FeedConnect?
Seq FeedC StrtPosC FeedEntC EOL
IF ZShiftOnly?
EntryMove
END
ELSE
Seq RapidC StrtPosC EOL
IF FeedEntry?
Seq ZCP2C EOL
END
EntryMove
END
END
ToolPath
ExitMove
NextRep
RETURN

G92Sub:
IF MultipleParts? AND EquallySpacedOffsets? { LongHand, no double Shifting }
IF AutoCycle?
SubWarning
Milling
SetPass2
TagUp
EachRep
IF NOT FirstCycle?
EACHFeat
Seq MoveSX MoveSY EOL
Seq 'G29C' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
NEXTFeat
END
NextRep
TagDown
ELSE
IF UseComments?
' ' EOL
'( THIS REPEAT OP WILL BE LONGHAND DUE TO MULTIPLE PARTS )' EOL
' ' EOL
END
XYZRep
END
ELSE
TagUp TagInc
SubWarning
StdSub
Seq AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
END
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
Seq Feed IncValue StrtPosC EOL
Seq AbsOrInc
ELSE
Seq Feed
END
ELSE
Seq Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
Seq Rapid IncValue StrtPosC EOL
IF FeedEntry?
Seq AbsOrInc ZCP2PlusInc EOL
Seq Feed ZInPlusInc FeedEnt EOL
ELSE
Seq AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
Seq Rapid ZCP2PlusInc EOL
Seq Feed ZInPlusInc FeedEnt EOL
ELSE
Seq Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
Seq Feed ZInPlusInc FeedEnt EOL
ELSE
Seq Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
Seq 'G29C' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
Seq Feed ZCP2 FeedEnt EOL
ELSE
Seq Rapid ZCP2 EOL
END
END
Seq EndSub 'E' EOL
TagDown
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
Seq Connect StrtPos EOL {added Connect}
END
IF FeedConnect?
Seq FeedC ZInPlusInc FeedEnt EOL {changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
Seq RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
Seq Feed ZInPlusInc FeedEnt EOL
ELSE
Seq RapidC ZInPlusInc EOL {added Rapid, reads better} {changed to RapidC, reads better}
END
END
Seq 'G29C' Tag# EOL
NextCycle
SetStatusRapid {force next G1,G2,G3,etc.}
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
Seq EndSub 'E' EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
ReverseXZArcs
SetTCZ('0')
OptCyc1F
UseSeparateSubCalls
SetMaxSeparateSubCalls('1000')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { OptCyc1 M1000/M2000 Look Ahead Mode }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' TCZ(), TOOLCHANGEZ() -' EOL
' Set the Toolchange Z value. Modal, changes all following OPs.' EOL
' Value is set to Z0 as a default.' EOL
' OptCyc1, OptionalCycle1 -' EOL
' For the selected operation to use look ahead.' EOL
END

EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' ENGLISH )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
{IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END}
END
OpenSub
RestoreScale
Plane { No Output }
'N0' Rapid 'G70' AbsValue EOL
EachTool
Seq 'G29T10' TLNum# 'X' TLDia# 'Z' TLLength# EOL
NextTool
Seq 'T0' EOL
EachOp
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
DoPostScript
Seq 'Z' TCZ# EOL
IF ToolChangeAtHome?
Seq Home EOL
END
END
NextOp

IF MultipleParts?
IF WorkFixtureOffsets?
' ' EOL
'( THIS POST PROCESSOR DOES NOT SUPPORT WORKFIXTURE OFFSETS )' EOL
'( PLEASE SELECT EQUALLY SPACED OFFSETS )' EOL
' ' EOL
ELSE { EquallySpacedOffsets }
IF AllToolsOnePart?
ATOPsubs
END
END
END

EachOp {Start of post processing *********************}
IF FirstOperation?
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
Seq OpToolID EOL
CheckPass
Seq AbsOrInc StrtPos ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
Seq Rapid StrtPos EOL
END
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
Seq 'T0' EOL
DoEndOpPS
DoPostScript
Seq 'Z' TCZ# EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF ToolChangeAtHome?
Seq Rapid Home EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END

{Start new Operation}

Plane { No Output }
IF MultipleParts? AND AllToolsOnePart?
OpenMP
DoOpComments
ELSE
DoOpComments
IF LAST ProgStop?
Seq 'M0' EOL
ELSE
Seq ProgStop EOL
END
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
Seq OpToolID EOL
CheckPass
Seq Rapid StrtPos ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
Seq Rapid StrtPos EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
Seq 'T0' EOL
Seq 'Z' TCZ# EOL

{Start new Operation}

GetStartOfSameTool
Seq 'M0' EOL
Seq ToolOfst EOL
Seq Rapid StrtPos ZCP1 EOL
ELSE
IF NewToolOffset?
Seq 'T0' EOL
Seq 'Z' TCZ# EOL

{Start new Operation}

GetStartOfSameTool
Seq ToolOfst EOL
Seq Rapid StrtPos ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
Seq Rapid StrtPos EOL
END
END
END
END
END {common point for all operations}
IF Milling?
Seq ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
TagUp TagInc
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
TagUp TagInc
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
Seq ZCP3C EOL
ELSE
IF FIFO? {.81}
Seq FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
Seq RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
Seq AbsOrInc Connect StrtPos EOL
END
Seq DrillCP EOL
GetCycle
IF Tap?
TagUp TagInc
StartSub
Seq Feed ZDepth 'F' FeedEntry# EOL
Seq 'M4' EOL
Seq 'Z' ClearancePlane2# EOL
Seq 'M3' EOL
Seq Rapid EOL
Seq EndSub 'E' EOL
CloseSub
TrackZNO# FIRST SPZ#
ToolPath
SetDrillEndOpZ
Seq Rapid ZCP3C EOL
TagDown
ELSE
IF RetractToCP1?
Seq 'M1313' EOL
END
Seq 'G29LV20 ' FeedEntry# EOL
Seq 'G29LV21 ' ClearancePlane2# EOL
IF Dwell?
Seq 'G29LV22 ' Dwell# EOL
END
IF Peck?
Seq 'G29LV23 ' Peck# EOL
END
IF RetractToCP1?
Seq 'G29LV24 ' ClearancePlane1# EOL
END
IF FIFO? AND Dwell?
Seq 'G89' EOL
ELSE
Seq Cycle EOL
END
Seq Feed ZDepth EOL
Seq StrtPos EOL
IF CallMasterOp?
Seq 'G29C' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
TagUp
NewMasterTag
Seq 'G29C' Tag# EOL
StartSub
ToolPath
Seq EndSub 'E' EOL
TagDown
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
Seq 'G80' EOL
IF RetractToCP1?
Seq 'M1314' EOL
END
Seq Rapid ZCP3 EOL
END
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
Seq 'T0' EOL
DoEndOpPS
Seq 'Z' TCZ# EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF FIRST ToolChangeAtHome?
Seq Rapid FirstHome EOL
END
IF ProgStop?
Seq 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
Seq EndSub 'E' EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END