{Change Comments ***********************************************************}

{2/22/91
Copied & modified: Fanuc 11M MTS M203.76.3
For: Hughes Radar
Machine: Mitsui
Control: Fanuc 15M
This Post Processor supports FullSepSubs, No G92's, all incremental subs.
Added IncValue 'G30Y0.Z0.' following SafeStart at FirstOperation.
Replaced OfstOff with 'G30Y0.Z0.' at NewTool and End of Prog.
Changed Tool Length Offset Cancel from 'G28' to 'G30' in Form's Commands 5 Dialog.
This processor still needs PostScript Pallet changing, for which I have started a sub.
DWB}

{10/28/91
Modified: Fanuc 15M MTS M402.76.3
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 6M M001.81 Format.
DWB}

{6/4/92,
Modified: Fanuc 15M MTS M402.81
For: Gibbs & Associates
Made minor modifications.
DWB}

{10/18/93
Modified: Fanuc 15M MTS M402.81.1
For: Hughes Radar
Updated to .81.2 format per Fanuc 6M IncSubs M001.81.2
Changed SetMaxRPM to 20000
Jim Radcliffe}

{10/17/94
Modified: Fanuc 15M MTS M402.81.2
For: Hughes Radar
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Changes made per Steve Sato of Hughes Radar
Deleted blank lines at SubWarning sub.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added support of CRC during multiple pocket dog-bone operation.
Outputs G41/G42 on Z Plunge block at CkCRC sub.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added condition to output CRCOffC for ZMoveOnly Feature at ToolPath RapidFeat
Outputs G40 at all Z Retract blocks.
Added CkCRCOffsetC sub.
Added CutterRadiusCompensation AND NOT EmptyLine AND Flag(3) condition to test for situation for
output of conditional 'D' Tool# for CRCOffset.
Customer requested WFOStuff output at all Operations.
Deleted IF NOT SameTool? AND IF NeedWFO1? condition at WFOStuff sub.
Moved PreTool to Speed SpinOn block at FirstOperation and NewTool.
Added literal 'G49', OfstOff block inside IF MultipleParts? AND OneToolAllParts? AND FullUp? at
NewTool and end of Prog.
Added SafeStart block Rapid 'G20' CRCOff 'G61G80' AbsOrInc SpinOff at NewTool and end of Prog.
Moved IncValue 'G30Y0.Z0.' block following SafeStart block at NewTool and end of Prog.
Added IncValue 'G30X0Y0' OpToolID block following SafeStart block at NewTool and end of Prog
Added literal 'G49', OfstOff block following SafeStart block at NewTool and end of Prog.
Deleted SpinOff from IF ToolChangeAtHome? condition at NewTool.
Deleted SpinOff from IF FirstToolChangeAtHome? condition at end of Prog.
Added Seq at ToolChng at NewTool.
Added Speed SpinOn block to all conditions at SameTool.
Added OfstOn block to all conditions at SameTool.
Changed all occurances of OfstOn to 'G43Z' ClearancePlane1# 'H' Tool#.
DWB}

{9/26/95, Updated Fanuc 15M MTS M402.81.3 to .85 format per Fanuc 6M IncSubs M001.85, JR}

{2/6/96, Updated .85 version to .86, MPK}

{3/25/96, Updated .86 to .89 version, TH}

{5/10/96,
Initial: Fanuc 15M MTS M402.89
Created: Fanuc 15M MTS M999.89
For: Haas Automation
Changed handling of tool length offset to use just OfstOn.
Changed handling of CRC to use CRCOFstC instead of Tool#.
Eliminated safe start line 'G0G20G40G61G80G90M5' from NewTool and at program end.
Eliminated G49 at program end.
Eliminated redundant OpToolID at operation end in NewTool.
Changed to absolute drill subs.
MPK}

