{Change Comments ***********************************************************}

{2/22/91
Copied & modified: Fanuc 11M MTS M203.76.3
For: Hughes Radar
Machine: Mitsui
Control: Fanuc 15M
This Post Processor supports FullSepSubs, No G92's, all incremental subs.
Added IncValue 'G30Y0.Z0.' following SafeStart at FirstOperation.
Replaced OfstOff with 'G30Y0.Z0.' at NewTool and End of Prog.
Changed Tool Length Offset Cancel from 'G28' to 'G30' in Form's Commands 5 Dialog.
This processor still needs PostScript Pallet changing, for which I have started a sub.
DWB}

{10/28/91
Modified: Fanuc 15M MTS M402.76.3
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 6M M001.81 Format.
DWB}

{6/4/92,
Modified: Fanuc 15M MTS M402.81
For: Gibbs & Associates
Made minor modifications.
DWB}

{10/18/93
Modified: Fanuc 15M MTS M402.81.1
For: Hughes Radar
Updated to .81.2 format per Fanuc 6M IncSubs M001.81.2
Changed SetMaxRPM to 20000
Jim Radcliffe}

{10/17/94
Modified: Fanuc 15M MTS M402.81.2
For: Hughes Radar
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Changes made per Steve Sato of Hughes Radar
Deleted blank lines at SubWarning sub.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added support of CRC during multiple pocket dog-bone operation.
Outputs G41/G42 on Z Plunge block at CkCRC sub.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added condition to output CRCOffC for ZMoveOnly Feature at ToolPath RapidFeat
Outputs G40 at all Z Retract blocks.
Added CkCRCOffsetC sub.
Added CutterRadiusCompensation AND NOT EmptyLine AND Flag(3) condition to test for situation for
output of conditional 'D' Tool# for CRCOffset.
Customer requested WFOStuff output at all Operations.
Deleted IF NOT SameTool? AND IF NeedWFO1? condition at WFOStuff sub.
Moved PreTool to Speed SpinOn block at FirstOperation and NewTool.
Added literal 'G49', OfstOff block inside IF MultipleParts? AND OneToolAllParts? AND FullUp? at
NewTool and end of Prog.
Added SafeStart block Rapid 'G20' CRCOff 'G61G80' AbsOrInc SpinOff at NewTool and end of Prog.
Moved IncValue 'G30Y0.Z0.' block following SafeStart block at NewTool and end of Prog.
Added IncValue 'G30X0Y0' OpToolID block following SafeStart block at NewTool and end of Prog
Added literal 'G49', OfstOff block following SafeStart block at NewTool and end of Prog.
Deleted SpinOff from IF ToolChangeAtHome? condition at NewTool.
Deleted SpinOff from IF FirstToolChangeAtHome? condition at end of Prog.
Added Seq at ToolChng at NewTool.
Added Speed SpinOn block to all conditions at SameTool.
Added OfstOn block to all conditions at SameTool.
Changed all occurances of OfstOn to 'G43Z' ClearancePlane1# 'H' Tool#.
DWB}

{9/26/95, Updated Fanuc 15M MTS M402.81.3 to .85 format per Fanuc 6M IncSubs M001.85, JR}

{2/6/96, Updated .85 version to .86, MPK}

{3/25/96, Updated .86 to .89 version, TH}

{23Dec97
Original: Fanuc 15M MTS M402.89
Created: Fanuc 15M [PIW] Mxxx.89
For: Peninsula Iron Works
Changes made per: Matt Johnson
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Changed Default Format for 'F' from '###.##;0.' to '###.0#;0.' in MachSpec
Deleted EOR at FirstOperation
Charles Winston}

{23Mar98
Original: Fanuc 15M [PIW] MW82.89
Created: Fanuc 15M [PIW] MW82.89.1
For: Peninsula Iron Works
Changes made per: Matt Johnson
Added Formatting for ADD# at Prog Numeric Format Definitions
Added '16' to all Cutter_Radius Comp values in CkCRCOffsetC per customers request
Added 'X0.' to 'G30' Literal in FristOperation
Charles Winston}

