{Change Comments ***********************************************************}

{11/13/95, M690.81.8, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, DWB}

{1/5/96
Initial: Anilam 1100 [PMF] M690.85
Created: Anilam 1100 Z Moves M000.85
ForUser: CNCCS / Polo Metal Fab
Control: Anilam 1100
Machine: Same as the M690 processor except this one has Z moves
Develop: ComPost 4.21.33, Catalyst68K v2.30.22C
Comment: Added Z moves support & Drilling Cycles. Modified Multiple Part & Repeat handling.
Jim Radcliffe}

{1/31/96
Initial: Anilam 1100 Z Moves M000.85
Created: Anilam 1100 Z Moves M925.85 {ID per Pete Jackson}
ForUser: CNCCS / Polo Metal Fab
Develop: ComPost 4.21.33, Catalyst68K v2.30.27C
Comment: Changed Tap feed value from Lead to TPI.
Jim Radcliffe}

{3/13/96, Updated Anilam 1100 Z Moves M925.85 to .86 format, JR}
{7/31/96, .86.1, Changed 'Dim Inc' to 'Dim Incr', added suppression of beginning program lines, JR}

{7/31/96
Initial: Anilam 1100 Z Moves M925.86
Created: Anilam 1100 Z Moves M925.86.1
ForUser: Gibbs / T&S Services
ForUser: CNCCS / Polo Metal Fab
Control: Anilam 1100 versions 1.36a, 1.65a, 2.21c and 4.09a
Develop: ComPost2 68k, Catalyst68K v3.04.10.C
Comment: Modifications per conversations with both customers
Changed 'Dim Inc' to 'Dim Incr'
Added suppression of beginning program lines
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Recall#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ClearancePlane3#,4)
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(FeedContour#,4)
FORMAT(FeedEntry#,4)
FORMAT(ArcFeed#,4)
FORMAT(DecelFeed#,4)
FORMAT(ZDepth#,4)
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(ZDepth#,4)
FORMAT(Peck#,4)
FORMAT(Dwell#,4)
FORMAT(Retract#,4)
FORMAT(DIV#,4)
FORMAT(SUB#,4)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'* SUB NUMBER: ' Program# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'* OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'* ' OperationComment$ EOL
END
IF WorkGroupComment?
'* ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'* TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'* ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

FeedEntry:
SetFlag('3') { Conditional FeedRate Flag On }
Save# Num#('2') FeedEntry#
' Feed' Recall# Num#('2')
RETURN

FeedEntryC:
IF NOT Flag?('3') { Is Conditional FeedRate Flag Off? }
FeedEntry
ELSE
IF NOT Equal? Recall# Num#('2') FeedEntry#
FeedEntry
END
END
RETURN

FeedContour:
SetFlag('3') { Conditional FeedRate Flag On }
Save# Num#('2') FeedContour#
' Feed' Recall# Num#('2')
RETURN

FeedContourC:
IF NOT Flag?('3') { Conditional FeedRate Flag Off }
FeedContour
ELSE
IF NOT Equal? Recall# Num#('2') FeedContour#
FeedContour
END
END
RETURN

FeedArc:
SetFlag('3') { Conditional FeedRate Flag On }
Save# Num#('2') ArcFeed#
' Feed' Recall# Num#('2')
RETURN

FeedArcC:
IF NOT Flag?('3') { Conditional FeedRate Flag Off }
FeedArc
ELSE
IF NOT Equal? Recall# Num#('2') ArcFeed#
FeedArc
END
END
RETURN

FeedDecel:
SetFlag('3') { Conditional FeedRate Flag On }
Save# Num#('2') DecelFeed#
' Feed' Recall# Num#('2')
RETURN

FeedDecelC:
IF NOT Flag?('3') { Conditional FeedRate Flag Off }
FeedDecel
ELSE
IF NOT Equal? Recall# Num#('2') DecelFeed#
FeedDecel
END
END
RETURN

EntryMove:
IF FeedEntry?
'Line' ZIn FeedEntry EOL
ELSE
'Rapid' ZIn EOL
END
RETURN

StartSub:
OpenSub
'Sub ' Program# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
'* ' EOL
'* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
'* ' EOL
END
END
RETURN

StdSub:
'Loop Sub# ' Program# ' #Loops ' RepCycs EOL
StartSub
RETURN

ckCRCOffC:
IF CutterRadiusCompensation? { does this operation use CRC? }
IF Flag?('2') { does CRC need to be turned off? }
SetFlagF('2')
' ToolComp Off'
END
END
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
'Rapid' ZCP3C
END
ckCRCOffC EOL
ELSE
IF FIFO? {.81}
'Line' ZCP3C ckCRCOffC FeedEntryC EOL
ELSE
'Rapid' ZCP3C ckCRCOffC EOL
END
END
END
RETURN

FinishSubG92: {part 2}
'SetZero ' ShiftRC EOL
'EndSub' EOL
CloseSub
'SetZero ' UnshftRC EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
'Loop Sub# ' Program# ' #Loops ' Parts# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
'SetZero ' ShiftPC EOL
'EndSub' EOL
CloseSub
'SetZero ' UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
'Dim Incr' EOL
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
'Dim Abs' EOL
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
SetInc
'Dim Incr' EOL
ELSE
IF NOT SPZMove? AND NOT AbsValue?
SetAbs
'Dim Abs' EOL
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
'Dim Abs' EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
'Arc Cw'
ELSE
'Arc Ccw'
END
MoveXYZC
IF XYPlane?
' XCenter' ArcI# ' YCenter' ArcJ#
ELSE
IF XZPlane?
' XCenter' ArcI# ' ZCenter' ArcJ#
ELSE
' YCenter' ArcI# ' ZCenter' ArcJ#
END
END
RETURN

ckCRC:
IF CutterRadiusCompensation? { does this operation use CRC? }
IF LastFeat? { Exit Length Feature }
IF Flag?('2') { does CRC need to be turned off? }
SetFlagF('2')
MoveXYZC
' ToolComp Off'
END
ELSE
IF NOT ZMove?
IF NOT Flag?('2') { does CRC need to be turned on? }
SetFlag('2')
MoveXYZC
IF CRCLeft?
' ToolComp Left'
ELSE
' ToolComp Right'
END
END
END
END
END
RETURN

FormatLine:
DoAbsOrInc 'Line' ckCRC MoveXYZC
RETURN

ckCRCNum:
{ Not Supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
MoveSXYC EOL
'Call ' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
DoAbsOrInc 'Rapid' ckCRC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
FormatLine FeedContourC EOL
DecelMove2
END
FormatLine FeedDecelC EOL
ELSE
FormatLine FeedContourC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
FormatArc FeedArcC EOL
DecelMove2
END
FormatArc FeedDecelC EOL
ELSE
FormatArc FeedArcC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{ Note: This Post Processor does not support Work Fixture Offsets }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
'Dim Incr' EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbsOrInc
IF AbsoluteMoves?
'Dim Abs' EOL
END
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
'Line' ZCP2 FeedEntryC EOL
ELSE
'Rapid' ZCP2 EOL
END
END
'EndSub' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
IF FeedConnect?
'Line' StrtPos EOL
ELSE
'Rapid' StrtPos EOL
END
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
'Dim Incr' EOL
'Line' StrtPosC EOL
SetAbsOrInc
IF AbsoluteMoves?
'Dim Abs' EOL
END
ELSE
'Line'
END
ELSE
'Line'
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
'Dim Incr' EOL
'Rapid' StrtPosC EOL
SetAbsOrInc
IF AbsoluteMoves?
'Dim Abs' EOL
END
IF FeedEntry?
'Rapid' ZCP2PlusInc EOL
'Line' ZInPlusInc FeedEnt EOL
ELSE
'Rapid' ZInPlusInc EOL
END
ELSE
IF FeedEntry?
'Rapid' ZCP2PlusInc EOL
'Line' ZInPlusInc FeedEnt EOL
ELSE
'Rapid' ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
'Line' ZInPlusInc FeedEnt EOL
ELSE
'Rapid' ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
'Call ' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
'Line' ZCP2 FeedEntry EOL {.69}
ELSE
'Rapid' ZCP2 EOL {.69}
END
END {.69}
'EndSub' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
IF FeedConnect?
'Line' StrtPos EOL
ELSE
'Rapid' StrtPos EOL
END
END
IF FeedConnect?
'Line' ZInPlusInc FeedEntry EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
'Rapid' ZCP2PlusIncC EOL
END
'Line' ZInPlusInc FeedEntry EOL
ELSE
'Rapid' ZInPlusInc EOL
END
END
'Call ' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
'EndSub' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
SetLowerCaseOK
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CutterRadiusCompensation }
SetFlagF('3') { Conditional FeedRateC Flag Off }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
'* ' EOL
'* This Post Processor does not support WorkFixture Offsets.' EOL
'* Please select Equally Spaced Offsets.' EOL
'* ' EOL
END
END

EachOp {Start of post processing *********************}
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'* PROGRAM: ' ProgramName$ EOL
END
IF ProgramComment?
'* ' ProgramComment$ EOL
END
IF FormatNameComment?
'* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'* OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'* FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
SetAbsOrInc
IF AbsoluteMoves?
'Dim Abs' EOL
ELSE
'Dim Incr' EOL
END
IF NOT OptionalStops?
{ these lines are suppressed if the Optional Stop check box is checked }
{ this is to support T&S Services who does not want these output }
{ Polo Metal Fab wants these lines and never uses the Optional Stops }
'MCode 9' EOL
'MCode 5' EOL
'Tool# 0' EOL
'Rapid Z0' EOL
IF ToolChangeAtHome?
'Rapid' Home EOL
END
'MCode 0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
'Tool# ' Tool# EOL
DoOpComments
DoPostScript
'MCode 3' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
'MCode 8' EOL
CheckPass
'Rapid' StrtPos EOL
'Rapid' ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
'Rapid' StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
'MCode 9' EOL
'Tool# 0' EOL
'Rapid Z0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
'MCode 5' EOL
IF ToolChangeAtHome?
'Rapid' Home EOL
END
IF LAST ProgStop?
'MCode 0' EOL
END

{Start new Operation}

'Tool# ' Tool# EOL
DoOpComments
DoPostScript
'MCode 3' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
'MCode 8' EOL
CheckPass
'Rapid' StrtPos EOL
'Rapid' ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
'Rapid' StrtPos EOL
END
ELSE
IF SameTool?

{Finish off last Operation}

IF LAST ProgStop? OR CoolOff? AND LAST NOT CoolOff?
'MCode 9' EOL
END
IF LAST ProgStop? OR NewToolOffset?
'Tool# 0' EOL
'Rapid Z0' EOL
END
DoEndOpPS
IF LAST ProgStop?
'MCode 5' EOL
'MCode 0' EOL
END

{Start new Operation}

IF LAST ProgStop? OR NewToolOffset?
'Tool# ' Tool# EOL
END
DoOpComments
DoPostScript
IF LAST ProgStop?
'MCode 3' EOL
END
IF LAST ProgStop? OR NOT CoolOff? AND LAST CoolOff?
'MCode 8' EOL
END
CheckPass
'Rapid' StrtPos EOL
IF LAST ProgStop? OR NewToolOffset?
'Rapid' ZCP1 EOL
END
END
END
END {common point for all operations}
IF Milling?
IF FirstOperation? OR NewTool?
IF NotEqual? ClearancePlane1# ClearancePlane2#
'Rapid' ZCP2 EOL
END
ELSE
IF LAST ProgStop? OR NewToolOffset?
IF NotEqual? ClearancePlane1# ClearancePlane2#
'Rapid' ZCP2 EOL
END
ELSE
IF NotEqual? LAST ClearancePlane3# ClearancePlane2#
'Rapid' ZCP2 EOL
END
END
END
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
'Rapid' ZCP3C EOL
ELSE
IF FIFO? {.81}
'Line' ZCP3C ckCRCOffC FeedEntryC EOL
ELSE
'Rapid' ZCP3C ckCRCOffC EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
'Rapid' StrtPos EOL
END
GetCycle
IF FIRO?
'BasicDrill'
ELSE
IF FIFO?
'Boring'
ELSE
IF Tap?
'Tapping'
ELSE
IF PeckFullRetract?
'PeckDrill'
ELSE
IF PeckChipBreaker?
'ChipBreak'
ELSE
'BasicDrill'
END
END
END
END
END
' ZDepth ' ZDepth# ' StartHgt ' ClearancePlane2#
IF RetractToCP1?
IF NotEqual? ClearancePlane1# ClearancePlane2#
' ReturnHgt ' ClearancePlane1#
END
END
IF PeckFullRetract?
' Peck ' Peck#
END
IF PeckChipBreaker?
' FirstPeck ' Peck# ' PeckDecr 0 MinPeck ' Peck# ' ChipBrkInc ' Retract# ' RetractDep ' SUB# ClearancePlane2# ZDepth#
END
IF Dwell?
' Dwell' Dwell#
END
IF Tap?
' TPIorLead ' DIV# Num#('1') FeedTapIPR#('1')
ELSE
FeedEntry
END
EOL
IF CallMasterOp?
'Call ' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
'Call ' Program# EOL
StartSub
StrtPos EOL
ToolPath
'EndSub' EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
StrtPos EOL
ToolPath
END
END
'DrillOff' EOL
IF RetractToCP1?
IF NotEqual? ClearancePlane1# ClearancePlane3#
'Rapid' ZCP3 EOL
END
ELSE
IF NotEqual? ClearancePlane2# ClearancePlane3#
'Rapid' ZCP3 EOL
END
END
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
'MCode 9' EOL
'Tool# 0' EOL
'Rapid Z0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
'MCode 5' EOL
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
'Rapid' FirstHome EOL
END
IF ProgStop?
'MCode 0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
'EndMain' EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'* FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'* FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'* FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END