{Change Comments ***********************************************************}

{12/12/91
Copied & modified: GE 1050T LeBlonde L105.82
For: Caric Machine
Rapid is not used, Feed outputs 'G21', CWArc outputs 'G23' and CCWArc outputs 'G22'.
Modifications made per Sample Program supplied.
Changed FORMAT for FeedRate from '##^###0;0' to '##^0000' in Mach Spec.
Changed FORMAT for RapidF# from '0' to '0^0000' in Prog.
Full Canned Cycle Support, without documentation.
Canned Cycles were based on GE 1050 HLX Hardinge L124.82 which is a Diameter, PosSideLathe Post.
This Post is a Radius, ToolOver('20') is NegSideLathe, others are PosSideLathe.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###^###0'
#3 = '########;0'
#4 = '0^0000'
#5 = '0000'
#6 = '###^#####0'
#7 = '+###^###0'
#8 = '###^0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolOffsetXRadius#,2)
FORMAT(TrackX#,2)
FORMAT(TrackZ#,2)
FORMAT(GECSPX#,2)
FORMAT(GECSPZ#,2)
FORMAT(CycleStartX#,2)
FORMAT(FinishXRadius#,2)
FORMAT(FinishZ#,2)
FORMAT(Peck#,2)
FORMAT(Dwell#,2) {.72}
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(RapidF#,4)
FORMAT(CalcEPRPM#,5)
FORMAT(FeedIPR#,6)
FORMAT(CutDepth#,7)

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( SUBROUTINE FOR OPERATION ' Operation# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

CheckCoolant:
IF NOT CoolOff?
IF ToolOver? ('20')
'M07'
ELSE
CoolOn
END
END
RETURN

GetGESP:
IF CannedCycle?
SetStatusOff
SetPass2
Save# Num#('1') SPX#
Save# Num#('2') SPZ#
IF Roughing?
IF NOT RoughSimple?
Save# Num#('1') ADD# Recall# Num#('1') MUL# StockXRadius# Num#('1')
Save# Num#('2') ADD# Recall# Num#('2') ADD# StockZ# NumSc#('.1')
IF ApproachFace?
IF GreaterThan? CycleStartX# FirstMoveEPX# { ODFaceApproach }
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('.1')
ELSE { IDFaceApproach }
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('-.1')
END
END
EachFeat
IF LastFeat?
IF ApproachFace?
Save# Num#('2') EPZ#
ELSE
Save# Num#('1') EPX#
END
END
NextFeat
END
ELSE
IF Threading?
IF ApproachOD?
IF ToolOver?('20')
Save# Num#('1') ADD# FinishXRadius# MUL# ThreadXInc# Num#('-1')
ELSE
Save# Num#('1') ADD# FinishXRadius# MUL# ThreadXInc# Num#('1')
END
ELSE { ApproachID }
IF ToolOver?('20')
Save# Num#('1') ADD# FinishXRadius# MUL# ThreadXInc# Num#('1')
ELSE
Save# Num#('1') ADD# FinishXRadius# MUL# ThreadXInc# Num#('-1')
END
END
ELSE { Drilling }
IF SameTool? AND LAST Drilling?
Save# Num#('3') Num#('0')
END
END
END
IF ApproachOD?
IF ToolOver?('20')
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('-.1')
ELSE
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('.1')
END
ELSE
IF ApproachID?
IF ToolOver?('20')
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('.1')
ELSE
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('-.1')
END
ELSE { ApproachFace }
IF NOT Threading? AND NOT Drilling?
Save# Num#('2') ADD# Recall# Num#('2') NumSc#('.1')
END
END
END
SetPass1
SetStatusOn
END
RETURN

GESPX:
TrackX# Recall# Num#('1')
Save# Num#('3') Recall# Num#('1')
RETURN

GESPZ:
TrackZ# Recall# Num#('2')
Save# Num#('4') Recall# Num#('2')
RETURN

GESPXC:
IF CannedCycle?
IF NotEqual? Recall# Num#('1') Recall# Num#('3')
'X' GESPX
END
ELSE
XSPC
END
RETURN

GESPZC:
IF CannedCycle?
IF NotEqual? Recall# Num#('2') Recall# Num#('4')
'Z' GESPZ
END
ELSE
ZSPC
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan GESPZC EOL
SeqLabC StockOff XOpCDC EOL
Save# Num#('3') XOpCD#
SeqLabC StockOnNoCan GESPXC FeedRate EOL
RETURN

IDApproachSP:
SeqLabC StockOnNoCan GESPZC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
Save# Num#('3') XOpCD#
SeqLabC StockOnNoCan GESPXC FeedRate EOL
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan GESPXC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
Save# Num#('4') ZOpCP#
SeqLabC StockOnNoCan GESPZC FeedRate EOL
RETURN

AppMove:
ZCP OpToolID LatheOffset CheckCoolant RapidF
Save# Num#('4') ZStockMax#
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Save# Num#('3') HomeX#
Save# Num#('4') HomeZ#
IF ApproachOD?
SeqLabC Feed XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC Feed XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC Feed StockOnNoCan GESPXC StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

TurnCSSOn:
SeqLabC CSSOn 'G96' Speed EOL
RETURN

CheckSpinOn:
IF ToolOver?('20')
SpinOn
ELSE
InverseSpinOn
END
RETURN

CheckInverseSpinOn:
IF ToolOver?('20')
InverseSpinOn
ELSE
SpinOn
END
RETURN

CheckGear:
IF NewGear?
CheckSpinOn
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
IF NewGear?
SeqLabC LOfstOff '00' SpinOff EOL
SeqLabC OpToolID LatheOffset GearRange EOL
ELSE
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
ELSE
IF NewGear?
SeqLabC SpinOff EOL
SeqLabC GearRange EOL
END
END
IF ConstantSurfaceFeed?
IF LAST NOT ConstantSurfaceFeed?
CSSOn CheckGear CalcRPM1
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOff 'G97' CheckGear Speed
END
END
IF LAST ProgStop?
SeqLabC
IF NOT NewGear?
CheckSpinOn
END
SpeedC EOL
SeqLabC CheckCoolant EOL
ELSE
SeqLabC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CheckCoolant EOL
END
END
DoPostScript
RETURN

FinishThreadStart: { For Canned Thread Cycle }
Save# Num#('6') ADD# FinishXRadius# Taper#
FORMAT(Recall#,2)
'X' Recall# Num#('6')
RETURN

FIRSTThreadCutDepth: { For Canned Thread Cycle }
FORMAT(MUL#,6)
IF ToolOver?('20')
MUL# SUB# ABS# SUB# Recall# Num#('6') FirstMoveEPX# ThreadXInc# Num#('1')
ELSE
MUL# SUB# ABS# SUB# Recall# Num#('6') FirstMoveEPX# ThreadXInc# Num#('-1')
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC ArcIJC
RETURN

GetRapidFC:
IF NOT EmptyLine?
RapidFC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04X20000' EOL
SeqLabC CheckInverseSpinOn Speed EOL
ELSE
IF Dwell?
SeqLabC 'G04X' Dwell# EOL
END
END
ELSE
IF CannedCycle?
IF Roughing?
IF NOT RoughSimple?
SeqLab
END
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC FeedC MoveXC MoveZC GetRapidFC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC ThrdLead EOL
Feed
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid1: { For NewTool OR SameTool }
IF LAST CannedCycle?
Feed
ELSE
FeedC
END
RETURN

CheckRapid2: { For End of Prog }
IF CannedCycle?
Feed
ELSE
FeedC
END
RETURN

CheckRapidF1: { For NewTool OR SameTool }
IF LAST CannedCycle?
RapidF
ELSE
GetRapidFC
END
RETURN

CheckRapidF2: { For End of Prog }
IF CannedCycle?
RapidF
ELSE
GetRapidFC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
XsAreRadii
ReverseXZArcs
NoIJKSigns
SetMaxRPM('3000')
SetMaxFeed('400')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'S' ASCII ('18') EOL
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
Plane
IF ToolOver?('20')
NegSideLathe
ELSE
PosSideLathe
END
DoOpComments
DoPostScript
GetGESP
SeqLabC AbsOrInc EOL
SeqLabC 'G70' EOL { Inch Data Input }
IF Threading?
SeqLabC 'G94' GearRange EOL { Inches Per Minute }
ELSE
SeqLabC 'G95' GearRange EOL { Inches Per Revolution }
END
SeqLab Preset Home
IF ConstantSurfaceFeed?
'R' ToolOffsetXRadius# MaxRPM
END
EOL
SeqLabC CSSOff 'G97' CheckSpinOn
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
EOL
SeqLabC 'G04X20000' OpToolID '00' EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid1
IF LAST ApproachOD?
SeqLabC XCPC CheckRapidF1 EOL
SeqLabC ZCPC GetRapidFC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC CheckRapidF1 EOL
SeqLabC ZCPC GetRapidFC EOL
ELSE { LAST ApproachFace }
SeqLabC ZCPC CheckRapidF1 EOL
END
END
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC NewHome EOL
SeqLabC LOfstOff '00'
IF NewGear?
SpinOff
END
EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

IF ToolOver?('20')
NegSideLathe
ELSE
PosSideLathe
END
DoOpComments
DoPostScript
GetGESP
SeqLabC AbsOrInc EOL
SeqLabC 'G70' EOL { Inch Data Input }
IF Threading?
SeqLabC 'G94' GearRange EOL { Inches Per Minute }
ELSE
SeqLabC 'G95' GearRange EOL { Inches Per Revolution }
END
SeqLab Preset Home
IF ConstantSurfaceFeed?
'R' ToolOffsetXRadius# MaxRPM
END
EOL
SeqLabC CSSOff 'G97' CheckSpinOn
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
EOL
SeqLabC 'G04X20000' OpToolID '00' EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
GetGESP
IF LAST StraightConnect?
CheckOffset
CheckRapid1
SeqLabC StockOnNoCan GESPXC GESPZC CheckRapidF1 EOL
ELSE
CheckRapid1
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC CheckRapidF1 EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC CheckRapidF1 EOL
SeqLabC ZCPC GetRapidFC EOL
ELSE { LAST ApproachFace }
SeqLabC ZCPC CheckRapidF1 EOL
END
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC CheckRapidF1 EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC CheckRapidF1 EOL
SeqLabC ZCPC GetRapidFC EOL
ELSE
SeqLabC ZCPC CheckRapidF1 EOL
END
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC CheckRapidF1 EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC CheckRapidF1 EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC CheckRapidF1 EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
TurnCSSOn
END
ELSE
SeqLabC Preset 'R'
IF CannedCycle?
GESPX
ELSE
CycleStartX#
END
MaxRPM EOL
TurnCSSOn
END
ELSE
TurnCSSOn
END
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
{ G81/G82 [ Turning/Facing ] Cycle:
X (Ä…3^4) = Workpiece Radius at Final Cutting Depth.
Z (Ä…3^4) = Total Cutting Length at Final Cutting Depth.
P1 ( 3^4) = Maximum Depth of Cut per Pass in the [ X/Z ] Axis, Incremental, Radial Value.
P2 (Ä…3^4) = Taper Pull-out Point at END of LAST Pass, Incremental from
Absolute StartPoint.
P3 (Ä…3^4) = Taper Pull-in Point at Beginning of LAST Pass, Incremental from
Absolute StartPoint.
P4 ( 1 ) = IF a '1' is Programmed, all Moves are 'In Zone'.
P5 ( 3^1) = Pull-in FeedRate. }
StockOn
SetPass1
IF Taper?
' ' EOL
'( NOTE: This Post Processor does not support RoughSimple Cycle with Taper!!! )' EOL
' ' EOL
END
FORMAT(FeedIPR#,8)
SeqLabC LCycle 'X' FinishXRadius# 'Z' FinishZ# 'P1' CutDepth# 'P41' 'P5' FeedIPR# FeedRate EOL
ELSE
TagInc
SetPass2
IF RoughContour?
{ G68/G69 [ Turning/Facing ] Cycle:
X (Ä…3^4) = X Axis Contour StartPoint, Radial Value.
Z (Ä…3^4) = Z Axis Contour StartPoint.
I ( 3^4) = Amount of Finish Stock in X Axis, Incremental, Radial Value.
K ( 3^4) = Amount of Finish Stock in Z Axis, Incremental Value.
P1 ( 4 ) = Sequence Number of Starting Block.
P2 ( 4 ) = Sequence Number of Ending Block.
P3 ( 3^4) = Maximum Depth of Cut per Pass in [ X/Z ] Axis, Incremental, Radial Value.
P4 (Ä…1 ) = Tracing of EACH Pass as follows:
+0 = Tool follows Contour to END of EACH Pass ( Standard Gibbs Cycle ).
-0 = Same as +0, but on LAST Pass, Tool follows entire Contour for a
Clean-up Pass.
+1 = Tool withdraws at 45Ä„ Angle at END of EACH Pass.
-1 = Same as +1, but on LAST Pass, Tool follows entire Contour for a
Clean-up Pass. }
SeqLabC LCycle XSP ZSP XStkLeft ZStkLeft 'P1Å‚' Tag# 'P2²' Tag# CutDepth 'P4+0' FeedRate EOL
ELSE
IF RoughPatternShift?
{ G66/G67 [ Turning/Facing ] Cycle:
X (Ä…3^4) = X Axis Contour StartPoint, Radial Value.
Z (Ä…3^4) = Z Axis Contour StartPoint.
I ( 3^4) = Amount of Finish Stock in X Axis, Incremental, Radial Value.
K ( 3^4) = Amount of Finish Stock in Z Axis, Incremental Value.
P1 ( 4 ) = Sequence Number of Starting Block.
P2 ( 4 ) = Sequence Number of Ending Block.
P3 ( 3^4) = Maximum Depth of Cut per Pass in [ X/Z ] Axis, Incremental,
Radial Value.
P4 ( 3^4) = Maximum, Total Amount of Stock to be Removed, Incremental,
Radial Value.
P5 ( 2 ) = Z Axis Angular Shift ²45Ä„. }
SeqLabC
IF ApproachFace?
'G67'
ELSE
LCycle { G66 }
END
XSP ZSP XStkLeft ZStkLeft 'P1Å‚' Tag# 'P2²' Tag# 'P3' CutDepth# XminusU 'P545' FeedRate EOL
END
END
IF AutoFinish?
SeqLabC 'G25P1Å‚' Tag# 'P2²' Tag# EOL
END
OpenSub
DoSubComment
'>' Tag# EOL
SeqLab
IF FIRST RapidFeat?
Rapid
ELSE
Feed
END
ToolPath
'<' Tag# EOL
CloseSub
END
ELSE
IF Threading?
{ G84 Cycle:
X (Ä…3^4) = Root Radius at Beginning of Thread, Absolute Value.
Z (Ä…3^4) = ZDepth at End of Thread, Absolute Value.
P1 ( 3^4) = Cutting Depth of FIRST Pass.
P2 ( 1^6) = Thread Lead.
P3 (Ä…3^4) = Tapered Root Radius at End of Thread, Absolute Value.
P4 (Ä…3^4) = Anticipated Pull-out Lead Distance at End of Thread. }
{ G80 AutoFinish Cycle:
P3 ( 3 ) = Control will make Additional Clean-up Pass(es). }
FORMAT(ADD#,2)
IF AutoFinish?
SeqLabC 'G80P32' EOL
END
FORMAT(FeedIPR#,6)
SeqLabC LCycle FinishThreadStart FinZ 'P1' FIRSTThreadCutDepth 'P2' FeedIPR#
IF Taper?
'P3' FinishXRadius#
END
EOL
ELSE
IF Drilling?
IF Tap?
{ G33 Cycle: }
FORMAT(FeedIPR#,6)
SeqLabC LCycle ZDepth 'K' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G04X20000' EOL
SeqLabC CheckInverseSpinOn Speed EOL
SeqLabC ZSP 'K' FeedIPR# EOL
ELSE
IF Peck? AND PeckChipBreaker?
{ G83 Cycle:
Z (Ä…3^4) = Final Hole Depth, Absolute Value.
P1 ( 3^4) = FIRST Peck Increment.
P2 ( 1^2) = Multiplier of [ P1 ] Peck Increment for Succeeding Pecks.
P3 ( 3^4) = Dwell Period at the Bottom of Hole, in Spindle Revolutions.
P4 ( 3^4) = Retract Increment after EACH Peck.
P5 ( 3^4) = Minimum Peck Increment. }
SeqLabC LCycle ZDepth Peck 'P28000'
IF Dwell?
FORMAT(MUL#,2)
'P3' MUL# DIV# Dwell# Num#('60') SpeedRPM#
END
Retract 'P5' Peck# FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth FeedRate EOL
IF Dwell?
SeqLabC 'G04X' Dwell# EOL
END
SeqLabC Rapid ZSP GetRapidFC EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLabC FeedC StrtPos GetRapidFC EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04X20000' EOL
SeqLabC CheckSpinOn Speed EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CheckRapid2
IF ApproachOD?
SeqLabC XCPC CheckRapidF2 EOL
SeqLabC ZCPC GetRapidFC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC CheckRapidF2 EOL
SeqLabC ZCPC GetRapidFC EOL
ELSE { ApproachFace }
SeqLabC ZCPC CheckRapidF2 EOL
END
END
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC FirstHome EOL
SeqLabC OpToolID '00' EOL
IF ProgStop?
SeqLabC 'M00' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
NullFoot ASCII ('4') EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END