{Change Comments ***********************************************************}

{5/21/96
Updated:
Modified:
Copied: Heid TNC 425 [HPM] M972.89m
Created: Heid TNC 425 [PB] M053.89m
For: Fructus/Pharmacia Biosensor
Machine:
Control:
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.04.05C/Compost 4.21.37/1.0a
Changes made per Mikael Bagge of Fructus.
Customer requested Coordinate FORMAT changes.
Changed FORMAT#1 from '####0.000' to '####0.###;0' at Prog Numeric Format Definitions.
Changed FORMAT#2 from '###.###;0.' to '##0.###;0' at Prog Numeric Format Definitions.
Changed FORMAT#3 from '*###.###;0.' to '*##0.###;0' at Prog Numeric Format Definitions.
Changed FORMAT#4 from 'Ä…####0.000' to 'Ä…####0.###;+0' at Prog Numeric Format Definitions.
Changed FORMAT#6 from 'Ä…*####0.000' to 'Ä…*####0.###;+0' at Prog Numeric Format Definitions.
Modified literal at ckCRCOff, StartSub, StdSub, FinishSubG92, OpenMP, CloseMP, FormatArc,
ToolPath, AutoCycCutSub2 and ZonlyRep subs, and FirstOperation and NewTool.
Customer requested deletion of padded spaces.
Modified DoL, Space, XYZSpace, DoR0 and DoM subs.
Customer requested deletion of CYCL7 sub.
Deleted sub and 3 calls to same at FirstOperation.
Deleted SetProgNumTo10 sub.
Replaced with SetProgNum command at setup and initializations
Customer requested Tool Comment at Tool Call block.
Added ToolTypeComments sub, called from FirstOperation and NewTool.
Deleted ToolChng block at FirstOperation and NewTool.
Deleted PreTool at FirstOperation and NewTool.
Changed Drill Cycle Labels at IF Drilling.
Changed output blocks at end of Prog.
Including ASCII(3)
DWB}

{2/27/97
Modified: Heid TNC 425 [PB] M053.89m
Created: Heid TNC 425 [PB] M053.89.1m
For: Fructus/Biacore formerly known as Pharmacia Biosensor
Versions: Catalyst v3.30C/ComPost2 MSL 68K
Changes made per Mikael Bagge of Fructus.
Customer requested that subs be output outside of main program, between M2 and END PGM.
UnCommented OpenSub at StartSub.
UnCommented CloseSub at at FinishSubG92, CloseMP, AutoCycCutSub2, ZonlyRepAutoCycle, ZonlyRep
and IF Drilling.
Deleted Post command at end of Prog.
Added CloseSub and Post2 commands between M2 and END PGM at end of Prog.
DWB}

{3/11/97
Modified: Heid TNC 425 [PB] M053.89.1m
Created: Heid TNC 355 [SP] MY41.89m
For: Maquinser/Spasa
Machine: CORREA A16
Control: Heid TNC 355
Versions: Catalyst v3.30C/ComPost2 MSL 68K
Changes made per Juan Jose Osoro of Maquinser, faxes and sample programs.
Commented out OpenSub at StartSub.
Commented out CloseSub at at FinishSubG92, CloseMP, AutoCycCutSub2, ZonlyRepAutoCycle, ZonlyRep
and IF Drilling.
Added Variable(1) to count Repeats# for ZShift Operations.
Suppresses final Call Label block since sub is imbedded right after final pass position.
Changed all Comments Control Out codes from Parentheses to semi-colon.
Changed Drill Cycles to support CalcCP2FmSurf# and CalcZSurf# per Heid TNC 155 [P&A] M694.81.10m.
Added Tool Def blocks at FirstOperation and NewTool.
Added ToolChangeAtHome at NewTool.
DWB}

