{Change Comments ***********************************************************}

{6/14/95, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, DWB}
{7/18/95, Added IF NOT LastFeat? at CkCRC sub, DWB}
{8/18/95, .85.01.01, Added format CallMasterNum#, changed 'P' to CallLabB, added OptCyc1F, JR}
{8/19/95, .85.01.02, Modified CRC handling, set up for Virtual, not Gibbs System DogBone!, JR}
{8/23/95, .85.01.03, Simplified/corrected SameTool section, JR}
{3/20/96, .86, New ZonlyRepAutoCycle sub per Fanuc 6M M001.11, JR}
{4/17/96, .89, Changed version number per new version identification, JR}

{8/6/96
Initial: Fanuc 6M M001.89
Created: Fanuc 15M Monarch Mxxx.89
ForUser: Avant Systems, Inc
Control: Fanuc 15M
Machine: Monarch VMC-75B
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New Processor per marked up readout from and conversation with Harry Pendergass
Jim Radcliffe}

{9/14/96
Initial: Fanuc 15M Monarch MZ16.89
Created: Fanuc 15M Monarch MZ16.89.1
Develop: ComPost2 68k v1.0b3, Catalyst68K v3.04.10.C
Comment: Modified per marked up readout from Avant.
Modified tapping codes with support for left hand tapping.
Jim Radcliffe}

{26Nov97
Original: Fanuc 15M Mon [AS] MZ16.89.1
Created: Fanuc 15M Mon [AS] MZ16.89.2
For: Avant Systems, Inc
Changes made per: Nick Lupfer
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added Formatting for Save# and Recall# in Prog Numeric Format Definitions
Changed First WFO from G54 to G55 in MachSpec
Added Litreral 'G90G54' to 'G28G49Z0H0' in DoOfstOff Sub
Note:Added custom line numbering Subs in order to support a block of code commencing
with Line Number 5000 ( used for Auto Set-Up ), to be output at the end of each program.
If the output exceeds this line number then the code block numbers are incremented to the
next highest "Thousand" line number.
DoEOL replaces EOL on all lines using SeqC and keeps track of Line Number increments in units of 10
Added InitLineNumbers at InitProg to initialize the start Sequence Number and to set Line Tracking ON.
Line Number Tracking is switched OFF after an OpenSub and back ON after a CloseSub
This method is crude but effective ( Use Sub-Programs = True in MachSpec and Sequence# is disabled ! )
At the End of the Program, CalcLineNo is called to check if the '5000' block needs to be incremented.
Added the Custom Line-Block of code at End of Prog per customers printout
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(Save#,5)
FORMAT(Recall#,5)

{Special Command Subroutines ***********************************************}

DoOfstOff:
'G90G54G28G49Z0H0'
RETURN

InitLineNumbers:
Save# Num#('5') Sub# Sequence# Num#('5')
SetFlag('9') { Line Number Tracking ON }
RETURN

DoEOL:
IF NOT EmptyLine? AND Flag?('9')
IF NOT MinimizeSequencing?
Save# Num#('5') ADD# Recall# Num#('5') Num#('5')
END
END
EOL
RETURN

CalcLineNo:
IF GTEqual? Recall# Num#('5') Num#('4990')
Save# Num#('6') Trunc# Div# Recall# Num#('5') Num#('1000')
Save# Num#('5') Add# Recall# Num#('6') Num#('1')
ELSE
Save# Num#('5') Num#('5')
END
RETURN

DoCloseSub:
CloseSub
SetFlag('9') { Line Number Tracking ON }
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# DoEOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# DoEOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# DoEOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# DoEOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript DoEOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS DoEOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt DoEOL
ELSE
SeqC RapidC ZIn DoEOL
END
RETURN

StartSub:
SetFlagF('9') { Line Number Tracking OFF }
OpenSub
SubID DoEOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs DoEOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
DoEOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC DoEOL
SeqC EndSub DoEOL
DoCloseSub
SeqC Preset UnshftRC DoEOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO DoEOL
SeqC SubCall CallLab RepLab OnePart DoEOL
IncWFO
NextWFO
ELSE
SeqC SubCall CallLab RepLab Parts DoEOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub DoEOL
DoCloseSub
SeqC WFO1 DoEOL
ELSE
SeqC Preset ShiftPC DoEOL
SeqC EndSub DoEOL
DoCloseSub
SeqC Preset UnshftPC DoEOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue DoEOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC DoEOL
SeqC SubCall CallLab DoEOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC DoEOL
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC DoEOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc RapidC MoveXYZC DoEOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC RapidC MoveXYZC CRCOffsetC DoEOL
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC DoEOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC DoEOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC DoEOL
DecelMove2
END
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC DoEOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC DoEOL
END
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC DoEOL
DecelMove2
END
SeqC FormatArc DecelFeed DoEOL
ELSE
SeqC FormatArc ArcFeedC DoEOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS'
EOL
ELSE
'G' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'G' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue DoEOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
DoEOL
SeqC EndSub DoEOL
DoCloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos DoEOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC DoEOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt DoEOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC DoEOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc DoEOL
SeqC Feed ZInPlusInc FeedEnt DoEOL
ELSE
SeqC AbsOrInc ZInPlusInc DoEOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc DoEOL
SeqC Feed ZInPlusInc FeedEnt DoEOL
ELSE
SeqC Rapid ZInPlusInc DoEOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt DoEOL
ELSE
SeqC Rapid ZInPlusInc DoEOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab DoEOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt DoEOL
ELSE
SeqC Rapid ZCP2 DoEOL
END
END
SeqC EndSub DoEOL
DoCloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos DoEOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt DoEOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC DoEOL
END
SeqC Feed ZInPlusInc FeedEnt DoEOL
ELSE
SeqC RapidC ZInPlusInc DoEOL
END
END
SeqC SubCall CallLab DoEOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub DoEOL
DoCloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
InitLineNumbers
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' DoEOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq Plane CRCOff DrillOff DoEOL
SeqC DoOfstOff DoEOL
SeqC OpToolID ToolChng DoEOL
DoOpComments
DoPostScript
CheckPass
SeqC AbsOrInc WFOStuff Rapid StrtPos Speed SpinOn PreTool DoEOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqC StrtPos DoEOL
END
SeqC OfstOn DoEOL
SeqC CoolOn DoEOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos DoEOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff DoEOL
SeqC DoOfstOff DoEOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home SpinOff DoEOL
ELSE
SeqC SpinOff DoEOL
END
IF LAST ProgStop?
SeqC 'M0' DoEOL
ELSE
SeqC ProgStop DoEOL
END

{Start new Operation}

Seq Plane CRCOff DrillOff DoEOL
SeqC DoOfstOff DoEOL
SeqC OpToolID ToolChng DoEOL
DoOpComments
DoPostScript
CheckPass
SeqC AbsOrInc WFOStuff Rapid StrtPos Speed SpinOn PreTool DoEOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
SeqC StrtPos DoEOL
END
SeqC OfstOn DoEOL
SeqC CoolOn DoEOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos DoEOL
END
ELSE
IF SameTool?

{Finish off last Operation}

IF LAST ProgStop? OR CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff DoEOL
END
IF LAST ProgStop? OR NewToolOffset?
SeqC DoOfstOff DoEOL
END
DoEndOpPS
IF LAST ProgStop?
SeqC SpinOff DoEOL
SeqC 'M0' DoEOL
END

{Start new Operation}

DoOpComments
DoPostScript
CheckPass
SeqC PlaneC AbsOrInc WFOStuff Rapid StrtPos SpeedC
IF LAST ProgStop?
SpinOn
END
DoEOL
IF LAST ProgStop? OR NewToolOffset?
SeqC OfstOn DoEOL
END
IF LAST ProgStop? OR NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn DoEOL
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C DoEOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C DoEOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC DoEOL
ELSE
SeqC RapidC CRCOffC ZCP3C DoEOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos DoEOL
END
SeqC DrillCP DoEOL
GetCycle
SeqC
IF RigidTap?
IF CWSpindle?
'G84.2'
ELSE
'G84.3'
END
ELSE
IF Tap? AND NOT CWSpindle?
'G74'
ELSE
Cycle
END
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt DoEOL
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# DoEOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab DoEOL
StartSub
ToolPath
SeqC EndSub DoEOL
DoCloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid DrillOff ZCP3 DoEOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff DoEOL
SeqC DoOfstOff DoEOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid FirstHome SpinOff DoEOL
ELSE
SeqC SpinOff DoEOL
END
IF MultipleParts? AND AllToolsOnePart?
IF ProgStop?
SeqC 'M0' DoEOL
ELSE
SeqC ProgStop DoEOL
END
CloseMP
END
CalcLineNo
'N' Recall# Num#('5') '000 GOTO 1050' EOL
'N' Recall# Num#('5') '010 (SET UP)' EOL
'N' Recall# Num#('5') '020 G65 P8915 S1. T24. M1. R16. Z3.' EOL
'N' Recall# Num#('5') '030 G54 X20. Y20.' EOL
'N' Recall# Num#('5') '040 G65 P8907 A.3 C1. R.1 Z-.2 E2. U.5 V.5 M0. X1. Y1.' EOL
'N' Recall# Num#('5') '050 M30' EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END