{Change Comments ***********************************************************}

{1/10/90
Copied & modified: Allen Bradley Hard L019.53
For: Bio-Rad
Machine: Sheldon 1710
Control: Allen Bradley
Front turret consists of tools 1-4 and 9-12.
Front turret situation will have ReverseXZArcs, PosSideLathe, SpinFor and Positive Home.
Rear turret consists of tools 5-8.
Rear turret situation will have StandardXZArcs, NegSideLathe, SpinRev and Negative Home.
NOTE: We need a command to output current 'X' position for use with 'G96' CSSOn.
Control requires block to be 'G96R' CurrXPos# when activating CSS.
DWB}

{2/23/90
Modified: AB Sheldon [-] L141.53
For: Gibbs & Associates
Reversed G02 and G03 in Mach Spec per Joe C.
Updated to Version 3.2 per Fanuc 10T MS [-] L001.69.3 Format.
JR}

{6/1/90
Modified: AB Sheldon [-] L141.69.3
For: Gibbs & Associates
Added CycleStartXRadius# per NOTE of 1/10/90.
DWB}

{6/11/91
Modified: AB Sheldon [-] L141.70
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Changed CycleStartXRadius# to CycleStartX#.
Changed SpinFor and SpinRev to SpinOn as this is handled in 4.0.
Only Canned Cycles supported are Threading and Tapping.
DWB}

{01/14/92
Modified: AB Sheldon [-] L141.80
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1 Format.
Kim Michelman}

{9/7/95, Updated AB Sheldon [-] L141.82.1 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '###.##;0'
#5 = '##.#####;0'
#6 = '###0'
#7 = '00'
#8 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(CycleStartX#,2)
FORMAT(CycleStartZ#,2)
FORMAT(FinishXRadius#,2)
FORMAT(FinishZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(ToolOffset#,7)
FORMAT(RapidF#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC LOfstOff '00' EOL
SeqC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
SeqC SpeedC EOL
ELSE
SeqC Preset MaxRPM EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' Speed EOL
ELSE
SeqC SpeedC EOL
END
END
IF LAST ProgStop?
SeqC SpinOn EOL
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC ArcIJC
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G94G4F2.' EOL
SeqC 'G95' Speed InverseSpinOn EOL
SeqC Feed MoveXC MoveZC FeedRate EOL
ELSE
IF Dwell?
SeqC 'G94G4F' Dwell# EOL
IF RapidFeat?
SeqC 'G95' Rapid MoveXC MoveZC EOL
ELSE
SeqC 'G95' Feed MoveXC MoveZC FeedRate EOL
END
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC FeedRateC EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid1:
CRCOffC
IF LAST CannedCycle?
IF LAST Threading?
IF LAST NOT AutoFinish?
Rapid
END
ELSE
IF LAST Drilling? AND LAST Tap?
Rapid
END
END
ELSE
RapidC
END
RETURN

CheckRapid2:
CRCOffC
IF CannedCycle?
IF Threading?
IF NOT AutoFinish?
Rapid
END
ELSE
IF Drilling? AND Tap?
Rapid
END
END
ELSE
RapidC
END
RETURN

SetUpTurret:
IF ToolOver?('4') AND NOT ToolOver?('8')
StandardXZArcs
NegSideLathe
ELSE
ReverseXZArcs
PosSideLathe
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
XsAreRadii
NoIJKSigns
SetMaxRPM('2000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
'(TN,' Program# ')' EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq Rapid CSSOff AbsOrInc 'G95G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID ToolOffset# SpinOn EOL
SetUpTurret
SeqC Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid1
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' LAST OpExitZCPC CalcRPM2 CoolOff EOL
ELSE
SeqC LAST OpExitZCPC CoolOff EOL
END
DoEndOpPS
SeqC NewHome EOL
SeqC Preset 'X0Z0T0000'
IF LAST ProgStop?
'M0'
ELSE
ProgStop
END
EOL

{Start new Operation}

DoOpComments
DoPostScript
Seq Rapid CSSOff AbsOrInc 'G95G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID ToolOffset# SpinOn EOL
SetUpTurret
SeqC Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid1
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid1
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool?
IF LAST NOT ConstantSurfaceFeed?
SeqC CSSOn 'G96R' CycleStartX# Speed EOL
END
ELSE
SeqC CSSOn 'G96R' CycleStartX# Speed EOL
END
END
IF CannedCycle?
StockOff
IF Threading?
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF Taper?
SeqC 'X' ADD# FinishXRadius# MUL# Taper# NumSc#('1') EOL
SeqC LCycle 'X' FinishXRadius# 'Z' FinishZ# FeedRateC EOL
ELSE
SeqC 'X' FinishXRadius# EOL
SeqC LCycle 'Z' FinishZ# FeedRateC EOL
END
SeqC Rapid 'X' CycleStartX# EOL
SeqC 'Z' CycleStartZ# EOL
END
ELSE
IF Drilling?
IF Tap?
SeqC LCycle ZDepth FeedRateC EOL
SeqC SpinOff EOL
SeqC 'G94G4F2.' EOL
SeqC 'G95' Speed InverseSpinOn EOL
SeqC LCycle ZSP FeedRate EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC EOL
ELSE
SeqC RapidC XOpECDC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC 'X' ADD# FinishXRadius# MUL# Taper# NumSc#('1') EOL
SeqC 'G33'
IF Taper?
'X' FinishXRadius#
END
'Z' FinishZ# FeedRateC EOL
SeqC Rapid XSP EOL
SeqC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G94G4F2.' EOL
SeqC 'G95' Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CheckRapid2
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
IF ConstantSurfaceFeed?
SeqC CSSOff 'G97' OpExitZCPC 'S' CalcEPRPM# CoolOff EOL
ELSE
SeqC 'G97' OpExitZCPC CoolOff EOL
END
DoEndOpPS
SeqC FirstHome EOL
SeqC Preset 'X0Z0T0000' EOP EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END