{10/19/96
Updated: Fanuc 15M MTS M999.89.1
Created: Fanuc 15M MTS M999.89.2
For: Haas Automation
Machine:
Control:
Versions: Catalyst v3.09C/Compost 4.21.37/v1.0b1
Changes made per Paul Cross of Haas Automation.
Updated for Catalyst v3.09C per Fanuc 6M M001.89 Format
Added ADD# to FORMAT#5 at Prog Numeric Format Definitions.
Deleted support of Pallet routines.
Added FeedEntC for SameTool Operations at EntryMove sub.
Modified WFOStuff to output with other code.
Added StrtPos to Drill Cycle block at DrillStuff.
Added GetOpToolID sub.
Adds 1000 to Tool#.
Added GetPreTool sub.
Adds 1000 to NextTool#.
Modified SafeStart block at FirstOperation.
Added #5221, #5222 and #5223 WFO blocks at FirstOperation.
Added M51/M59 Tool List for Tool Life Management Mode at FirstOperation.
Changed ToolChng, OfstOn and SpinOn commands to literal 'G65P22' block at FirstOperation.
P22 is a sub that takes care of these items.
Deleted G49, OfstOff block two places at NewTool.
Deleted IncValue 'G30Z0' block at NewTool and end of Prog.
Deleted IncValue 'G30X0Y0' block at NewTool and end of Prog.
Added 'G103Z.01J999.' block at NewTool and end of Prog.
Added blank line at NewTool.
Deleted G49, OfstOff block at SameTool and end of Prog.
Added 'M99' block at end of Prog.
Added 'N999' block at end of Prog.
Added Rapid IncValue 'G28Z0M19' block at end of Prog.
Added IncValue 'G28X0Y0Z0' block at end of Prog.
Added 'B0' block at end of Prog.
DWB}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SUB#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(TrackZNO#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ADD#,5)
FORMAT(Program2#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

CheckAbsOrInc:
IF Flag?('3') {we are in a MultipleParts sub}
IncValue
ELSE
IF Flag?('4') {we are in a Repeats sub}
IncValue
ELSE {we are not in a sub}
AbsOrInc
END
END
RETURN

EntryMove:
IF FeedEntry?
IF FirstOperation? OR NewTool?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC Feed ZIn FeedEntC EOL
END
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
END
END
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

HomeOrStrtPos:
IF AllToolsOnePart?
Home
ELSE {OneToolAllParts}
StrtPos
END
RETURN

DrillClearancePlane:
IF RetractToCP1?
IF SameTool?
IF NotEqual? LAST ClearancePlane3# ClearancePlane1#
SeqC 'Z' ClearancePlane1# EOL {ZCP1 does not output in incremental}
END
END
ELSE
SeqC ZCP2C EOL
END
RETURN

ECPZmove:
IF OneToolAllParts? AND ExitClearancePlane?
IF Milling?
SeqC ZCP2 EOL
ELSE {Drilling}
IF RetractToCP1?
SeqC ZCP1 EOL
ELSE
SeqC ZCP2 EOL
END
END
END
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO {simple eachPart}
SeqC SetWFO Rapid AbsOrInc HomeOrStrtPos EOL
ECPZmove
SeqC SubCall CallLab EOL
IncWFO
NextWFO {simple NextPart}
ELSE
EachPart
SeqC Rapid AbsOrInc HomeOrStrtPos EOL
ECPZmove
SeqC SubCall CallLab EOL
IF FirstPart?
SetStatusOff
END
NextPart
SetStatusOn
END
StartSub
SeqC IncValue EOL
SetFlag('3') {set true, we are in a MP sub}
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SetFlagF('3')
SeqC WFO1 AbsOrInc EOL
ELSE
SeqC EndSub EOL
CloseSub
SetFlagF('3')
SeqC AbsOrInc EOL
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
SetFlag('2') { CRCOffsetC }
CRCOnC
END
END
RETURN

FormatLine:
CkCRC FeedC MoveXYZC
RETURN

ckCRCNum:
IF Flag?('2')
SetFlagF('2')
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC FormatLine DecelFeed ckCRCNum EOL
ELSE
SeqC FormatLine FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
SeqC
ELSE
'G' NewWFO#
END
ELSE
IF FirstOperation?
IF NeedWFO1?
'G' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
CheckAbsOrInc
ELSE
IF FIFO? {.81}
FeedC CheckAbsOrInc ZCP2 FeedEntC
ELSE
RapidC CheckAbsOrInc ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

NoReps:
IF AutoCycle?
NewProg
AutoCycCutSub1
RapidF# { Forces FeedEntC }
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

RepAutoCycle:
EachRep
IF FirstCycle?
SeqC SubCall CallLab EOL
SaveProgNum2
StartSub
SetFlag('4') {set true, we are in a Repeats sub}
SeqC IncValue EOL
NewProg
AutoCycPat
AutoCycCutSub1
EntryMove
AutoCycCutSub2
SeqC EndSub EOL
CloseSub
SetFlagF('4')
ELSE
ResetPass2
SeqC CheckAbsOrInc StrtPos EOL
SeqC SubCall 'P' Program2# EOL
SetSRSubXYRC
END
NextRep
RETURN

RepZOnlyAutoCycle:
AutoCycPat
StartSub
SetFlag('4') {set true, we are in a Repeats sub}
SeqC IncValue EOL
NewProg
EachRep
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed StrtPosC EOL
ELSE
SeqC
END
ELSE
SeqC Feed
END
ZIn FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid StrtPosC EOL
END
END
IF FeedEntry?
SeqC ZCP2C EOL
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC ZIn EOL
END
END
SeqC SubCall CallLab EOL
IF FirstCycle?
AutoCycCutSub1 {save substatus at Z depth}
AutoCycCutSub2 {goes to ZCP2}
ELSE
IF NOT FeedConnect?
TrackZNo# ClearancePlane2#
END
END
NextRep
SeqC RapidC
IF NOT MultipleParts?
AbsOrInc
END
ZCP2C EOL
SeqC EndSub EOL
CloseSub
SetFlagF('4')
IF NOT FeedConnect?
SetStatusRapid
END
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

DrillStuff:
GetCycle
SeqC Cycle FromCP StrtPos
{ZDepth outputs incorrectly when in incremental and retract from 1st clearance plane}
{ZDepth# will only output absolute values}
IF MultipleParts? OR Repeats?
SetAbs
'Z' SUB# ZDepth# ClearancePlane2# {calculate incremental depth}
SetInc
ELSE
ZDepth
END
RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
ELSE
ToolPath
END
END
SetDrillEndOpZ
RETURN

StdRep:
EachRep
IF FirstCycle?
SubWarning
RapidF# { Forces FeedEntC }
EntryMove
SeqC SubCall CallLab EOL
StartSub
SetFlag('4') {set true, we are in a Repeats sub}
SeqC IncValue EOL
ToolPath
FinishSub1
SaveSubStatus
SeqC EndSub EOL
CloseSub
SetFlagF('4')
ELSE
SeqC Connect CheckAbsOrInc StrtPos EOL
IF FeedConnect?
SeqC ZinC EOL {takes care of different tool path start and end Z values}
ELSE
IF NOT Equal? ClearancePlane2# ClearancePlane3#
SeqC ZCP2 EOL
END
RapidF# { Forces FeedEntC }
EntryMove
END
SeqC SubCall CallLab EOL
SetSRSubXYRC
SetSRSubZRC
END
NextRep
RETURN

GetOpToolID:
'T' ADD# Tool# Num#('1000')
RETURN

GetPreTool:
'T' ADD# NextTool# Num#('1000')
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
{DoOpComments}
DoPostScript
WFOStuff
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('20000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CRCOffsetC }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
CheckPass
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq Plane 'G20' CRCOff WFOStuff 'G80' CheckAbsOrInc EOL
SeqC '#5221=X' EOL { G54 X }
SeqC '#5222=Y' EOL { G54 Y }
SeqC '#5223=Z' EOL { G54 Z }
SeqC 'M51' EOL { Tool Life Management On }
{EachTool
SeqC 'T' ADD# TLNum# Num#('1000') EOL { Need a way to do this }
NextTool}
SeqC 'M59' EOL { Tool Life Management Off }
SeqC CheckAbsOrInc WFOStuff EOL
SeqC GetOpToolID EOL
DoOpComments
DoPostScript
{ G65 P22 calls sub 22, does M6, G43, M3 }
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC 'G65P22' ToolOfst GetOpToolID Speed EOL
OpenMP
SeqC ZCP1 EOL
ELSE
SeqC 'G65P22' StrtPos ZCP1 ToolOfst GetOpToolID Speed EOL
END
SeqC
IF NOT LastTool?
GetPreTool
END
CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SeqC 'G103Z.01J999.' EOL { Sends Tool To Checker for Broken Tools }
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid CheckAbsOrInc Home EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Seq ' ' EOL
DoOpComments
DoPostScript
WFOStuff
CheckPass
{ G65 P22 calls sub 22, does M6, G43, M3 }
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC 'G65P22' ToolOfst GetOpToolID Speed EOL
OpenMP
SeqC ZCP1 EOL
ELSE
SeqC 'G65P22' StrtPos ZCP1 ToolOfst GetOpToolID Speed EOL
END
SeqC GetPreTool CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF SameTool?
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC IncValue 'G30Z0' EOL
SeqC IncValue 'G30X0Y0' EOL
DoEndOpPS
SeqC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC Rapid CheckAbsOrInc StrtPos EOL
SeqC Speed SpinOn EOL
SeqC CoolOn EOL
SeqC OfstOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC IncValue 'G30Z0' EOL
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC Rapid CheckAbsOrInc StrtPos EOL
SeqC SpeedC EOL
SeqC OfstOn EOL
ELSE
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC Rapid CheckAbsOrInc StrtPos EOL
SeqC SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF AutoCycle?
IF ZshiftOnly?
RepZOnlyAutoCycle
ELSE
RepAutoCycle
END
ELSE {not AutoCycle}
StdRep
END {end Auto Cycle IF}
ELSE {no repeat OPs}
NoReps
END
IF AutoCycle?
SeqC CheckAbsOrInc ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CheckAbsOrInc CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CheckAbsOrInc CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
EachRep
IF FirstCycle?
DrillClearancePlane
SeqC SubCall CallLab EOL
StartSub
SetFlag('4') {set true, we are in a Repeats sub}
SeqC IncValue EOL
DrillStuff
SeqC
IF NOT MultipleParts?
AbsOrInc
END
DrillOff ZCP3 EOL
SaveSubStatus
SeqC EndSub EOL
CloseSub
SetFlagF('4')
ELSE
SeqC Rapid StrtPos EOL
IF RetractToCP1?
IF NOT Equal? ClearancePlane3# ClearancePlane1#
SeqC 'Z' ClearancePlane1# EOL {ZCP1 does not output in incremental}
END
ELSE
SeqC ZCP2C EOL
END
SeqC SubCall CallLab EOL
SetSRSubXYRC
SetSRSubZRC
END
NextRep
ELSE
DrillClearancePlane
DrillStuff
SeqC DrillOff ZCP3 EOL
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SeqC 'G103Z.01J999.' EOL { Sends Tool To Checker for Broken Tools }
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid CheckAbsOrInc FirstHome EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC 'M99' EOL
'N999' EOL
Rapid IncValue 'G28Z0M19' EOL
IncValue 'G28X0Y0Z0' EOL
'B0' EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END