{Change Comments ***********************************************************}

{6/1/93
Copied & modified: Fanuc 6M M001.81.2
For: Sim Solutions
Machine:
Control: Anilam 1400
Changes made per sample programs supplied by Bob Ustrepski.
No manual was supplied. I faxed a list of questions, but received no reply. Canned drill cycle
parameters could not be confirmed. Bob said that any standard Fanuc output would work.
Comments start with asterisk.
Deleted WorkFixtureOffset support.
Deleted ToolChng, Speed, OfstOn, OfstOff, CRCOffset.
Added spaces between addresses, and blank lines between subs.
Changed to unconditional I, J and R for Arcs.
DWB}

{1/13/94
Copied & modified: Anilam 1400 M574.81.2
For: Stanford University per John Wadsworth
Control: Anilam 1100 in Machinist Language
This is a 2 axis machine, the Z axis command causes a stop for manual positioning.
Jim Radcliffe}

{3/17/94
Modified: Anilam 1100 M621.81.2
For: Stanford University per John Wadsworth
Deleted sequence numbers, the 1100 cannot have line numbers.
Added ' Dwell 0.0', dwell forever used as program stop at tool changes.
Added StrtPos in Drilling after Cycle line.
Deleted space at beginning of lines.
Jim Radcliffe}

{7/21/94
Modified: Anilam 1100 M621.81.3
For: Gibbs & Associates
Changed 'Line' to 'Rapid' at beginning of program Home move.
Corrected and cleaned up Cutter Radius Compensation handling:
Added LastFeat? to CheckCRC sub to discriminate output of 'ToolComp Off'.
Remove LastFeat? statements from ToolPath:RapidFeat and LineFeat.
Jim Radcliffe}

{12/12/94
Modified: Anilam 1100 M621.81.4
For: Stanford University
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Changes made per John Wadsworth of Stanford University.
Deleted SeqC command at FinishSub1 sub.
Control does not support line numbers.
Added space to literal ' XCenter' at FormatArc sub.
Necessary syntax required.
Modified CutterRadiusCompensation support per Version 4.2.
DWB}

{
Format: Anilam 1100 [NOAO] M738.81.6
1/27/95
Changed format of arcs to use absolute arc centers
Added StartHgt and CalcZSurf# to the drill cycle
Added support for Pecks and Dwells in the drill cycle
TH}

{
Format: Anilam 1100 [NOAO] M738.81.7
2/6/95
Fixed a bug in the drill cycles
TH}

{
Format: Anilam 1100 [NOAO] M738.81.8
2/27/95
Change BoreDrill to Boring
Added 'MCode 5' before Dwell 0.0 in tool changes
Changed the format of Dwell# from 6 to 4
Changed CalcZSurf# in drill cycles to ClearancePlane1#
Added support for ReturnHgt in drill cycles
Fixed a bug with PeckDrill
Formatted ClearancePlane1#, ClearancePlane2#, ClearancePlane3#, Peck#, and ZDepth# to format 4
TH}

{6/6/95
Initial: Anilam 1100 [NOAO] M738.81.8
ForUser: Hughes Space and Communications Company
Control: Anilam S1100 3.10C
Machine: Supermax
Comment: New processor fro marked up readout.
Added 'Tool#0' & 'Rapid Z0' to beginning of program.
Changed ZCP3C to ZCP3 after Drilling.
Added logic, with subs and calls, to make feed rates modal. Using Var#1
Changed shifting for subs called with StdSub and OpenMP:
deleted XIncr YIncr from the call line.
added SetZero to FinishSubG92 and CloseMP. It works same as G92.
Corrected OpenMP, changed RepCycs to Parts.
Corrected FORMATS, formats added 2/27/95 were followed by a semi-colon!?, wouldn't compile!
Jim Radcliffe}

{6/30/95
Initial: Anilam 1100 [HSCG] M805.81.8
Created: Anilam 1100 [HSCG] M805.81.9
ForUser: Hughes Space and Communications Company
Comment: Modified per conversation with Rich
Changed 'Dim Inc' to 'Dim Incr'.
Jim Radcliffe}

