{Change Comments ***********************************************************}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{3/26/91
Modified: Bandit II Cadillac L070.58
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Only Canned Cycles supported are RoughContour (Turning only) and all Drilling Cycles.
BUG NOTE: ComPost's Strings dialog indicates that '/X' and '/Z' are Rapid moves,
but Default Formats does not recognize the '/', so no value is output.
BUG NOTE: Canned RoughContour used an EachCycle/NextCycle loop which is a Milling command.
Could be that we need an EachPass/NextPass loop instead.
DWB}

{8/6/91
Updated: Bandit II Cadillac L070.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
KM}

{9/28/93
Modified: Bandit II Cadillac L070.82
For: Gibbs & Associates
Corrected Rapid moves per BUG NOTE of 3/26/91.
Removed spaces between codes in Mach Spec.
JR}

{10/10/93
Copied & modified: Bandit II Cadillac L070.82.1
For:
Machine: Phaser Lathe
Control: Bandit
Changes made for output loaded to control from external device.
Changed X Arc Center Label from /K to K in Mach Specs Strings 1 Dialog.
Changed Y Arc Center Label from /J to J in Mach Specs Strings 1 Dialog.
Changed Rapid X End-Point Label from /X to J in Mach Specs Strings 1 Dialog.
Changed Rapid Z End-Point Label from /Z to K in Mach Specs Strings 1 Dialog.
Changed Feed Label from /F to F in Mach Specs Strings 1 Dialog.
No slashes required except for non-modal ThrdLead in Single Point Threading.
Changed Change Tool from M6 to M20 in Mach Specs Commands 4 Dialog.
Deleted GearRange at CheckOffset sub, FirstOperation and NewTool.
Moved SpinOn to before AbsOrInc at FirstOperation and NewTool.
Deleted CoolOn and FirstOperation and NewTool.
Deleted literal 'M11' at FirstOperation and NewTool.
Added literal 'M20' for ToolChange prior to ProgStop at NewTool and end of Prog.
Deleted Feed command at Home block at NewTool.
Ken Crowther}

{12/22/93
Modified: Bandit II Phaser L292.82.1
For: Gibbs & Associates
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32/Compost 4.21.19
Changes made per conversations with Ken Crowther.
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1 Format.
Deleted CoolOn at CheckOffset sub.
Deleted CoolOff at CheckOffset sub.
Moved ThrdLead from RapidFeat to ThreadFeat of ToolPath.
FeedRate is not Modal and needs to be output on all Thread Passes for encoder to pick up Lead.
Added Variable(1) to keep track of Turret Indexes.
Turret is 4 station and needs to be indexed back to station 1 at end of program.
Var(1) set to 1 at FirstOperation for First Turret Station.
Var(1) incremented by 1 at NewTool.
Added logic to output literal 'M20' to return Turret back to Station 1 at end of prog.
NOTE: Ken Crowther requested that FeedRates be output in Inches per Minute instead of Revolution.
This is to be taken care of at a later date.
DWB}

{12/22/93
Copied & modified: Bandit II Phaser L292.82.2
For: MD Research
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32/Compost 4.21.19
Changes made per EMails and samples supplied by Maurizio of Cigraph PTY.
Maurizio explains that customer will run jobs on Bandit Mill.
Part will be held in a Rotary Table and Tool to be held in Spindle.
Requested that Lathe stuff be stripped down without support of Speed, Spindle and Canned
Cycles, etc.
Created Metric version.
Added FORMAT#5 '000' for Program#.
Deleted all support of Coolant.
Deleted all support of ToolOffsets.
Deleted all support of Speed, GearRange and Spindle.
Deleted all support of Canned Cycles.
Tapping operations output M0 at depth and pullout.
Deleted ArcCPsDia at setup and initializations.
Added XsAreRadii at setup and initializations.
Deleted literal 'T0' at NewTool and end of prog.
Added ToolChng at NewTool and end of prog.
Deleted literal 'M20' at NewTool and end of prog.
Deleted support of Variable(1) Turret Index Counter.
DWB}

{2/1/94
Modified: Bandit II [MDR] L293.82.2m
For: MD Research
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.02/Compost 4.21.19
Changes made per EMails and samples supplied by Maurizio of Cigraph PTY.
Modified per Bandit IIM MDR NoS M595.81.7m
Deleted all SeqLab/SeqLabC Commands.
Changed Retag to Renum and moved to after end of Prog Comments.
Added Program2# to Format#5.
Added SaveProgNum2 to setup and initializations.
Added 'N' Program2# EOL at FinishLastOp.
Changed value of SetMaxRPM from 10000 to 3800 at setup and initializations.
Changed value of SetMaxFeed from 500 to 999 at setup and initializations.
Added OfstOnB block to before Home block at FirstOperation and NewTool.
Added OfstOnB block for NewToolOffset at CheckOffset sub.
Added literal 'T0' block to follow NewHome block at NewTool.
Added literal 'T0' block to follow FirstHome block at end of Prog.
Deleted ProgStop at NewTool and end of Prog.
ToolChng [M6] causes ProgStop to automatically happen.
Changed literal 'M0' to 'M6' for ProgStop at CheckOffset sub.
DWB}

