{Change Comments ***********************************************************}

{6/1/89
Modified; Cincinnati 900V2 (1) M099.54, for C G Richter.
Change "RapidC" to "Rapid" after Drilling.
Add "NullFoot" twice to beginning and twice to end of prog.
Changed "'( MSG" to "'(MSG".
Checked "Use Absolute Drill Depths" in Booleans.
Jim Radcliffe}

{9/6/89
Copied & modified: Cincinnati 900V2 (1) M099.55
For: Hughes T&CSD
Machine: Cincinnati Cintimatic 5VC-750
Control: Acramatic 900 V2
New processer from Manual and Customer requests.
Jim Radcliffe}

{9/15/89, add PostScript, JR}

{9/21/89
Copied & modified: Cin 5VC Acr 900V2 M238.56
For: Hughes T&CSD
Machine: Cincinnati Cintimatic 10VC
Control: Acramatic 900 MC
Added Probing Operation utilizing PostScript commands SetZSurf & OptCyc1.
Probing and setting of Z axis should be OK.
Needs method for X and Y axis.
Jim Radcliffe}

{10/11/89, modified operation comments, JR}

{12/5/89
Modified: Cin 10VC Acr 900MC M245.62
For: Hughes T&CSD
Machine: Cincinnati Cintimatic 10VC
Control: Acramatic 900 MC
Added PostScript for Coolant, Program Stop & Index.
Jim Radcliffe}