{05/21/98,
Initial: Fanuc 15M [PIW] MW82.89.1
Created: Fanuc 15M [PIW] MW82.89.2
For: Peninsula Iron Works

Changes to Prog:
1) FirstOp - Added AbsValue and ZCP1.
2) FirstOp/NewTool - Deleted ClearancePlane1# and literal Z.
3) Deleted all PreTool commands.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(SUB#,4)
FORMAT(Program#,5)
FORMAT(Program2#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(ADD#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Pallet#,5)
FORMAT(Dwell#,6)

{Pallet Subroutines ********************************************************}

PalletCode:
IncValue 'G30X0'
RETURN

DoPallet:
SeqC PalletCode 'P4B90.' EOL { Position }
SeqC PalletCode 'Y0Z0P' Pallet# EOL
RETURN

PalletStuff:
{ Pallet#('2') = Right Pallet }
{ Pallet#('3') = Left Pallet }
IF PalletIn?
DoPallet
SeqC 'M68' EOL { Load }
END
IF PalletOut?
DoPallet
SeqC 'M69' EOL { Unload }
END
RETURN

HandlePalletChange:
PalletInF
PalletOutF
EachPS
PalletStuff
NextPS
PalletInF
PalletOutF
EachEOPS
PalletStuff
NextPS
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
PalletInF
PalletOutF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

CheckAbsOrInc:
IF Flag?('1') {we are in a MultipleParts sub}
IncValue
ELSE
IF Flag?('2') {we are in a Repeats sub}
IncValue
ELSE {we are not in a sub}
AbsOrInc
END
END
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
END
END
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

HomeOrStrtPos:
IF AllToolsOnePart?
Home
ELSE {OneToolAllParts}
StrtPos
END
RETURN

DrillClearancePlane:
IF RetractToCP1?
IF SameTool?
IF NotEqual? LAST ClearancePlane3# ClearancePlane1#
SeqC 'Z' ClearancePlane1# EOL {ZCP1 does not output in incremental}
END
END
ELSE
SeqC ZCP2C EOL
END
RETURN

ECPZmove:
IF OneToolAllParts? AND ExitClearancePlane?
IF Milling?
SeqC ZCP2 EOL
ELSE {Drilling}
IF RetractToCP1?
SeqC ZCP1 EOL
ELSE
SeqC ZCP2 EOL
END
END
END
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO AbsOrInc Rapid HomeOrStrtPos EOL
ECPZmove
SeqC SubCall CallLab EOL
IncWFO
NextWFO
ELSE
EachPart
SeqC AbsOrInc Rapid HomeOrStrtPos EOL
ECPZmove
SeqC SubCall CallLab EOL
IF FirstPart?
SetStatusOff
END
NextPart
SetStatusOn
END
StartSub
SeqC IncValue EOL
SetFlag('1') {set true, we are in a MP sub}
RETURN

CloseMP:
SeqC EndSub EOL
CloseSub
SetFlagF('1')
IF WorkFixtureOffsets?
SeqC WFO1 AbsOrInc EOL
ELSE
SeqC AbsOrInc EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF LastFeat? { Exit Length Feature }
CRCOffC
ELSE
CRCOnC
IF NOT EmptyLine?
SetFlag('3')
END
END
RETURN

CkCRCOffsetC:
IF Flag?('3')
SetFlagF('3')
'D' ADD# NUM#('16') Tool# { CRCOffsetC }
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CkCRC FeedC MoveXYZC FeedRateC CkCRCOffsetC EOL
DecelMove2
END
SeqC CkCRC FeedC MoveXYZC DecelFeed CkCRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CkCRC FeedC MoveXYZC FeedRateC CkCRCOffsetC EOL
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF AutoCycle?
IF LastFeat?
CRCOffC {.70}
END
SeqC RapidC MoveXYZC EOL
ELSE
IF ZMove? AND NOT XMove? AND NOT YMove?
CRCOffC {.82}
END
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC 'G' NewWFO# EOL
END
ELSE
SeqC 'G' NewWFO# EOL { Output at all Operations }
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC CheckAbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

NoReps:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

RepAutoCycle:
EachRep
IF FirstCycle?
SeqC SubCall CallLab EOL
SaveProgNum2
StartSub
SetFlag('2') {set true, we are in a Repeats sub}
SeqC IncValue EOL
NewProg
AutoCycPat
AutoCycCutSub1
EntryMove
AutoCycCutSub2
SeqC EndSub EOL
CloseSub
SetFlagF('2')
ELSE
ResetPass2
SeqC CheckAbsOrInc StrtPos EOL
SeqC SubCall 'P' Program2# EOL
SetSRSubXYRC
END
NextRep
RETURN

RepZOnlyAutoCycle:
AutoCycPat
StartSub
SetFlag('2') {set true, we are in a Repeats sub}
SeqC IncValue EOL
NewProg
EachRep
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed StrtPosC EOL
ELSE
SeqC
END
ELSE
SeqC Feed
END
ZIn FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid StrtPosC EOL
END
END
IF FeedEntry?
SeqC ZCP2C EOL
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC ZIn EOL
END
END
SeqC SubCall CallLab EOL
IF FirstCycle?
AutoCycCutSub1 {save substatus at Z depth}
AutoCycCutSub2 {goes to ZCP2}
ELSE
IF NOT FeedConnect?
TrackZNo# ClearancePlane2#
END
END
NextRep
SeqC
IF NOT MultipleParts?
AbsOrInc
END
RapidC ZCP2C EOL
SeqC EndSub EOL
CloseSub
SetFlagF('2')
IF NOT FeedConnect?
SetStatusRapid
END
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

DrillStuff:
GetCycle
SeqC Cycle FromCP
{ZDepth outputs incorrectly when in incremental and retract from 1st clearance plane}
{ZDepth# will only output absolute values}
IF MultipleParts? OR Repeats?
SetAbs
'Z' SUB# ZDepth# ClearancePlane2# {calculate incremental depth}
SetInc
ELSE
ZDepth
END
RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
SeqC IncValue EOL
ToolPath
IF NOT Repeats? AND NOT MultipleParts?
SeqC AbsOrInc EOL
END
SeqC EndSub EOL
CloseSub
ELSE
ToolPath
END
END
SetDrillEndOpZ
RETURN

StdRep:
EachRep
IF FirstCycle?
SubWarning
EntryMove
SeqC SubCall CallLab EOL
StartSub
SetFlag('2') {set true, we are in a Repeats sub}
SeqC IncValue EOL
ToolPath
FinishSub1
SaveSubStatus
SeqC EndSub EOL
CloseSub
SetFlagF('2')
ELSE
SeqC CheckAbsOrInc Connect StrtPos EOL
IF FeedConnect?
SeqC ZinC EOL {takes care of different tool path start and end Z values}
ELSE
IF NOT Equal? ClearancePlane2# ClearancePlane3#
SeqC ZCP2 EOL
END
EntryMove
END
SeqC SubCall CallLab EOL
SetSRSubXYRC
SetSRSubZRC
END
NextRep
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('20000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' PalletIn(1), PIn(1) -' EOL
' PalletOut(1), POut(1) -' EOL
' Both of these comamnds will cause Post Processor to output:' EOL
' G91G30X0P4B90.' EOL
' G91G30X0Y0Z0P Pallet#' EOL
' M68 or M69 ( Load or Unload ).' EOL
' Pallet# is the argument entered.' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
' ' EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
{HandlePalletChange}
CheckPass
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq Plane 'G80' CRCOff EOL
SeqC IncValue 'G30X0.Y0.Z0.' EOL
SeqC AbsValue ZCP1 EOL
DoOpComments
DoPostScript
WFOStuff
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
ELSE
SeqC CheckAbsOrInc Rapid StrtPos EOL
END
SeqC Speed SpinOn EOL
SeqC 'G43H' Tool# EOL { OfstOn }
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC 'G49' EOL { OfstOff }
CloseMP
END
SeqC Rapid 'G20' CRCOff 'G61G80' AbsOrInc SpinOff EOL
SeqC IncValue 'G30Z0' EOL
SeqC IncValue 'G30X0Y0' OpToolID EOL
SeqC 'G49' EOL { OfstOff }
DoEndOpPS
IF ToolChangeAtHome?
SeqC CheckAbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

{HandlePalletChange}
Seq ToolChng EOL
DoOpComments
DoPostScript
WFOStuff
CheckPass
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
ELSE
SeqC CheckAbsOrInc Rapid StrtPos EOL
END
SeqC Speed SpinOn EOL
SeqC 'G43H' Tool# EOL { OfstOn }
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF SameTool?

{Finish off last Operation}

IF LAST ProgStop? OR CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF LAST ProgStop?
SeqC Rapid 'G20' CRCOff 'G61G80' AbsOrInc SpinOff EOL
END
IF LAST ProgStop? OR NewToolOffset?
SeqC IncValue 'G30Z0' EOL
END
IF LAST ProgStop?
SeqC IncValue 'G30X0Y0' EOL
END
IF LAST ProgStop? OR NewToolOffset?
SeqC 'G49' EOL { OfstOff }
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
END

{Start new Operation}

{HandlePalletChange}
DoOpComments
DoPostScript
WFOStuff
CheckPass
SeqC PlaneC CheckAbsOrInc Rapid StrtPos EOL
SeqC Speed SpinOn EOL
SeqC 'G43Z' ClearancePlane1# 'H' Tool# EOL { OfstOn }
IF LAST ProgStop? OR NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF AutoCycle?
IF ZshiftOnly?
RepZOnlyAutoCycle
ELSE
RepAutoCycle
END
ELSE {not AutoCycle}
StdRep
END {end Auto Cycle IF}
ELSE {no repeat OPs}
NoReps
END
SeqC CheckAbsOrInc
IF AutoCycle?
ZCP3C EOL
ELSE
IF FIFO?
FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
EachRep
IF FirstCycle?
DrillClearancePlane
SeqC SubCall CallLab EOL
StartSub
SetFlag('2') {set true, we are in a Repeats sub}
SeqC IncValue EOL
DrillStuff
SeqC
IF NOT MultipleParts?
AbsOrInc
END
DrillOff ZCP3 EOL
SaveSubStatus
SeqC EndSub EOL
CloseSub
SetFlagF('2')
ELSE
SeqC Rapid StrtPos EOL
IF RetractToCP1?
IF NOT Equal? ClearancePlane3# ClearancePlane1#
SeqC 'Z' ClearancePlane1# EOL {ZCP1 does not output in incremental}
END
ELSE
SeqC ZCP2C EOL
END
SeqC SubCall CallLab EOL
SetSRSubXYRC
SetSRSubZRC
END
NextRep
ELSE
DrillClearancePlane
DrillStuff
SeqC DrillOff ZCP3 EOL
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC 'G49' EOL { OfstOff }
CloseMP
END
SeqC Rapid 'G20' CRCOff 'G61G80' AbsOrInc SpinOff EOL
SeqC IncValue 'G30Z0' EOL
SeqC IncValue 'G30X0Y0T' FIRST Tool# EOL
SeqC 'G49' EOL { OfstOff }
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC CheckAbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
{HandlePalletChange}
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END