{2/21/94
Modified: Bandit II [MDR] L293.82.3m
For: MD Research
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.02/Compost 4.21.20
Changes made per EMails by Maurizio of Cigraph PTY.
Deleted EOP at end of prog.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '#'
#5 = '000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,2) {.72}
FORMAT(FeedIPR#,2)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Tag#,4)
FORMAT(RapidF#,4)
FORMAT(Program#,5) {.72}
FORMAT(Program2#,5)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT Threading?
IF CannedCycle?
IF Drilling?
FeedC
END
ELSE
FeedC
END
END
RETURN

FeedRateNoCan:
IF NOT Threading?
IF CannedCycle? AND Drilling?
ELSE
FeedRateC EOL
END
END
RETURN

ODApproachSP:
StockOnNoCan ZSPC EOL
StockOff XOpCDC EOL
StockOnNoCan
FeedRateNoCan
IF NotEqual? CycleStartX# XOpCD#
FeedNoCan XSPC EOL
END
RETURN

IDApproachSP:
StockOnNoCan ZSPC EOL
StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
FeedRateNoCan
IF NotEqual? CycleStartX# XOpCD#
FeedNoCan XSPC EOL
END
RETURN

FaceApproachSP:
StockOnNoCan XSPC EOL { for SameTool ApproachFace }
StockOff ZOpCPC EOL
StockOnNoCan
FeedRateNoCan
IF NotEqual? CycleStartZ# ZOpCP#
FeedNoCan ZSPC EOL
END
RETURN

AppMove:
StockOff ZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF CannedCycle? AND Drilling?
ELSE
RapidF# { RapidF# Forces FeedRate }
END
Rapid
IF ApproachOD?
StockOff XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
'M6' EOL
END
IF NewToolOffset?
OfstOnB EOL
END
DoPostScript
RETURN

FormatArc:
MoveXC MoveZC ArcIJ
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
'M0' EOL
ELSE
IF Dwell?
'/T' Dwell# EOL
END
END
END
END
IF PointFeat?
MoveSXYC EOL
ELSE
IF RapidFeat?
RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
FeedRateC EOL
FeedC MoveXC MoveZC EOL
ELSE
IF ArcFeat?
FeedRateC EOL
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
FormatArc EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
ThrdLead EOL
Feed MoveZC EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
XsAreRadii
ReverseXZArcs
PosSideLathe
SetMaxRPM('3800')
SetMaxFeed('999')
SaveProgNum2
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MILLIMETERS )' EOL
END
END
RestoreScale
' ' EOL
'N' Program# '&' 'G71' EOL
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane { No Output }
AbsOrInc EOL
OfstOnB EOL
Feed Home Preset EOL
IF CannedCycle? AND Drilling?
ELSE
Approach
END
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
XCPC EOL
ELSE
IF LAST ApproachID?
LAST XOpECDC EOL
END
END
ZCPC EOL
DoEndOpPS
NewHome EOL
'T0' EOL
ToolChng EOL { ProgStop }

{Start new Operation}

DoOpComments
DoPostScript
Plane { No Output }
AbsOrInc EOL
OfstOnB EOL
Feed Home Preset EOL
IF CannedCycle? AND Drilling?
ELSE
Approach
END
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
LAST XOpECDC EOL
END
ZCPC EOL
XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
XCPC EOL
END
ZCPC EOL
XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
XCPC EOL
ELSE {LAST ApproachID}
LAST XOpECDC EOL
END
ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
'( Canned Cycles were removed per customer request. )' EOL
'( Please inform Tech Support that Processor is attempting to output a Canned Cycle. )' EOL
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple? AND NOT Threading?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
ZOpECPC EOL
FaceApproachSP
ELSE
XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
RapidC XSPC ZSPC EOL
END
StockOff StrtPosC EOL
ToolPath
END
END
IF Drilling? AND Tap?
'M0' EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
XCPC EOL
ELSE
IF ApproachID?
XOpECDC EOL
END
END
ZCPC EOL
DoEndOpPS
FirstHome EOL
'T0' EOL
ToolChng EOL { ProgStop & EOP }
'N' Program2# EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Renum