{3/18/97
Modified: Heid TNC 355 [SP] MY41.89m
Created: Heid TNC 355 [SP] MY41.89.1m
For: Maquinser/Spasa
Versions: Catalyst v3.30C/ComPost2 MSL 68K
Changes made per Juan Jose Osoro of Maquinser and fax.
Deleted output of literal X0 Y0 ToolChangeAtHome move at NewTool and end of Prog.
Customer only wanted Home block when checkbox is checked.
Post was output literal block when checkbox was not checked.
UnCommented ReTag command at end of Prog.
My mistake, I do this for developing purposes only and I forgot to Undo it when I had finished
working on this post.
DWB}

{4/2/97
Updated & Modified: Heid TNC 355 [SP] MY41.89.1m
Created: Heid TNC 355 [SP] MY41.15m
For: Maquinser/Spasa
Versions: Catalyst v3.32C/ComPost2 MSL 68K
Changes made per Juan Jose Osoro of Maquinser and fax.
Updated for Catalyst v3.32C per Fanuc 6M M001.15 Format.
Added StartPosX# to FORMAT#4 at Prog Numeric Format Definitions.
Added StartPosY# to FORMAT#4 at Prog Numeric Format Definitions.
Changed MoveZC to MoveZ two places at CheckMove sub.
Added Feed {no output} at AutoCycCutSub2 sub.
Added Rapid {no output} at AutoCycCutSub2 sub.
Added Feed {no output} at G92Sub sub.
Added Rapid {no output} at G92Sub sub.
Changed SPX# to StartPosX# two places at ZonlyRepAutoCycle sub.
Changed SPY# to StartPosY# two places at ZonlyRepAutoCycle sub.
Changed ZCP2PlusIncC to ZCP2PlusInc at ZonlyRep sub.
Deleted LoadFeat at end of IF Milling?
DWB}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = 'Ä…####0.###;+0'
#3 = 'Ä…*####0.###;+0'
#4 = '####0.###;0'
#5 = '#######0'
#6 = '+###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ABS#,2)
FORMAT(DIV#,2)
FORMAT(ClearancePlane2#,2)
FORMAT(XStockMin#,2)
FORMAT(XStockMax#,2)
FORMAT(YStockMin#,2)
FORMAT(YStockMax#,2)
FORMAT(ZStockMin#,2)
FORMAT(ZStockMax#,2)
FORMAT(HomeX#,2)
FORMAT(HomeY#,2)
FORMAT(StartPosX#,2)
FORMAT(StartPosY#,2)
FORMAT(SPX#,2)
FORMAT(SPY#,2)
FORMAT(SPZ#,2)
FORMAT(EPX#,2)
FORMAT(EPY#,2)
FORMAT(EPZ#,2)
FORMAT(ArcI#,2)
FORMAT(ArcJ#,2)
FORMAT(CalcZFmSurf#,2)
FORMAT(RepeatX#,2)
FORMAT(RepeatY#,2)
FORMAT(RepeatZ#,2)
FORMAT(PartShiftX#,2)
FORMAT(PartShiftY#,2)
FORMAT(PartShiftZ#,2)
FORMAT(OriginUnShiftPX#,2)
FORMAT(OriginUnShiftPY#,2)
FORMAT(OriginUnShiftPZ#,2)
FORMAT(OriginUnShiftRX#,2)
FORMAT(OriginUnShiftRY#,2)
FORMAT(OriginUnShiftRZ#,2)
FORMAT(ToolDiameter#,2)
FORMAT(ToolLength#,2)
FORMAT(TrackZNO#,2)
FORMAT(SUB#,3)
FORMAT(CalcCP2FmSurf#,3)
FORMAT(Peck#,3)
FORMAT(Dwell#,4)
FORMAT(Program#,5)
FORMAT(Program2#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NextTool#,5)
FORMAT(Parts#,5)
FORMAT(FeedEntry#,6)

{Special Subs ****}

DoL:
' L'
RETURN

DoZL:
DoL
RETURN

Space: { 10 Spaces }
{' '}
RETURN

XYZSpace:
{' '} Space
RETURN

XYSpace:
Space Space
RETURN

ZSpace:
Space Space Space
RETURN

IXYZSpace:
Space
RETURN

IXYSpace:
Space Space
RETURN

IZSpace:
Space Space Space
RETURN

DoR0:
IF NOT Flag?('3') { ArcFeat }
{' '}
END
IF Flag?('2') { CutterRadiusCompensation }
IF CRCleft?
' RL'
ELSE
' RR'
END
ELSE
' R0'
END
RETURN

RF: { RapidF }
' F MAX'
RETURN

DoM:
{' M'}
RETURN

ckCRCOff:
IF Flag?('2') { CRCOn }
SetFlagF('2')
SeqLab DoL ' IX+0 IY+0' IXYSpace DoR0 RF DoM EOL
END
RETURN

CheckCoolOn:
IF CoolOff?
DoM
ELSE
CoolOn
END
RETURN

CheckCoolOff:
IF CoolOff?
DoM
ELSE
CoolOff
END
RETURN

{Prog Subroutines ****}

RestoreScale:
IF NOT Metric? { CAM file is in English, tools and tool path }
SetScale('25.4') { change to Metric, this is a Metric post }
ELSE
SetScale('1')
END
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'; SUB NUMBER: ' Program# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'; ' OperationComment$ EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'; ' ToolComment$ EOL
END
RestoreScale
END
RETURN

ToolTypeComments:
IF ToolTypeComment?
SetScale('1')
' ; ' ToolType$ ' ' ToolDiameter# EOL
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
SeqLab DoZL
IF NOT AbsValue?
' IZ' SPZ# IZSpace
ELSE
ZIn ZSpace
END
DoR0
IF FeedEntry?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
RETURN

StartSub:
{OpenSub}
DoSubComment
SeqLab ' LBL ' Program# EOL
RETURN

SubWarning:
IF UseComments?
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'; WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
END
RETURN

StdSub:
SeqLab ' CALL LBL ' Program# ' REP ' Repeats# ' / ' Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
SeqLab DoZL ZCP3 ZSpace
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
RF
ELSE
IF FIFO?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
END
DoM EOL
END
ckCRCOff
RETURN

FinishSubG92: {part 2}
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' RepeatX# EOL
SeqLab ' CYCL DEF 7.2 IY' RepeatY# EOL
SeqLab ' CYCL DEF 7.3 IZ' RepeatZ# EOL
SeqLab ' LBL 0' EOL
{CloseSub}
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftRX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftRY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftRZ#('0') EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
SeqLab ' CALL LBL ' Program# ' REP ' Parts# ' / ' Parts# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' PartShiftX# EOL
SeqLab ' CYCL DEF 7.2 IY' PartShiftY# EOL
SeqLab ' CYCL DEF 7.3 IZ' PartShiftZ# EOL
SeqLab ' LBL 0' EOL
{CloseSub}
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftPX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftPY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftPZ#('0') EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
{ Not Supported }
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
END
RETURN

CheckMove:
IF AutoCycle? OR NOT AbsValue?
IF XMove? OR YMove? OR ArcFeat?
' IX' EPX# ' IY' EPY#
IF ZMove?
' IZ' EPZ# IXYZSpace
ELSE
IXYSpace
END
ELSE
IF ZMove?
' IZ' EPZ# IZSpace
END
END
ELSE
IF XMove? OR YMove? OR ArcFeat?
MoveX MoveY
IF ZMove?
MoveZ XYZSpace
ELSE
XYSpace
END
ELSE
IF ZMove?
MoveZ ZSpace
END
END
END
RETURN

FormatArc:
DoAbsOrInc
SeqLab ' CC'
IF AutoCycle? OR NOT AbsValue? {implies incremental}
' IX' ArcI# ' IY' ArcJ#
ELSE
ArcIJ
END
EOL
SeqLab ' C' CheckMove
IF ArcCW?
' DR-' CWArc {no output}
ELSE
' DR+' CCWArc {no output}
END
SetFlag('3')
DoR0
SetFlagF('3')
RETURN

ckCRC:
IF CutterRadiusCompensation?
IF LastFeat?
SetFlagF('2') { CRCOff }
ELSE
IF NOT ZMove?
SetFlag('2') { CRCOn }
END
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

FormatLine:
IF ZMove? AND NOT XMove? AND NOT YMove?
DoZL
ELSE
DoL
END
DoAbsOrInc CkCRC CheckMove DoR0
RETURN

DrillCycle:
IF RigidTap?
SeqLab ' CYCL DEF 17.0 FAST GAENGNING' EOL
SeqLab ' CYCL DEF 17.1 AVST ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 17.2 DJUP ' SUB# CalcZSurf# SPZ# EOL
SeqLab ' CYCL DEF 17.3 V.TID 0' EOL
ELSE
IF Tap?
SeqLab ' CYCL DEF 2.0 G€NGBORRNING' EOL
SeqLab ' CYCL DEF 2.1 AVST ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 2.2 DJUP ' SUB# CalcZSurf# SPZ# EOL
SeqLab ' CYCL DEF 2.3 V.TID 0' EOL
SeqLab ' CYCL DEF 2.4' FeedEnt EOL
ELSE
SeqLab ' CYCL DEF 1.0 PECKING' EOL
SeqLab ' CYCL DEF 1.1 SET UP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 1.2 DEPTH ' SUB# CalcZSurf# SPZ# EOL
SeqLab ' CYCL DEF 1.3 PECKG '
IF Peck?
Peck#
ELSE
SUB# CalcZSurf# SPZ#
END
EOL
SeqLab ' CYCL DEF 1.4 DWELL '
IF Dwell?
Dwell#
ELSE
'0'
END
EOL
SeqLab ' CYCL DEF 1.5' FeedEnt EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
Rapid {no output}
IF AutoCycle?
IF NOT FirstFeat?
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF DoM EOL
END
SeqLab ' CALL LBL ' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF FirstFeat?
SeqLab ' CYCL CALL' XYZSpace ZSpace DoM EOL
ELSE
IF SPZMove? OR RetractToCP1?
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF DoM EOL
IF RetractToCP1?
SeqLab DoZL ZCP2 ZSpace DoR0 RF DoM EOL
END
DrillCycle
SeqLab ' CYCL CALL' XYZSpace ZSpace DoM EOL
ELSE
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF ' M99' EOL
END
TrackZNO# SPZ#
END
IF RetractToCP1?
SeqLab DoZL ZCP1 ZSpace DoR0 RF DoM EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
Rapid {no output}
SeqLab FormatLine RF DoM EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
Feed {no output}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatLine FeedRate DoM EOL
DecelMove2
END
SeqLab FormatLine DecelFeed DoM EOL
ELSE
SeqLab FormatLine FeedRate DoM EOL
END
END
ELSE
IF ArcFeat?
SetStatusOff
IF Metric? AND LessThan? ABS# ArcR# Num#('.02')
SetFlag('4')
ELSE
IF NOT Metric? AND LessThan? ABS# ArcR# Num#('.0007874015748031') { .02 Ö 25.4 }
SetFlag('4')
END
END
SetStatusOn
IF Flag?('4')
SeqLab FormatLine FeedRate DoM EOL { StdLine }
ELSE
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
FormatArc ArcFeed DoM EOL
DecelMove2
END
FormatArc DecelFeed DoM EOL
ELSE
FormatArc ArcFeed DoM EOL
END
NEXTQuadrant
END
SetFlagF('4')
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
SeqLab DoZL ZCP2 ZSpace DoR0
IF FIFO?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
{CloseSub}
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SetAbs
SeqLab DoL StrtPos XYSpace DoR0
IF FeedConnect?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
Save# Num#('1') Num#('0') { ZShiftRepeats# }
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed {no output}
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' StartPosX# ' IY' StartPosY# IXYSpace DoR0 FeedEnt DoM EOL
SetAbs
END
END
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt DoM EOL
ELSE
IF NOT FirstCycle?
Rapid {no output}
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' StartPosX# ' IY' StartPosY# IXYSpace DoR0 RF DoM EOL
SetAbs
END
IF FeedEntry?
SeqLab DoZL ZCP2PlusInc ZSpace DoR0 RF DoM EOL
END
END
SeqLab DoZL ZInPlusInc ZSpace DoR0
IF FeedEntry?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
Save# Num#('1') ADD# Recall# Num#('1') Num#('1') { ZShiftRepeats# }
IF NotEqual? Recall# Num#('1') Repeats#
SeqLab ' CALL LBL ' Program# EOL
END
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
SeqLab DoZL ZCP2 ZSpace DoR0
IF FIFO?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
{CloseSub}
{Element shift, not pattern}
RETURN

ZonlyRep:
Save# Num#('1') Num#('0') { ZShiftRepeats# }
EachCycle
IF NOT FirstCycle?
SeqLab DoL StrtPos XYSpace DoR0
IF FeedConnect?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
END
IF FeedConnect?
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt DoM EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
Rapid {no output}
SeqLab DoZL ZCP2PlusInc ZSpace DoR0 RF DoM EOL
END
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt DoM EOL
ELSE
Rapid {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
END
Save# Num#('1') ADD# Recall# Num#('1') Num#('1') { ZShiftRepeats# }
IF NotEqual? Recall# Num#('1') Repeats#
SeqLab ' CALL LBL ' Program# EOL
END
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab ' LBL 0' EOL
{CloseSub}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLab DoZL ZCP2 ZSpace DoR0 RF CheckCoolOn EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLab DoZL ZCP3 ZSpace
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
Rapid {no output}
RF
ELSE
IF FIFO?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
END
CheckCoolOff EOL
ckCRCOff
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
Rapid {no output}
SeqLab DoL StrtPos XYSpace DoR0 RF DoM EOL
END
SeqLab DoZL ZCP2 ZSpace DoR0 RF CheckCoolOn EOL
GetCycle
IF RigidTap?
SeqLab ' CYCL DEF 17.0 FAST GAENGNING' EOL
SeqLab ' CYCL DEF 17.1 AVST ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 17.2 DJUP ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 17.3 V.TID 0' EOL
ELSE
IF Tap?
SeqLab ' CYCL DEF 2.0 G€NGBORRNING' EOL
SeqLab ' CYCL DEF 2.1 AVST ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 2.2 DJUP ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 2.3 V.TID 0' EOL
SeqLab ' CYCL DEF 2.4' FeedEnt EOL
ELSE
SeqLab ' CYCL DEF 1.0 PECKING' EOL
SeqLab ' CYCL DEF 1.1 SET UP ' CalcCP2FmSurf# EOL
SeqLab ' CYCL DEF 1.2 DEPTH ' CalcZFmSurf# EOL
SeqLab ' CYCL DEF 1.3 PECKG '
IF Peck?
Peck#
ELSE
CalcZFmSurf#
END
EOL
SeqLab ' CYCL DEF 1.4 DWELL '
IF Dwell?
Dwell#
ELSE
'0'
END
EOL
SeqLab ' CYCL DEF 1.5' FeedEnt EOL
END
END
TrackZNO# FIRST SPZ#
IF RetractToCP1?
ToolPath
ELSE
EachFeat
IF SPZMove?
SetFlag('5')
END
NextFeat
IF Flag?('5')
SetFlagF('5')
TrackZNO# FIRST SPZ#
ToolPath
ELSE
IF CallMasterOp?
SeqLab ' CALL LBL ' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
NewMasterProg
SeqLab ' CALL LBL ' Program# EOL
StartSub
ToolPath
SeqLab ' LBL 0' EOL
{CloseSub}
ELSE
ToolPath
END
END
END
END
SetDrillEndOpZ
Rapid {no output}
SeqLab DoZL ZCP3 ZSpace DoR0 RF CheckCoolOff EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
SetAbs
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('3000')
SaveProgNum2
SetProgNum('10')
Save# Num#('1') Num#('0') { ZShiftRepeats# }
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CRCOff }
SetFlagF('3') { ArcFeat }
SetFlagF('4') { OutPut ArcFeat as StdLine when ArcR# LessThan Num#('.02mm') }
SetFlagF('5') { Variable Drill Depths }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

IF MultipleParts? AND WorkFixtureOffsets?
'; *** WARNING ***' EOL
'; THIS POST PROCESSOR DOES NOT SUPPORT WORKFIXTURE OFFSETS.' EOL
'; PLEASE SELECT EQUALLY SPACED OFFSETS.' EOL
'; *** WARNING ***' EOL
END
RETURN

InitOp:
SeqLab ' BEGIN PGM ' Program2# ' MM' EOL
IF ToolChangeAtHome?
SetHome
END
SeqLab ' BLK FORM 0.1 Z X' XStockMin# ' Y' YStockMin# ' Z' ZStockMin# EOL
SeqLab ' BLK FORM 0.2 X' XStockMax# ' Y' YStockMax# ' Z' ZStockMax# EOL
IF UseComments?
IF ProgramNameComment?
'; PROGRAM: ' ProgramName$ EOL
END
IF ProgramComment?
'; ' ProgramComment$ EOL
END
IF FormatNameComment?
'; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'; OUTPUT IN ABSOLUTE METERS' EOL
END
IF PartsComment?
'; PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'; FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
Plane {no output}
SeqLab ' TOOL DEF ' Tool# ' L' ToolLength# ' R' DIV# ToolDiameter# Num#('2') EOL
SeqLab ' TOOL CALL ' Tool# ' Z ' Speed ToolTypeComments EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
CheckPass
SeqLab DoL StrtPos XYSpace DoR0 RF SpinOn EOL
RETURN

FirstOp3:
RETURN

NewToolOp1:
Rapid {no output}
SeqLab DoL ZCP1 ZSpace DoR0 RF SpinOff EOL
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqLab DoL Home XYSpace DoR0 RF ' M91' EOL
END
SeqLab ' STOP M5' EOL
RETURN

NewToolOp3: {Start new Operation}
Plane {no output}
SeqLab ' TOOL DEF ' Tool# ' L' ToolLength# ' R' DIV# ToolDiameter# Num#('2') EOL
SeqLab ' TOOL CALL ' Tool# ' Z ' Speed ToolTypeComments EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
CheckPass
SeqLab DoL StrtPos XYSpace DoR0 RF SpinOn EOL
RETURN

NewToolOp5:
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLab ' STOP M02' EOL
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3:
Plane {no output}
SeqLab DoL StrtPos XYSpace DoR0 RF DoM EOL
RETURN

End1:
Rapid {no output}
SeqLab DoL ZCP1 ZSpace DoR0 RF SpinOff EOL
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLab DoL FirstHome XYSpace DoR0 RF ' M91' EOL
END
IF ProgStop?
SeqLab ' STOP M02' EOL
END
RETURN

End3:
Post
SeqLab ' TOOL CALL 0' EOL
SeqLab ' L M2' EOL
SeqLab ' END PGM ' Program2# ' MM' EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'; FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
'; FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
'; FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
IF EquallySpacedOffsets?
FirstOp2 {need StrtPos in Sub}
END
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
IF EquallySpacedOffsets?
NewToolOp4 {need StrtPos in Sub}
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END