{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=T
SUBS=T
MILLTURN_POLAR-SEG=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{
10/24/94 [cwh]
B001.81.4 ( from B001.81.3 )

Made changes to ZOnlyRep and FinishSub1 subs to properly handle
Feed connects and clearance moves.
}

{11/8/94
Modified: Fanuc 6M (FW) B001.81.4
For: Gibbs & Associates
Versions: Catalyst v2.14.12C/Compost 4.21.23
Changes made per Pete Jackson
Charles reported a problem involving operations that do not change coordinate systems from
previous operations.
Added ClearCSOffset at NotSameToolWFO and SameToolWFO subs.
DWB}

{
12/01/94
B001.81.6
Changed FirstOp3 to call out A0B0 to move to the first CS.
When possible, this should be changed to check the MDD and only call out the axes that
make sense.

Added RecallWFO sub-routine to NotSameToolWFO and SameToolWFO to ouput the current fixture offset
and A0B0. Added for easier restarts at the machine. Both are only called from NoMPs.
When possible, this should be changed to check the MDD and only call out the axes that
make sense.
}

{
12/02/94
Changed version number to .00 from .81
TH}

{
Format: Fanuc 6M (FW) B001.00.01
12/08/94
Added AAxisAvail? and BAxisAvail? checks to CSAngleA and CSAngleB subs
Added WFO1 and A0B0 if AxisAvail to End2:
TH}

{
Format: Fanuc 6M (FW) B001.00.01
12/09/94
Fixed RecalWFO to check AAxisAvail? and BAxisAvail?
Cleaned up FirstOp3 to use new checks placed in CSAngleA and CSAngleB
TH}

{
Format: Fanuc 6M (FW) B001.00.03
12/19/94
Added ClearCSOffset to OpenMP: CloseMP: and SubCSMP:
Added if AChange? OR BChange? to home postition call-out in SameToolOp1
Started using Flag('3') to determine toggle between incrementing through MPs and decrementing through MPs
Changed CloseMP to check Flag('3'). If true, the WFOs will increment from first to last. If false, the WFOs will
decrement from last to first.
Example:
TRUE for 4 parts: G54P1, G54P2, G54P3, G54P4
FALSE for 4 parts: G54P4, G54P3, G54P2, G54P1
This is most useful for tombstone machining on rotary tables. With this method, the code will machine part1, rotate, part2,
rotate, part3, rotate, part4, tool change, part4, part3, part2, part1, toolchange, etc. It minimizes the rotation and also
stops the machine from "winding up".
To do this a new sub was created called ToggleIncDecWFO. The flag is set to true in ProgStart and toggled inside CloseMP
after running through the parts
Replaced SetZRepInc and RestoreAbsOrInc with one sub called DoAbsOrInc. Any line with SetZRepInc now
has DoAbsOrInc as the first command after the SeqC.
TH}

{
Format: Fanuc 6M (FW) B001.00.04
1/10/95
NewToolOp3 now has an AbsOrInc on the line that calls out the Plane 'G80' CRCOff
NewToolOp5 no longer has the AbsOrInc command
NewToolOp5b has been created and has the AbsOrInc command
Changed MP1ToollAllPfu to call NewToolOp5b
Added AbsOrInc and Rapid to the FirstOperation? section of MP1ToollAllPXcp
Added Rapid to the NewTool? section of MP1ToollAllPXcp
Started using Flag ('4') to turn on Inc/Dec WFO's (See above). True means use Inc/Dec WFO's.
MP1ToollAllPXcp, MP1ToollAllPFU, and MPallTools1P now output WFO if NOT WorkFixtureOffsets?
TH}

{
Format: Fanuc 6M (FW) B001.00.05
1/13/95
Replaced TrackZNO# ZDepth# with TrackZNO# FIRST SPZ# in the drilling section
Formatted TrackZNO# to #4
}

{
Format: Fanuc 6M (FW) B001.00.06
2/15/95
Fixed RecallWFO: to output correct WFO# if WFOCS
TH}

{ Added ClearCSOffset to SubCSMP TH}

{
Format: Fanuc 6M (FW) B001.10
7/27/95
Added G52 style output for too many coordinate systems
Updated to .10 format
TH}

{1/17/96, Updated .10 to .11 version, MPK}

{2/26/96
Initial: Fanuc 6M (FW) B001.11
Created: Fanuc 6M (FW) B001.11.01
Develop: ComPost 4.21.34, Catalyst68K v3.02.02C
Comment: Corrections to Processor.
Corrected format of CSOffsetA# and CSOffsetB#.
To correct multiple parts output:
Added "OR Flag?('2')" to "IF WFOCS?" in "SubCSMP:".
To Simplify prog subs and correct errors in MP1ToollAllPXcp:
Changed FirstOp3a/NewToolOp5a to FirstOp4/NewToolOp6
Deleted NewToolOp5b sub and changed call to NewToolOp5 (they were identical!)
Deleted OfstOn and Cool On from FirstOp3/NewToolOp5
Added calls to FirstOp4/NewToolOp6 after calls to FirstOp3/NewToolOp5.
Changed StrtPos in MP1ToollAllPXcp to FirstOp3/NewToolOp5.
To correct a literal number 2 from being output when processing multiple parts:
Changed order of booleans from:
IF WFOCS? OR Flag?('2')
to:
IF Flag?('2') OR WFOCS?
Modified WFO Handling:
Changes:
Deleted RecallWFO sub. It was not used!
Deleted NotSameToolWFO & SameToolWFO subs.
Added WFOStuff sub.
Changed all WFO calls in main loops to WFOStuff.
Results:
Changes do not effect Multiple Parts output.
Correct WFO is output by default at the beginning of each tool.
G52, if used, is output by default at the beginning of each tool.
G52, without WFO, is output at SameTool only if there is a change.
Jim Radcliffe}

{4/17/96
Initial: Fanuc 6M (FW) B001.11.01
Created: Fanuc 6M (FW) B001.12.01
Comment: Changed version number to reflect new identification scheme.
Jim Radcliffe}

{6/14/96
Initial: Fanuc 6M (FW) B001.12.01
Created: Fanuc 6M (FW) B001.12.02
Comment: Modified CRC handling to reflect the way I do it and same as M001.89.
Jim Radcliffe}

{6/17/96
Initial: Fanuc 6M (FW) B001.12.02
Created: Fanuc 16M Kuraki Cxxx.12
ForUser: Patriot Precision Products
Control: Fanuc 16M
Machine: Kuraki KBM-2000
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New processor per sample readout from and conversation with Jeff Nelson.
Fanuc 0M style subs
W axis used for Drill Operations but set for all operations to fcilitate editing.
Jim Radcliffe}

{2/24/97
Initial: Fanuc 16M Kuraki C123.12
Created: Fanuc 16M Kuraki C123.14
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: Updated to .14 format per Fanuc 6M (PW) C001.14
Jim Radcliffe}

{2/24/97
Initial: Fanuc 16M Kuraki C123.14
Created: Fanuc 16M Kuraki Cxxx.14
ForUser: 3M
Control: Fanuc 15M
Machine: Kuraki KBT-13PDX ( Horizontal )
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: New processor per marked up readout.
Deleted the W axis.
Deleted T codes, manual tool changer!
Simplified handling of AbsOrInc/AbsValue/IncValue with OfstOff with created conditional calls!
Deleted OfstOff when followed by tool change, ToolChng retracts the spindle!
Deleted G30 Y0 at tool changes, ToolChng positions the Y axis!
Deleted move to machine home at end of program.
Jim Radcliffe}

{7Jan99
Original: Fanuc 15M Kuraki KBT CY32.14
Created: Fanuc 15M Kuraki [CGB] CT73.14
For: GC Bretting
Changes made per: Gerry Beebe
Develop: Catalyst 5.03/ComPost2 1.7b13
Added Post Header Comment at the top of Prog.
NEW POST: FIRST DRAFT, Changes to Z Axis. Added W Axis support.
GENERAL CHANGES
Added formatting for ClearancePlane2#, ClearancePlane3#, Num#, Abs#, Sub# and SPZ#
Changed Dwell# from FORMAT#6 to FORMAT#2
Added ToolChng in FirstOp1 and Changed to 'FIRST TOOL NOT IN SPINDLE'
Addd Literal 'M98 P8111' in FirstOp and deleted Safety line.
Deleted G17 thru G19 in MachSpec.
No output is required in FirstOp1 and a Literal is used in NewToolOp3
Added AbsOrInc to StrtPos Line in FirstOp1 and NewToolOp4
Moved WFOStuff and G52Stuff below StrtPos in FirstOp2, NewToolOp4
Added a Boolean to suppress the Safety line when the W axis is not being used, in NewToolOp3
W AXIS SUPPORT
Added support for W axis using the PALLETOUT ( POUT ) PostScript Command.
This causes the post to switch to W axis output.
Z axis is used for all moves to ZCP1. W axis for all moves below ZCP1
Note: Avoided using OptCyc1 because this sets the RigidTap Boolean to TRUE.
Added Subs: DCP2, DCP2C, DCP3, DCP3C, LastDCP3, LastDCP3C, DInPlusInc, DCP2PlusInc
DCP2PlusIncC, DIn, MoveDC, MoveSDC at W Axis Subroutines
Subs are called at various required places throughout Prog.
Added Boolean for PalletOutF at PSInit
Added Boleans in FirstOp3 and NewToolOp5 to suppress CoolOn when the Z axis is not being used.
CoolOn is called when the W Axis moves to ZCP2.
NOTE: NewToolOp1 and END1 only get called in MP_1_ToolAllP_fu.
Because of this, additional W axis functions were added to NewToolOp2 and End2
Added PalletOut Booleans to cancel toolOffsets in NewToolOp2 and End2
Added W axis support in SameToolOp1 and SameToolOp3.
NOTE: Customer has still to provide sample code using Sametool.
This is only an interim, partial solution, whilst he tests this.
Added Custom W-axis drill cycles.
Added Utility Data Instructions at InitProg.
Charles Winston}

{19Jan99
Original: Fanuc 15M Kuraki [CGB] CT73.14
Created: Fanuc 15M Kur [CGB] CT73.14.1
For: GC Bretting
Changes made per: Gerry Beebe
Develop: Catalyst 5.03/ComPost2 1.7b13
Added Formatting for ContourFeed2#, FeedEntry#, TCZ# and Recall# in Prog Numeric Format Definitions
Added PostScript support for TZC Command to overide W-Axis Exit Clearance Plane Value
Enables Customer to avoid Clamps.
Added Booleans in DCP3 Sub, added DoTCZCommentSub, added SetTCZ('0') in PSInit
Added DoTCZComment in FirstOp1, NewToolOp3 and SameToolOp2
Suppressed WFO output when Multiple Parts is FALSE
Changed CWArcC to CWArc and CCWArcC to CCWArc in FormatArc
Changed MoveXYC to MoveXY in ToolPath at RapidFeat and LineFeat. Forces all G0, G1,G2 and G3 co-ordinates to be output
Deleted ckCRCNum Sub. No longer called in ToolPath
Added Custom FeedRates in ToolPath.
*** NOTE ***
This Post outputs a CUSTOMISED FEEDRATE in Toolpath which distinguishes between ENTRY Feedrates and CONTOUR FeedRates
In Particular the ContourFeedrate is output immediately following each Z Move.
Virtual v5.0 now permits editing of ToolPath Feedrates. This post DOES NOT fully Support this feature.
Added doEntryFeedRate, doContourFeedRate and doFeedRate Subs
Added Flag('7'), Flag('8') and Flag('9') to keep track of Feedrate Status.
Added doCRCOn Sub. CRCOffsetC is now called in FirstOp3 and NewToolOp5
Added support for CRCOffsetC in SameToolOp3
Added Support for W-Axis Tap Cycle at Drilling in OpGuts.
Added Support for W-Axis and Z-Axis Bore Cycle at Drilling in OpGuts.
Added Custom Calls for Drilling Subs.
Drilling Subs are created only when there are more than 11 items in ToolPath.
This is equivalent to 10 Holes or more. ( Because the First hole is usually supressesed )
Drilling is output in the main program when there are 9 holes or less. i.e. No subs are created.
Corrected the Q value in the W-Axis FI-RO Drill Cycle. It needs to be the same as thw 'W' value
Created a 3-Axis and 4-Axis VM and HM Mill MDDs and Added support for Customers G86 Bore Cycle ( FI-Stop-RO )
Changed to SetMaxRPM('1300') in ProgStart
Added Utility Data Instructions at ProgStart.
Moved Speed SpinOn after the StrtPos Line in FirstOp2 and NewToolOp4 and SameToolOp3
Deleted IncValueC OfstOff for Z-Axis in NewToolOp2, SameToolOp1 and End1
Deleted CoolOff Booleans in SameToolOp1. Forces CoolOff to be output
Added a Blank Line after ProgStop.
Charles Winston}

{17Feb99
Original: Fanuc 15M Kuraki [CGB] CT73.14.1
Created: Fanuc 15M Kur [CGB] CT73.14.2
For: GC Bretting
Changes made per: Gerry Beebe
Develop: Catalyst 5.03/ComPost2 1.7b15
Added Formatting for Peck# in Prog Numeric Format Definitions.
Added Support for Operator Instructions to be output using PostScript PIN commands.
Supported by doKeyWords, 1stKeyword, 2ndKeyword, 3rdKeyword and 4thKeyword Subs.
Deleted the Contents of DoIndex Sub. Machine has no Indexer. Parts are re-positioned manually.
Added PalletInF and SetPalletIn('0') at pSInit. PIN commands are NON-MODAL
Added Logic to ToolPath to support W-AXIS Drill Clearance Planes with 'G98' and 'G99'
Added support for PeckFullRetract W_AXIS Drill cycle.
Added Utility Data Instructions at ProgStart.
Added doKeyWords in newToolOp2 and sameToolOp1 and End2.
Charles Winston}

{13Mar99
Original: Fanuc 15M Kur [CGB] CT73.14.2
Created: Fanuc 15M Kur [CGB] CT73.14.3
For: GC Bretting
Changes made per: Gerry Beebe
Develop: Catalyst 5.05/ComPost2 1.7b15
Added Post Header Comment at the top of Prog.
Added OperationComment line after SubID in StartSub.
Changed MoveXYC to MoveXY in FormatArc.
Added logic to force Feed, ( G01) onto each line that contains G40, G41 or G42
Modified ckCRC Sub and ToolPath Subs and added doFeedC Sub.
Added Boolean IF SPXMove? OR SPYMove? and changed MoveSXYC to MoveSX MoveSY
in ToolPath Autocycles.
Deleted Custom FeedRates in ToolPath. Post now supports Virtaul v5.0 Utility Markers.
Added NewMasterProg Boolean in Drilling.
Virtual requires NewMasterProg to be called even if a Drill Sub is not being Created.
Deleted EOR at the start of InitOp.
Moved the ProgramComment onto the same line as ProgID1 in InitOp.
Charles Winston}

{5Apr99
Original: Fanuc 15M Kur [CGB] CT73.14.3
Created: Fanuc 15M Kur [CGB] CT73.14.4
For: GC Bretting
Changes made per: Gerry Beebe
Develop: Catalyst 5.09.39/ComPost2 1.7b15
Added additional Logic in doKeyWords Subs.
NewTool, SameTool and End of Prog now handle Coolant Off.
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0'
#3 = '*#####.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^##0'
#7 = '0000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(ContourFeed2#,4)
FORMAT(FeedEntry#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ClearancePlane3#,4)
FORMAT(TCZ#,4)
FORMAT(NUM#,4)
FORMAT(ABS#,4)
FORMAT(SUB#,4)
FORMAT(SPZ#,4)
FORMAT(Peck#,4)
FORMAT(Recall#,5)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Program#,7)
FORMAT(CSSubID#,7)
FORMAT(CallMasterNum#,7)

{W Axis Subroutines *****************}

DCP2:
IF PalletOut?
' W' Sub# ClearancePlane2# ClearancePlane1# { Output the W value for ZCP2 }
TrackZNO# ClearancePlane2# { Set Status Register to ZCP2 }
ELSE
ZCP2
END
RETURN

DCP2C:
LoadFeat Num#('0') Num#('0') ClearancePlane2# { Load ZCP2 }
IF ZMove?
DCP2
END
RETURN

DCP3:
IF PalletOut?
IF NotEqual? TCZ# Num#('0')
' W' TCZ# { Move the W Axis to W=TCZ# }
TrackZNO# ClearancePlane3# { Set Status Register to Z=ZCP3 }
ELSE
' W' Sub# ClearancePlane3# ClearancePlane1# { Output the W value for ZCP3 }
TrackZNO# ClearancePlane3# { Set Status Register to ZCP3 }
END
ELSE
ZCP3
END
RETURN

DCP3C:
LoadFeat Num#('0') Num#('0') ClearancePlane3# { Load ZCP3 }
IF ZMove?
DCP3
END
RETURN

LastDCP3:
IF PalletOut?
' W' Sub# LAST ClearancePlane3# ClearancePlane1# { Output the W value for LAST ZCP3 }
TrackZNO# LAST ClearancePlane3# { Set Status Register to LAST ZCP3 }
ELSE
LAST ZCP3
END
RETURN

LastDCP3C:
LoadFeat Num#('0') Num#('0') LAST ClearancePlane3# { Load LAST ZCP3 }
IF ZMove?
LastDCP3
END
RETURN

DInPlusInc:
IF PalletOut?
' W' ZInPlusInc#
ELSE
ZInPlusInc
END
RETURN

DCP2PlusInc:
IF PalletOut?
' W' Sub# ZCP2PlusInc# ClearancePlane1# { Output the W value for ZCP2PlusInc# }
TrackZNO# ZCP2PlusInc# { Set Status Register to ZCP2PlusInc }
ELSE
ZCP2PlusInc
END
RETURN

DCP2PlusIncC:
LoadFeat Num#('0') Num#('0') ZCP2PlusInc#
IF ZMove?
DCP2PlusInc
END
RETURN

DIn:
IF PalletOut?
IF AbsValue?
' W' Sub# FIRST SPZ# ClearancePlane1# { Output Z from ZCP1 }
ELSE
' W' FIRST SPZ# { Only Output INCREMENTAL Z from ZCP2 }
END
TrackZNO# FIRST SPZ# { Set Status Register to FIRST SPZ# }
ELSE
ZIn
END
RETURN

MoveDC:
IF ZMove? AND PalletOut?
' W' Sub# EPZ# ClearancePlane1#
TrackZNO# SPZ# { Set Status Register to SPZ# }
ELSE
MoveZC
END
RETURN

MoveSDC:
IF SPZMove? AND PalletOut?
'W' Sub# SPZ# ClearancePlane1#
TrackZNO# SPZ# { Set Status Register to SPZ# }
ELSE
MoveSZC
END
RETURN

{Keyword Subroutines *****************}

ckPinNumber: { Sets Flag True if a valid PIN Number is Used }
SetFlagF('23')
IF NotEqual? Pallet# Num#('0')
IF GTEqual? Pallet# Num#('6')
{ Invalid PIN Number }
ELSE
IF LessThan? Pallet# Num#('1')
{ Invalid PIN Number }
ELSE
SetFlag('23')
END
END
END
RETURN

KeyWordProgStop:
SeqC ' M0' EOL
' ' EOL
RETURN

1stKeyword:
KeyWordProgStop
'( CHECK SIZE )' EOL
'( BDS NO.1 DOWN TO REPEAT FINISH CUT )' EOL
'( UP TO CONT )' EOL
'/1 M99 P0000' EOL
RETURN

2ndKeyword:
KeyWordProgStop
'( CHANGE PARTS )' EOL
'( BDS NO.1 DOWN TO REPEAT THIS SETUP )' EOL
'( UP TO CONT )' EOL
'/1 M99 P0000' EOL
RETURN

3rdKeyword:
KeyWordProgStop
'( MOVE CLAMPS )' EOL
RETURN

4thKeyword:
KeyWordProgStop
'( REMOVE CLAMPS )' EOL
'( BOLT THRU MOUNTING HOLES )' EOL
RETURN

5thKeyword:
KeyWordProgStop
'( SET ON BLOCKS )' EOL
'( POSITION TO MILL TOP )' EOL
RETURN

doKeyWords:
IF Equal? Pallet# Num#('1')
1stKeyword
ELSE
IF Equal? Pallet# Num#('2')
2ndKeyword
ELSE
IF Equal? Pallet# Num#('3')
3rdKeyword
ELSE
IF Equal? Pallet# Num#('4')
4thKeyword
ELSE { ProgStop is Executed }
IF Equal? Pallet# Num#('5')
5thKeyword
ELSE { ProgStop is Executed }
IF Flag?('22') {End of Prog}
IF ProgStop?
KeyWordProgStop
END
ELSE
IF SameTool?
IF LAST ProgStop?
KeyWordProgStop
END
ELSE
IF LAST ProgStop?
KeyWordProgStop
ELSE
SeqC ProgStop EOL
' ' EOL
END
END
END
END
END
END
END
END
RETURN

{Prog Subroutine *****************}

restoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

AbsValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

IncValueC:
IF AbsValue?
IncValue
END
RETURN

AbsOrIncC:
IF AbsoluteMoves?
AbsValueC
ELSE
IncValueC
END
RETURN

CSPartNum#:
ADD# CS# MUL# NumOfCS# SUB# PartNum# Num#('1')
RETURN

CSWFO:
IF MultipleParts?
' G' ADD# CSPartNum# Num#('53')
END
RETURN

WFO:
IF MultipleParts?
' G' ADD# PartNum# Num#('53')
END
RETURN

WFOStuff:
IF Flag?('2')
IF NOT SameTool?
IF WFOCS?
CSWFO
ELSE
WFO
END
ELSE
IF WFOCS?
IF ChangeCS?
IF MultipleParts?
{MP ChangeCS is handled in SubCSMP and CloseMP}
ELSE
CSWFO
END
END
END
END
END
SetFlagF('2')
RETURN

CSG52:
' G52 X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ#
RETURN

G52Stuff:
IF NOT MultipleParts?
IF NOT WFOCS?
IF ChangeCS?
SeqC CSG52 EOL
ELSE
IF NOT SameTool?
SeqC CSG52 EOL
END
END
END
ClearCSOffset
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoCSComment:
IF AAxisAvail?
'( CS#' CS# ' - ' CSComment$ ' )' EOL
END
RETURN

DoCSWFOComment:
IF AAxisAvail? OR BAxisAvail?
'( ' CSWFO ' = X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
END
RETURN

OffsetComments:
IF NOT MultipleParts?
IF WFOCS?
IF ChangeCS?
DoCSComment
DoCSWFOComment
END
ELSE
IF ChangeCS?
DoCSComment
ELSE
IF NOT SameTool?
DoCSComment
END
END
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
OffsetComments
RETURN

DoTCZComment:
IF UseComments?
SetScale('1')
IF OperationComment?
IF PalletOut? AND NotEqual? TCZ# Num#('0')
'( W-Axis TCZ = ' TCZ# ' )' EOL
END
END
RestoreScale
END
RETURN

CSAngleA:
IF AAxisAvail?
' A' CSOffsetA#
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
' B' CSOffsetB#
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoIndex:
{ '( Rotate Part )' }
RETURN

Index:
IF AAxisAvail? OR BAxisAvail?
IF AChange? OR BChange?
DoIndex
END
END
RETURN

PSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
PalletInF
SetPalletIn('0')
SetTCZ('0')
IF FirstOperation?
PalletOutF { Used to activate the W axis }
END
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed DIn FeedEnt EOL
ELSE
SeqC RapidC DIn EOL
END
RETURN

StartSub:
OpenSub
' ' EOL
SubID EOL
IF OperationComment?
' ( ' OperationComment$ ' )' EOL
END
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLabB RepCycs Program# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
DCP3C
ELSE
IF FIFO?
FeedC DCP3C FeedEntC
ELSE
RapidC DCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
SeqC SubCall CallLabB Parts Program# EOL
IF ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
StartSub
END
RETURN

DoCSWFOOps:
EachCSOp
DoCSComment
DoCSWFOComment
ClearCSOffset
SeqC CSWFO EOL
SeqC SubCall CallLabB CSSubID# EOL
NextCSOp
RETURN

DoCSG52Ops:
EachCSOp
DoCSComment
ClearCSOffset
SeqC CSG52 EOL
SeqC SubCall CallLabB CSSubID# EOL
NextCSOp
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
IF WFOCS?
DoCSWFOOps
ELSE
SeqC SetWFO EOL
DoCSG52Ops
END
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
IF WFOCS?
DoCSWFOOps
ELSE
SeqC SetWFO EOL
DoCSG52Ops
END
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

SubCSMP:
SeqC AbsOrIncC EOL
IF WorkFixtureOffsets?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXY MoveDC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

doFeedC:
IF Flag?('7')
Feed
SetFlagF('7')
ELSE
FeedC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
IF NOT EmptyLine?
Feed
END
ELSE
IF NOT ZMove?
CRCOnC
END
IF NOT EmptyLine?
SetFlag('7') { CRC Flag }
END
END
RETURN

ckCRCNum:
{ Not supported in ToolPath. Called in FirstOp3, NewToolOp5 & SameToolOp3 }
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
IF SPXMove? OR SPYMove?
SeqC MoveSX MoveSY EOL
END
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF PalletOut?
IF RetractToCP1?
SeqC DoDrillAbsOrInc MoveSX MoveSY MoveSDC
IF FirstFeat?
' G98'
END
EOL
ELSE
IF FirstFeat? AND LastFeat?
SeqC DoDrillAbsOrInc MoveSX MoveSY MoveSDC ' G98' EOL
ELSE
SeqC DoDrillAbsOrInc MoveSX MoveSY MoveSDC
IF FirstFeat?
' G99'
ELSE
IF LastFeat?
' G98'
END
END
EOL
END
END
ELSE
SeqC DoDrillAbsOrInc MoveSX MoveSY MoveSDC EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC DoAbsOrInc RapidC MoveXY MoveDC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC ckCRC DoAbsOrInc FeedC MoveXYC MoveDC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC ckCRC DoAbsOrInc FeedC MoveXYC MoveDC DecelFeed ckCRCNum EOL
ELSE
SeqC ckCRC DoAbsOrInc doFeedC MoveXY MoveDC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC DCP2 FeedEntC
ELSE
RapidC DCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC DInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC DCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed DInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC DInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed DCP2 FeedEnt EOL
ELSE
SeqC Rapid DCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC DCP2 FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC DCP2PlusIncC EOL
END
SeqC Feed DInPlusInc FeedEnt EOL
ELSE
SeqC RapidC DInPlusInc EOL
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

doCRCOn:
IF CutterRadiusCompensation?
CRCOffsetC
ELSE
IF Drilling? AND NOT SameTool?
' D0'
END
END
RETURN

OpGuts:
IF Milling?
SeqC DCP2
IF PalletOut?
CoolOn
END
EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC DCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC DCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC DCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC Rapid StrtPos EOL
END
IF PalletOut?
SeqC Rapid DCP2 CoolOn EOL
ELSE
SeqC DrillCP EOL
END
GetCycle
IF PalletOut?
IF FIFO? OR RigidTap?
'( WARNING INVALID DRILL CYCLE : '
IF FIFO?
'FI-FO )' EOL
ELSE
'Rigid Tap )' EOL
END
END
SeqC
IF FIStopRO? {Bore} { This Boolean is required to enable the Bore Cycle }
' G66'
ELSE
' G66'
END
IF Tap?
' P9184'
ELSE
IF FIStopRO?
' P9186'
ELSE
' P9181'
END
END
' Z' Sub# ZDepth# ClearancePlane1#
IF NOT Tap? AND NOT FIStopRO?
IF Peck? and PeckFullRetract?
' W' Peck#
' C.01'
' Q' Sub# Num#('1') ZDepth#
ELSE
' W' Sub# Num#('1') ZDepth#
' C.01'
IF PeckChipBreaker?
Peck
ELSE { Implied Full Out }
' Q' Sub# Num#('1') ZDepth#
END
END
END
' R' Sub# ClearancePlane2# ClearancePlane1#
FeedEnt
IF Dwell?
' A' Dwell#
END
EOL
TrackZNO# Sub# ClearancePlane2# ClearancePlane1#
ELSE
SeqC
IF FIStopRO? {FI-Stop-RO}
' G86'
ELSE
Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
END
Save# Num#('50') Num#('0')
EACHFeat
Save# NUM#('50') ADD# Recall# NUM#('50') NUM#('1') { Increment counter by 1 }
NextFeat
IF LessThan? Recall# Num#('50') Num#('11')
IF MasterOp?
NewMasterProg
END
TrackZNO# FIRST SPZ#
ToolPath
ELSE { Only output a Drill Sub if there are 11 OR MORE items in ToolPath }
IF CallMasterOp?
SeqC SubCall ' P' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
END
SetDrillEndOpZ
IF PalletOut?
SeqC ' G67' EOL
ELSE
SeqC Rapid ' G80' ZCP3 EOL
END
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('1300')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlag('3') { True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP }
SetFlag('4') { True = toggle between incrementing/decrementing WFO's }
SetFlagF('22') { Used with End3. Default : FALSE = Suppress ToolChangeAtHome }
SetFlagF('23') { Valid Pin NUmber in Used }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' ' EOL
' Using the PALLETOUT ( POUT ) PostScript Command' EOL
' ==========================================' EOL
' The PALLETOUT ( POUT ) command can be entered in the Utility Data At Op Start BOX.' EOL
' This will cause the Post to Switch from the Z axis to W axis output' EOL
' NOTE [1]: The POUT command is MODAL and Works in the First Operation ONLY.' EOL
' ' EOL
' Using the TCZ() PostScript Command' EOL
' ==============================' EOL
' To enter a Clearance Plane value for the W-axis and enable Clamp Avoidance.' EOL
' The Command TCZ(x) should be entered in the Operation Data, At Op Start Box.' EOL
' The Value, X, can be any positive or negative number.' EOL
' NOTE [2]: The TCZ command is NON-MODAL and is active only in the Operation where it is used.' EOL
' ' EOL
' Using the PIN() PostScript Command' EOL
' ==============================' EOL
' The Command PIN(x) should be entered in the Operation Data, At Op END Box.' EOL
' The Value, X, must be a positive Integer between One and Five.' EOL
' The Command is NON-MODAL.' EOL
' The Following Code is output with each PIN command.' EOL
' ' EOL
' PIN (1)' EOL
' =======' EOL
' M9' EOL
' N10 M0' EOL
' -BLANK LINE-' EOL
' ( CHECK SIZE )' EOL
' ( BDS NO.1 DOWN TO REPEAT FINISH CUT )' EOL
' ( UP TO CONT )' EOL
' /1 M99 P0000' EOL
' ' EOL
' PIN (2)' EOL
' =======' EOL
' M9' EOL
' N10 M0' EOL
' -BLANK LINE-' EOL
' ( CHANGE PARTS )' EOL
' ( BDS NO.1 DOWN TO REPEAT THIS SETUP )' EOL
' ( UP TO CONT )' EOL
' /1 M99 P0000' EOL
' ' EOL
' PIN (3)' EOL
' =======' EOL
' M9' EOL
' N10 M0' EOL
' -BLANK LINE-' EOL
' ( MOVE CLAMPS )' EOL
' ' EOL
' PIN (4)' EOL
' =======' EOL
' M9' EOL
' N10 M0' EOL
' -BLANK LINE-' EOL
' ( REMOVE CLAMPS )' EOL
' ( BOLT THRU MOUNTING HOLES )' EOL
' ' EOL
' PIN (5)' EOL
' =======' EOL
' M9' EOL
' N10 M0' EOL
' -BLANK LINE-' EOL
' ( SET ON BLOCKS )' EOL
' ( POSITION TO MILL TOP )' EOL
' ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('6')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to G52 style output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('6') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
END
END
END
RETURN

InitOp:
ProgID1
IF UseComments? AND ProgramComment?
' ( ' ProgramComment$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
Seq Plane ' M98 P8111' EOL { Plane has no Output }
SeqC ToolChng EOL
' ' EOL
DoOpComments
DoPostScript
DoTCZComment
RETURN

FirstOp2:
CheckPass
SeqC Rapid AbsOrInc StrtPos EOL
SeqC Speed SpinOn EOL
SeqC WFOStuff EOL
G52Stuff
Index
RETURN

FirstOp3:
SeqC OfstOn doCRCOn
IF NOT PalletOut?
CoolOn
END
EOL
RETURN

NewToolOp1: { Only called in MP_1_ToolAllP_fu }
SeqC AbsOrIncC EOL
RETURN

NewToolOp2:
IF PalletOut?
SeqC Rapid ' G28 W0' CoolOff EOL
ELSE
SeqC CoolOff EOL
END
Seq ' M98 P8111' EOL
DoEndOpPS
ckPinNumber
IF ToolChangeAtHome?
SeqC AbsOrIncC Rapid Home EOL
END
SeqC ToolChng EOL
doKeyWords
RETURN

NewToolOp3: {Start new Operation}
IF NOT PalletOut?
Seq Plane ' G17' CRCOff DrillOff AbsOrInc EOL { Plane has no Output }
END
DoOpComments
DoPostScript
DoTCZComment
RETURN

NewToolOp4:
CheckPass
SeqC Rapid AbsOrInc StrtPos EOL
SeqC Speed SpinOn EOL
SeqC WFOStuff EOL
G52Stuff
Index
RETURN

newToolOp5:
SeqC OfstOn doCRCOn
IF NOT PalletOut?
CoolOn
END
EOL
RETURN

SameToolOp1:
doEndOpPS
ckPinNumber
IF Flag?('23') OR LAST ProgStop?
IF PalletOut?
SeqC Rapid ' G28 W0' CoolOff EOL
ELSE
SeqC CoolOff EOL
END
Seq ' M98 P8111' EOL
doKeyWords
ELSE
IF NewToolOffset? OR ChangeCS?
IF PalletOut?
SeqC Rapid ' G28 W0' EOL
END
Seq ' M98 P8111' EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
DoTCZComment
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqC WFOStuff EOL
G52Stuff
IF Flag?('23') OR LAST ProgStop?
SeqC PlaneC Rapid AbsOrIncC StrtPos EOL
SeqC Speed SpinOn EOL
SeqC Index EOL
SeqC OfstOn
IF CutterRadiusCompensation?
CRCOffsetC
ELSE
IF Drilling?
' D0'
END
END
IF NOT PalletOut?
CoolOn
END
EOL
ELSE
SeqC PlaneC Rapid AbsOrIncC StrtPos EOL
SeqC SpeedC EOL
SeqC Index EOL
IF NewToolOffset? OR ChangeCS?
SeqC OfstOn
IF NOT PalletOut?
CoolOn
END
EOL
END
END
RETURN

End1: { Only called in MP_1_ToolAllP_fu }
SeqC CoolOff EOL
SeqC AbsOrIncC EOL
RETURN

End2:
IF PalletOut?
SeqC Rapid ' G28 W0' CoolOff EOL
ELSE
SeqC CoolOff EOL
END
Seq ' M98 P8111' EOL
DoEndOpPS
ckPinNumber
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqC AbsOrIncC Rapid FirstHome EOL
END
SeqC ToolChng EOL
IF Flag?('23') OR ProgStop?
SetFlag('22')
doKeyWords
ELSE
SeqC ProgStop EOL
' ' EOL
END
IF Equal? CSOffsetA# Num#('0') AND Equal? CSOffsetB# Num#('0')
ELSE
IF AAxisAvail? OR BAxisAvail?
SeqC ' M11' EOL { unlock 4th axis }
SeqC AbsOrIncC
IF AAxisAvail?
CSAngleA
END
IF BAxisAvail?
CSAngleB
END
EOL
SeqC ' G92'
IF AAxisAvail?
' A0'
END
IF BAxisAvail?
' B0'
END
EOL
SeqC ' M10' EOL { lock 4th axis }
END
END
RETURN

End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END