{3/29/90, Updated: Cin 10VC Acr 900MC M245.63 to .70.3 format, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{7/24/90, Deleted SetZSurf command at start of prog, DWB}
{12/14/90, Updated: Cin 10VC Acr 900MC M245.71 to .76.1 format, JR}

{4/3/91
Modified: Cin 10VC Acr 900MC M245.76.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.79 Format.
DWB}

{6/18/91, Changed ArcIJC & ArcRC to ArcIJ & ArcR. Added OptCyc1F to PSInit, JC}

{6/27/91
Modified: Cin 10VC Acr 900MC M245.79.1
For: Hughes T&CSD per Terry Lowe
Modified Subs;
changed Sub ID from "PGM" to "DFS",
changed to output subs in front of program,
deleted all EOR codes except for the 1st one.
Modified Cutter Radius Compensation, must be in Feed when CRCOn is called and cannot have 2 G codes on same line;
deleted boolean statement that ouputs Feed, after a rapid entry, from; EntryMove, ZonlyRepAutoCycle & ZonlyRep,
added sub CkCRC to put Feed on line by itself before CRCOn, using flag to check condition,
put CRCOff on line by itself following move line and reset flag.
Jim Radcliffe}

{7/29/91
Modified: Cin 10VC Acr 900MC M245.80
For: Hughes T&CSD per Terry Lowe
Added codes to allow Retract to 1st Clearance Plane for Drilling Cycles.
For proper drill cycle depths:
changed ZDepth to 'Z' ADD# ZDepth# NumSc#('.1'),
unchecked "Use Absolute Drill Depths" in the MachSpec.
Jim Radcliffe}

{2/19/92
Modified: Cin 10VC Acr 900MC M245.80.1
For: Hughes T&CSD per Terry Lowe
Changed to no sub output, all long hand output.
Jim Radcliffe}

{5/10/94
Copied & modified: Cin 10VC Acr 900MC M245.80.2
For: Rexroth
Control: Cincinnati Acramatic 900
Machine: Cincinnati Milacron T-10
Cleaned up formatting, scaling and inch/metric conversion corrections.
Jim Radcliffe}

{4/13/95
Copied: Cin T10 900MC [RR] M656.81.5
Created: Cin T10 900MC [LA] D718.10
For: Gibbs & Associates/Lincoln Automotive
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.05/Catalyst v2.14.35/Compost 4.21.28
Changes made per Bill White of Lincoln Automotive.
Updated and Converted to Fanuc 6M [NW] D001.10
Deleted support of OptCyc1 and SetZSurf PostScript Commands.
Changed original Flag(1) to Flag(5) to keep track of CRCOn/CRCOff of processor and DrillStuff.
Deleted support of MistCoolant and SetMistCoolant PostScript commands and corresponding
PostScript Comments.
Added support for FloodCoolant, ThruSpindleCoolant and SetThruSpindle PostScript commands and
corresponding PostScript Comments.
Processor originally supported SetFlood PostScript command so no change was made.
DWB}

{
Format: Cin T10 900MC [LA] D718.10.01
8/23/95
Added FORMAT(CallMasterNum#,5)
TH}

{
Format: Cin T10 900MC [LA] D768.10.02
10/24/95
Added MSG, to DoCSWFOComment
TH}

{1/17/96, Updated .10 to .11 version, MPK}

{3/25/96, Tested ZOnlyRepAutoCycle, Changed version # to .12, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####^##0'
#3 = '*####^##0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '##^#0'
#7 = '00'
#8 = '###^###0'
#9 = '###^0'
#10 = '#####^##0'
#11 = '*#####^##0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(SpeedRPM#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6)
FORMAT(NewWFO#,7)
FORMAT(Recall#,8)
FORMAT(ADD#,8)
FORMAT(SUB#,8)
FORMAT(MUL#,8)
FORMAT(ArcZRads#,8)
FORMAT(ClearancePlane2#,8)
FORMAT(FeedEntry#,9)
FORMAT(CSOffsetA#,11)
FORMAT(CSOffsetB#,11)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
Save# Num#('11') Num#('.03937007874')
ELSE
SetScale('1')
Save# Num#('11') Num#('1')
END
RETURN

SetScale#:
Recall# Num#('11')
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqC '(MSG, SUB NUMBER - ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqC '(MSG, OPERATION ' Operation# ' - ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqC '(MSG, TOOL ' Tool# ' - ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqC '(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

CSWFO:
'H' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
'H' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSAngleA:
IF AAxisAvail?
'A' CSOffsetA#
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
'B' CSOffsetB#
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
'(MSG, CS#' CS# ' - ' CSComment$ ' )' EOL
'(MSG, ' CalcCSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
RETURN

PSInit:
ResetCool
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
EOR EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC '(CLS,I' Program# ',R' Repeats# ')' EOL
StartSub
RETURN

FinishSub1: {part 1}
IF FeedConnect?
IF CutterRadiusCompensation?
IF Flag?('5')
SetFlagF('5')
SeqC FeedC EOL
SeqC CRCOffC EOL
END
END
ELSE
IF AutoCycle?
SeqC CRCOffC ZCP3C EOL
ELSE
IF CutterRadiusCompensation?
IF Flag?('5')
SetFlagF('5')
IF FIFO?
SeqC FeedC EOL
ELSE
SeqC RapidC EOL
END
CRCOffC
END
END
IF FIFO?
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
IF WFOCS?
NewProg
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO {simple eachPart}
SeqC SetWFO EOL
SeqC '(CLS,I' Program# ',R' Parts# ')' EOL
IncWFO
NextWFO {simple NextPart}
ELSE
SeqC '(CLS,I' Program# ',R' Parts# ')' EOL
END
StartSub
END
RETURN

CloseMP:
IF WFOCS?
SeqC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqC CalcCSWFO EOL
SeqC '(CLS,I' CSSubID# ')' EOL
NextCSOp
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
LastWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqC CalcCSWFO EOL
SeqC '(CLS,I' CSSubID# ')' EOL
NextCSOp
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatIJ:
IF AbsoluteMoves? AND NOT AutoCycle?
ArcIJC
ELSE
ArcIJ
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane? AND ZMove?
MoveXYZC FormatIJ 'K' ArcZRads#
ELSE
IF XZPlane? AND YMove?
MoveXYZC FormatIJ 'J' ArcZRads#
ELSE
IF YZPlane? AND XMove?
MoveXYZC FormatIJ 'I' ArcZRads#
ELSE
MoveXYZC FormatIJ
END
END
END
RETURN

CkCRC: { 4.2 }
IF CutterRadiusCompensation?
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
IF NOT ZMove?
IF NOT Flag?('5')
SetFlag('5')
FeedC EOL
SeqC CRCOn
END
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
IF Flag?('5')
SetFlagF('5')
FeedC EOL
SeqC CRCOffC
END
END
END
RETURN

StdLine: {enables CRC on first call}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

DoPeck:
IF GTEqual? Recall# Num#('10') Num#('1') { NumFullPecks }
Save# Num#('10') SUB# Recall# Num#('10') Num#('1') { Number of remaining Pecks }
Save# Num#('12') SUB# Recall# Num#('12') MUL# SetScale# Peck# { PeckDepth }
Save# Num#('13') ADD# Recall# Num#('12') MUL# SetScale# Retract# { RetractDepth }
SeqC Feed 'Z' Recall# Num#('12') FeedEntC EOL
TrackZNO# Recall# Num#('12')
IF GTEqual? Recall# Num#('10') Num#('1') { Number of remaining Pecks }
IF PeckFullRetract?
SeqC Rapid ZCP2 EOL
END
SeqC RapidC 'Z' Recall# Num#('13') EOL { RetractDepth }
TrackZNO# Recall# Num#('13')
END
END
IF Equal? Recall# Num#('10') Num#('0') { NumFullPecks }
IF SPZMove? { LastPeck }
IF PeckFullRetract?
SeqC Rapid ZCP2 EOL
END
SeqC RapidC 'Z' Recall# Num#('13') EOL { RetractDepth }
SeqC Feed MoveSZ EOL
END
END
RETURN

Do5Pecks:
DoPeck DoPeck DoPeck DoPeck DoPeck
RETURN

Do10Pecks:
Do5Pecks Do5Pecks
RETURN

Do15Pecks:
Do10Pecks Do5Pecks
RETURN

Do20Pecks:
Do10Pecks Do10Pecks
RETURN

Do25Pecks:
Do20Pecks Do5Pecks
RETURN

DoPecks:
Save# Num#('10') TRUNC# DIV# ABS# SUB# ClearancePlane2# SPZ# Peck# { NumFullPecks }
IF LTEqual? Recall# Num#('10') Num#('5')
Do5Pecks
ELSE
IF LTEqual? Recall# Num#('10') Num#('10')
Do10Pecks
ELSE
IF LTEqual? Recall# Num#('10') Num#('15')
Do15Pecks
ELSE
IF LTEqual? Recall# Num#('10') Num#('20')
Do20Pecks
ELSE
Do25Pecks
END
END
END
END
RETURN

DrillPos:
IF Flag?('5') { Approach }
StrtPos
ELSE { ToolPath }
MoveSXYC
END
RETURN

DrillDepth:
IF Flag?('5') { Approach }
'Z' MUL# Num#('-1') SUB# ClearancePlane2# FIRST SPZ#
TrackZNO# FIRST SPZ# {.81.2}
ELSE { ToolPath }
IF SPZMove?
'Z' MUL# Num#('-1') SUB# ClearancePlane2# SPZ#
TrackZNO# SPZ# {.81.2}
END
END
RETURN

RPlane:
IF Flag?('5') { Approach }
'R' ClearancePlane2# { RLevel }
TrackZNO# FIRST SPZ# {.81.2}
END
RETURN

DrillStuff:
IF Peck?
Rapid DrillPos ZCP2
ELSE
IF FIFO? AND Dwell?
'G89'
ELSE
Cycle
END
DrillPos DrillDepth RPlane
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC '(CLS,I' Program# ')' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF Peck?
SeqC RapidC MoveSXYC EOL
SeqC ZCP2C EOL
Save# Num#('12') ClearancePlane2#
DoPecks
IF NOT LastFeat?
IF RetractToCP1?
SeqC Rapid ZCP1 EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
ELSE
IF RetractToCP1?
IF NOT FirstFeat?
SeqC DrillStuff EOL
END
IF NOT LastFeat?
SeqC Rapid ZCP1 EOL
END
ELSE
SeqC DoDrillAbsOrInc MoveSXYC DrillDepth EOL
END
END
END
ELSE
IF RapidFeat?
IF AutoCycle?
IF LastFeat?
IF CutterRadiusCompensation?
IF Flag?('5')
SetFlagF('5')
SeqC RapidC EOL
CRCOffC
END
END
END
SeqC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF ZMove? AND NOT XMove? AND NOT YMove?
IF CutterRadiusCompensation?
IF Flag?('5')
SetFlagF('5')
SeqC RapidC EOL
CRCOffC
END
END
END
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle?
IF LastFeat?
IF CutterRadiusCompensation?
IF Flag?('5')
SetFlagF('5')
SeqC FeedC EOL
CRCOffC {.70}
END
END
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc EOL
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{removed RapidC}
{removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO?
SeqC FeedC ZCP2 FeedEntC EOL
ELSE
SeqC RapidC ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc EOL
SeqC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC '(CLS,I' Program# ')' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {added Rapid, reads better} {changed to RapidC, reads better}
END
END
SeqC '(CLS,I' Program# ')' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetPreTool:
IF NOT LastTool?
'T' PreToolComment$
END
RETURN

CheckSpinOn: {turns on spindle and coolant}
IF CoolOff?
SpinOn
ELSE
IF ThruSpin?
IF CWSpindle?
'M20'
ELSE
'M21'
END
ELSE
IF CWSpindle?
'M13'
ELSE
'M14'
END
END
END
RETURN

Approach:
IF Milling?
Rapid StrtPos
IF FirstOperation? OR NewTool?
ZCP1 Speed CheckSpinOn
ELSE
IF LAST ProgStop?
ZCP1 Speed CheckSpinOn
ELSE
SpeedC
IF CoolOff? AND LAST NOT CoolOff?
CheckSpinOn
END
END
END
ELSE
GetCycle
IF RetractToCP1? OR Peck?
SetFlag('5')
DrillStuff
SetFlagF('5')
IF FirstOperation? OR NewTool?
FeedEnt Speed CheckSpinOn
ELSE
IF LAST ProgStop?
FeedEnt Speed CheckSpinOn
ELSE
FeedEntC SpeedC
IF CoolOff? AND LAST NOT CoolOff?
CheckSpinOn
END
END
END
ELSE
SetFlag('5')
DrillStuff
SetFlagF('5')
IF FirstOperation? OR NewTool?
FeedEnt Speed CheckSpinOn
ELSE
IF LAST ProgStop?
FeedEnt Speed CheckSpinOn
ELSE
FeedEntC SpeedC
IF CoolOff? AND LAST NOT CoolOff?
CheckSpinOn
END
END
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('4000')
SetMaxFeed('150')
SetFlagF('1') { SepSub ZMove for Milling ZonlyRep and Drilling MasterOp }
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlag('4') {True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') { CRCOff/DrillStuff }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' FloodCoolant, FCool -' EOL
' This command is non modal. An operation that contains this command, and when' EOL
' the Coolant On check box is checked, will cause the post processor to output' EOL
' M13 for clockwise spindle and M14 for counterclockwise spindle. When the' EOL
' Coolant On checkbox is not checked, no Coolant code is issued and the post processor' EOL
' will output the standard M03 for clockwise spindle and M04 for counterclockwise' EOL
' spindle. This command must be entered for every operation where it is needed.' EOL
' SetFlood, SF -' EOL
' This command is modal. An operation that contains this command, and when' EOL
' the Coolant On check box is checked, will cause the post processor to output' EOL
' M13 for clockwise spindle and M14 for counterclockwise spindle. When the' EOL
' Coolant On checkbox is not checked, no Coolant code is issued and the post processor' EOL
' will output the standard M03 for clockwise spindle and M04 for counterclockwise' EOL
' spindle. This command need only be entered for the first operation where it is needed.' EOL
' ThruSpindleCoolant, TSCool -' EOL
' This command is non modal. An operation that contains this command, and when' EOL
' the Coolant On check box is checked, will cause the post processor to output' EOL
' M20 for clockwise spindle and M21 for counterclockwise spindle. This command must' EOL
' be entered for every operation where it is needed.' EOL
' SetThruSpindle, STS -' EOL
' This command is modal. An operation that contains this command, and when' EOL
' the Coolant On check box is checked, will cause the post processor to output' EOL
' M20 for clockwise spindle and M21 for counterclockwise spindle. This command need' EOL
' only be entered for the first operation where it is needed.' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('0')
SetWFOCS { use WFO for CS changes }
END
END
ELSE
IF LTEqual? NumOfCS# Num#('0') {****}
SetWFOCS { use WFO for CS changes }
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
ZonlyRep {rep change 1}
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF CutterRadiusCompensation?
IF Flag?('5')
IF FIFO?
SeqC FeedC EOL
ELSE
SeqC RapidC EOL
END
SetFlagF('5')
CRCOffC
END
END
IF FIFO?
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC Rapid StrtPos EOL
END
GetCycle
IF RetractToCP1? OR Peck?
ToolPath
ELSE
IF CallMasterOp?
SeqC '(CLS,I' CallMasterNum# ')' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC '(CLS,I' Program# ')' EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
ELSE
ToolPath
END
END
END
SetDrillEndOpZ
SeqC Rapid ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

NotSameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
ClearCSOffset
SeqC CSWFO EOL
ELSE
ClearCSOffset { 11/8/94 }
END
ELSE
IF NeedWFO1?
'H' NewWFO#
END
END
RETURN

SameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
ClearCSOffset
SeqC CSWFO EOL
ELSE
ClearCSOffset { 11/8/94 }
END
END
RETURN

InitOp:
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqC '(MSG, PROGRAM - ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqC '(MSG, FORMAT - ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqC '(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqC '(MSG, PARTS PROGRAMMED - ' Parts# ' )' EOL
END
IF StartToolComment?
SeqC '(MSG, FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
EOR EOL
RestoreScale
RETURN

FirstOp1:
Seq AbsOrInc EOL
SeqC Plane EOL
SeqC 'T' ToolComment$ ToolChng EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
{ Not Needed }
RETURN

FirstOp3:
CheckPass
SeqC Approach CSAngleA CSAngleB GetPreTool EOL
RETURN

FirstOp3a: {can't XY position before WFO}
CheckPass
SeqC Rapid
IF Milling?
ZCP1 Speed CheckSpinOn
ELSE
GetCycle
IF RetractToCP1? OR Peck?
Rapid
ELSE
IF MasterOp? OR CallMasterOp?
Speed CheckSpinOn
ELSE
Rapid
END
END
END
GetPreTool EOL
RETURN

NewToolOp1:
{ Not Needed }
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC RapidC Home EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
Seq 'T' ToolComment$ ToolChng EOL
SeqC PlaneC EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
{ Not Needed }
RETURN

NewToolOp5:
CheckPass
SeqC Approach CSAngleA CSAngleB GetPreTool EOL
RETURN

NewToolOp5a:
CheckPass
SeqC Rapid
IF Milling?
ZCP1 Speed CheckSpinOn
ELSE
GetCycle
IF RetractToCP1? OR Peck?
Rapid
ELSE
IF MasterOp? OR CallMasterOp?
Speed CheckSpinOn
ELSE
Rapid
END
END
END
GetPreTool EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
IF ToolChangeAtHome?
SeqC RapidC Home EOL
END
SeqC 'M0' EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
RETURN

SameToolOp2: {Start new Operation}
SeqC PlaneC EOL
DoOpComments
DoPostScript
SeqC CSAngleAC CSAngleBC EOL
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqC Approach EOL
RETURN

End1:
{ Not Needed }
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC WFO1 EOL
SeqC RapidC FirstHome EOL
END

IF NotEqual? CSOffsetA# Num#('0')
IF AAxisAvail?
SeqC CSAngleA
END
IF BAxisAvail?
SeqC CSAngleB
END
EOL

SeqC Preset
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
ELSE
IF NotEqual? CSOffsetB# Num#('0')
IF AAxisAvail?
SeqC CSAngleA
END
IF BAxisAvail?
SeqC CSAngleB
END
EOL

SeqC Preset
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
END
IF ProgStop?
SeqC 'M0' EOL
END
RETURN

End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'(MSG, FILE LENGTH - ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'(MSG, FILE LENGTH - ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'(MSG, FILE LENGTH - ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: { MultipleParts AND AllToolsOnePart }
EachOp
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE { SameTool }
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
End1
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: { MultipleParts AND OneToolAllParts AND FullUp }
EachOp
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
OpenMP
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2
NewToolOp3
NewToolOp4
OpenMP
NewToolOp5
ELSE { SameTool }
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
End1
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: { MultipleParts AND OneToolAllParts AND ExitClearancePlane }
EachOp
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3a
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5a
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
ELSE { SameTool }
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
CloseMP
End1
End2
End3
RETURN

NoMPs: { NOT MultipleParts }
EachOp
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE { SameTool }
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
NextOp
End1
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE { OneToolAllParts }
IF FullUp?
MP1ToollAllPfu
ELSE { ExitClearancePlane }
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END