{Change Comments ***********************************************************}

{7/27/90
Modified: GE 550 LeBlonde L080.56
For: Grand Valley
Machine: LeBlonde
Control: GE 550
Updated to Version 3.2 per Fanuc 10T MS [-] L001.70 Format
DWB}

{7/15/91
Modified: GE 550 LeBlonde L080.70
For: B R Alexander Prog
Updated to Version 3.2 per Fanuc 10T MS [-] L001.81 Format
Only Canned Cycles supported are Threading and Tapping.
DWB}

{9/25/91
Modified: GE 550 LeBlonde L080.80
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####^###0;0'
#3 = '########;0'
#4 = '###^##0'
#5 = '####^0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(RapidF#,5)

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

ODApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
SeqC StockOnNoCan XSPC FeedRate EOL
RETURN

IDApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL { for SameTool ApproachID }
SeqC StockOnNoCan XSPC FeedRate EOL
RETURN

FaceApproachSP:
SeqC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqC StockOff ZOpCPC EOL
SeqC StockOnNoCan ZSPC FeedRate EOL
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC XCP ZCP EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC XOpCD ZCP EOL
IDApproachSP
ELSE {ApproachFace}
SeqC StockOnNoCan XSP StockOff ZCP EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
END
IF NewToolOffset?
SeqC LOfstOff '00' EOL
SeqC OpToolID LatheOffset EOL
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC ArcIJC
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC 'G04X20000' EOL
ELSE
IF Dwell?
SeqC 'G04X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC FeedC MoveXC MoveZC
IF LAST ThreadFeat?
RapidF
END
RapidFC EOL
ELSE
IF LineFeat?
SeqC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC ThrdLead EOL
Feed
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid1:
IF LAST CannedCycle? AND LAST Threading?
ELSE
FeedC
END
RETURN

CheckRapid2:
IF CannedCycle? AND Threading?
ELSE
FeedC
END
RETURN

CheckRapidF1:
IF LAST CannedCycle? AND LAST Threading?
ELSE
RapidFC
END
RETURN

CheckRapidF2:
IF CannedCycle? AND Threading?
ELSE
RapidFC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
XsAreRadii
NoIJKSigns
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq Preset Home EOL
':' EOL
SeqC AbsValue OpToolID LatheOffset EOL
SeqC Feed Home RapidF EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid1
IF LAST ApproachOD?
SeqC XCPC CheckRapidF1 EOL
SeqC ZCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidF1 EOL
SeqC ZCPC EOL
ELSE {LAST ApproachFace}
SeqC ZCPC CheckRapidF1 EOL
END
END
DoEndOpPS
SeqC NewHome LOfstOff '00'
IF LAST ProgStop?
'M00'
ELSE
ProgStop
END
EOL

{Start new Operation}

':' EOL
DoOpComments
DoPostScript
Seq Preset Home EOL
':' EOL
SeqC AbsValue OpToolID LatheOffset EOL
SeqC Feed Home RapidF EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid1
SeqC StockOnNoCan XSPC ZSPC CheckRapidF1 EOL
ELSE
CheckRapid1
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC CheckRapidF1 EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidF1 EOL
SeqC ZCPC EOL
ELSE {LAST ApproachFace}
SeqC ZCPC CheckRapidF1 EOL
END
SeqC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidF1 EOL
ELSE
IF LAST ApproachOD? {around}
SeqC XCPC CheckRapidF1 EOL
SeqC ZCPC EOL
ELSE {LAST ApproachFace}
SeqC ZCPC CheckRapidF1 EOL
END
SeqC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC CheckRapidF1 EOL
ELSE
IF LAST ApproachOD? {around}
SeqC XCPC CheckRapidF1 EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC CheckRapidF1 EOL
END
SeqC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
IF Threading?
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF Taper?
SeqC
'X' ADD# FinishXRadius# Taper#
EOL
SeqC LCycle XAtFinZ FinZ ThrdLead EOL
ELSE
SeqC XAtFinZ EOL
SeqC LCycle FinZ ThrdLead EOL
END
SeqC Feed XCSP RapidF EOL
SeqC ZCSP EOL
END
ELSE
IF Drilling?
IF Tap?
SeqC LCycle ZDepth FeedRate EOL
SeqC 'G04X20000' EOL
SeqC ZSP EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqC FeedC StrtPos RapidFC EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqC 'G04X20000' EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CheckRapid2
IF ApproachOD?
SeqC XCPC CheckRapidF2 EOL
SeqC ZCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC CheckRapidF2 EOL
SeqC ZCPC EOL
ELSE {ApproachFace}
SeqC ZCPC CheckRapidF2 EOL
END
END
DoEndOpPS
SeqC FirstHome OpToolID '00' EOL
IF ProgStop?
SeqC 'M00' EOL
END
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END