{8/3/95
Initial: Anilam 1100 [HSCG] M805.81.9
Created: Anilam 1100 [HSCG] M805.82
ForUser: Hughes Space and Communications Company
Comment: Per conversation with Rich, added spaces in sub call lines.
Jim Radcliffe}

{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Updated .84 version to .87, TH}

{1/8/97
Initial: Anilam 1100 [HSCG] M805.87
Created: Anilam 1100 ProMill Mxxx.87
ForUser: West Falls Machine
Control: Anilam 1100
Maxhine: ProMill-5 ( vertical 2-1/2 axis - manual tool change - manual gear range )
Develop: ComPost 4.21.37PPC, Virtual Gibbs 3.23
Comment: Added M codes for spindle, coolant program stop and program end per fax from Bart Ehlers.
Jim Radcliffe}

{08/21/98,
Initial: Anilam 1100 ProMill MZ99.87
Created: Anilam 1100 ProMill MZ99.87.1
For: West Falls Machine

Changes to Prog:
1) IF Drilling - Added Peck ChipBreaker code.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(FeedContour#,4)
FORMAT(FeedEntry#,4)
FORMAT(ArcFeed#,4)
FORMAT(DecelFeed#,4)
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(Retract#,4)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Program#,5)
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ClearancePlane3#,4)
FORMAT(ZDepth#,4)
FORMAT(Peck#,4)

{Command Subroutines *******************************************************}

StopProgram:
'MCode 0'
RETURN

EndProgram:
'MCode 2'
RETURN

DoSpinOn:
IF CWSpindle?
'MCode 3'
ELSE
'MCode 4'
END
RETURN

DoSpinOff:
'MCode 5'
RETURN

DoCoolOn:
'MCode 8'
RETURN

DoCoolOff:
'MCode 9'
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'* SUB NUMBER: ' Program# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'* OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'* ' OperationComment$ EOL
END
IF WorkGroupComment?
'* ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'* TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'* ' ToolComment$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoFeedEnt:
Save# Num#('1') FeedEntry#
' Feed' FeedEntry#
RETURN

DoFeedEntC:
IF NotEqual? FeedEntry# Recall# Num#('1')
DoFeedEnt
END
RETURN

DoFeedRate:
Save# Num#('1') FeedContour#
' Feed' FeedContour#
RETURN

DoFeedRateC:
IF NotEqual? FeedContour# Recall# Num#('1')
DoFeedRate
END
RETURN

DoArcFeed:
Save# Num#('1') ArcFeed#
' Feed' ArcFeed#
RETURN

DoArcFeedC:
IF NotEqual? ArcFeed# Recall# Num#('1')
DoArcFeed
END
RETURN

DoDecelFeed:
Save# Num#('1') DecelFeed#
' Feed' DecelFeed#
RETURN

EntryMove:
IF FeedEntry?
'Line' ZIn DoFeedEnt EOL
ELSE
'Rapid' ZIn EOL
END
RETURN

StartSub:
OpenSub
'Sub ' Program# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
'* ' EOL
'* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
'* ' EOL
END
END
RETURN

StdSub:
'Loop Sub# ' Program# ' #Loops ' RepCycs EOL
StartSub
RETURN

CheckCRCOffC:
IF CutterRadiusCompensation? { does this operation use CRC? }
IF Flag?('1') { does CRC need to be turned off? }
SetFlagF('1')
' ToolComp Off'
END
END
RETURN

FinishSub1: {part 1}
IF FeedConnect?
CheckCRCOffC EOL
ELSE
IF AutoCycle?
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
'Rapid' ZCP3C
END
CheckCRCOffC EOL
ELSE
IF FIFO? {.81}
'Line' ZCP3C CheckCRCOffC DoFeedEntC EOL
ELSE
'Rapid' ZCP3C CheckCRCOffC EOL
END
END
END
RETURN

FinishSubG92: {part 2}
'SetZero' ShiftRC EOL
'EndSub' EOL
CloseSub
'SetZero' UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
'*** This Processors does not support Work Fixture Offsets ***' EOL
'*** Processed with the Equally Spaced Offsets Values ***' EOL
END
'Loop Sub# ' Program# ' #Loops ' Parts EOL
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
'*** This Processors does not support Work Fixture Offsets ***' EOL
'*** Processed with the Equally Spaced Offsets Values ***' EOL
END
'SetZero' ShiftPC EOL
'EndSub' EOL
CloseSub
'SetZero' UnshftPC EOL
RETURN

FormatArc:
IF ArcCW?
'Arc Cw'
ELSE
'Arc Ccw'
END
MoveXYZC
IF XYPlane?
' XCenter' ArcI# ' YCenter' ArcJ#
ELSE
IF XZPlane?
' XCenter' ArcI# ' ZCenter' ArcJ#
ELSE
' YCenter' ArcI# ' ZCenter' ArcJ#
END
END
RETURN

CheckCRC:
IF CutterRadiusCompensation? { does this operation use CRC? }
IF NOT Flag?('1') { does CRC need to be turned on? }
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
IF NOT ZMove?
SetFlag('1')
MoveXYZC
IF CRCLeft?
' ToolComp Left'
ELSE
' ToolComp Right'
END
END
END
ELSE { does CRC need to be turned off? }
IF LastFeat? { Exit Length Feature }
SetFlagF('1')
MoveXYZC
' ToolComp Off'
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
'Line' CheckCRC MoveXYZC DoFeedRateC EOL
DecelMove2
END
'Line' CheckCRC MoveXYZC DoDecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
'Line' CheckCRC MoveXYZC DoFeedRateC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
MoveSXYC EOL
'Call ' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF AutoCycle?
'Rapid' MoveXYZC
IF LastFeat?
CheckCRCOffC
END
EOL
ELSE
IF ZMove? AND NOT XMove? AND NOT YMove?
'Rapid' MoveXYZC CheckCRCOffC EOL
END
IF XMove? OR YMove? OR ZMove?
'Rapid' MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
'Line' MoveXYZC CheckCRCOffC DoFeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
'Line' MoveXYZC DoFeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
FormatArc DoArcFeedC EOL
DecelMove2
END
FormatArc DoDecelFeed EOL
ELSE
FormatArc DoArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
{ Note: This Post Processor does not support Work Fixture Offsets }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
'Dim Incr' EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbsOrInc
IF AbsoluteMoves?
'Dim Abs' EOL
END
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO? {.81}
'Line' ZCP2 DoFeedEntC EOL
ELSE
'Rapid' ZCP2 EOL
END
END
'EndSub' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
IF FeedConnect?
'Line' StrtPos EOL
ELSE
'Rapid' StrtPos EOL
END
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
'Line Feed' FeedEntry# ' Dim Inc' SetInc StrtPosC EOL
SetAbs
END
'Line' AbsOrInc ZInPlusInc ' Feed' FeedEntry# EOL
ELSE
'Line' ZInPlusInc ' Feed' FeedEntry# EOL
END
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
'Rapid Dim Inc' SetInc StrtPosC EOL
SetAbs
IF FeedEntry?
'Rapid' AbsOrInc ZCP2PlusInc EOL
'Line' ZInPlusInc ' Feed' FeedEntry# EOL
ELSE
'Rapid' AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
'Rapid' ZCP2PlusInc EOL
'Line' ZInPlusInc ' Feed' FeedEntry# EOL
ELSE
'Rapid' ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
'Line' ZInPlusInc ' Feed' FeedEntry# EOL
ELSE
'Rapid' ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
'Call ' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
'Line' ZCP2 DoFeedEnt EOL {.69}
ELSE
'Rapid' ZCP2 EOL {.69}
END
END {.69}
'EndSub' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
IF FeedConnect?
'Line' StrtPos EOL
ELSE
'Rapid' StrtPos EOL
END
END
IF FeedConnect?
'Line' ZInPlusInc DoFeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
'Rapid' ZCP2PlusIncC EOL
END
'Line' ZInPlusInc DoFeedEnt EOL
ELSE
'Rapid' ZInPlusInc EOL
END
END
'Call ' Program# EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
'EndSub' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
SetLowerCaseOK
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { CutterRadiusCompensation }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
Save# Num#('1') Num#('0') {initialize feed rate}
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'* PROGRAM: ' ProgramName$ EOL
END
IF ProgramComment?
'* ' ProgramComment$ EOL
END
IF FormatNameComment?
'* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'* OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'* FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SetAbsOrInc
IF AbsoluteMoves?
'Dim Abs' EOL
ELSE
'Dim Incr' EOL
END
'Tool#0' EOL
'Rapid Z0' EOL
IF ToolChangeAtHome?
'Rapid' Home EOL
END
'Tool#' Tool# EOL
DoOpComments
DoPostScript
DoSpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
'Rapid' StrtPos ZCP1 EOL
DoCoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
'Rapid' StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
DoCoolOff EOL
'Tool# 0' EOL
'Rapid' ' Z0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
'Rapid' Home EOL
END
DoSpinOff EOL
StopProgram EOL

{Start new Operation}

'Tool#' Tool# EOL
DoOpComments
DoPostScript
DoSpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
'Rapid' StrtPos ZCP1 EOL
DoCoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
'Rapid' StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
DoCoolOff EOL
'Tool# 0' EOL
'Rapid' ' Z0' EOL
DoSpinOff EOL
StopProgram EOL

{Start new Operation}

GetStartOfSameTool
DoSpinOn EOL
'Rapid' StrtPos ZCP1 EOL
DoCoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
DoCoolOff EOL
END
IF NewToolOffset?
'Tool# 0' EOL
'Rapid' ' Z0' EOL

{Start new Operation}

GetStartOfSameTool
'Rapid' StrtPos ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
'Rapid' StrtPos EOL
END
IF NOT CoolOff? AND LAST CoolOff?
DoCoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
'Rapid' ZCP3C EOL
ELSE
IF FIFO? {.81}
'Line' ZCP3C CheckCRCOffC DoFeedEntC EOL
ELSE
'Rapid' ZCP3C CheckCRCOffC EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
'Rapid' StrtPos EOL
END
GetCycle
IF Peck?
IF PeckChipBreaker?
'ChipBreak ZDepth' ZDepth# ' StartHgt' ClearancePlane2# ' FirstPeck' Peck# ' PeckDecr0. MinPeck0. ChipBrkInc' Retract# DoFeedEnt
ELSE
'PeckDrill ZDepth' ZDepth# ' StartHgt' ClearancePlane2# ' Peck' Peck# DoFeedEnt
END
ELSE
IF Dwell?
'Boring ZDepth' ZDepth# ' StartHgt' ClearancePlane2# ' Dwell' Dwell# DoFeedEnt
ELSE
'BasicDrill ZDepth' ZDepth# ' StartHgt' ClearancePlane2# DoFeedEnt
END
END
IF NotEqual? ClearancePlane2# ClearancePlane3#
' ReturnHgt' ClearancePlane3#
END
EOL
StrtPos EOL
TrackZNO# FIRST SPZ# {.81.2}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
'DrillOff' EOL
IF Repeats?
FinishSubG92
END
'Rapid' ZCP3 EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
DoCoolOff EOL
'Tool# 0' EOL
'Rapid' ' Z0' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
'Rapid' FirstHome EOL
END
DoSpinOff EOL
IF MultipleParts? AND AllToolsOnePart?
StopProgram EOL { Dwell forever command, needed for tool change }
CloseMP
END
'EndMain' EOL
CloseSub
Post2 {organize Subs into one program}
EndProgram EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'* FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'* FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'* FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END