{5/24/93
created initial NoSubs Processor to .81 format
FIFO stuff not supported
variables: 1 = tools 1st op; 2 = tools last op; 3 = ncCAMs last op
Jim Radcliffe}

{7/29/93, v.81.1, added FIFO handling, JR}
{8/3/93, v.81.2, SameTool WFO, RapidF#, additional FIFO handling, JR}

{2/7/94
Copied & modified: Fanuc 6M NoSubs M001.81.2
For: Tenk
Machine: Devlieg 54K-60
Cantrol: GE 550 MC
Machine has W and Z axis. Using W for milling and Z for Driling.
CRCOff on last feature.
Jim Radcliffe}

{3/11/94, .81.3 corrected variable used for PeckChipBreaker, JR}

{6/8/94
Modified: GE 550 MC Devlieg M633.81.3
For: Tenk
Negated Z and R default formats, needed for Drilling.
Negated TrackZ#, used only for and needed for Drilling.
Changed ToolOfst label from a T to a D.
Modifed DoOfstOn sub.
Added Tool change position for the W axis, using SetTCZ & TCZ# commands.
Modified DoOfstOff sub, no longer needs DoLastOfstOff sub, changed all to DoOfstOff!
Jim Radcliffe}

{10/18/94
Modified: GE 550 MC Devlieg M633.81.4
For: Tenk
Added CRCOff to start of each tool.
Changed CRCOffset label from T to D.
Moved ResetCRCNum to ToolPath.
Added 'D00' to cancel CRC line.
Changed SetTCZ('12') to SetTCZ('6')
Added SpinOn to SameTool non-ProgStop operations.
Jim Radcliffe}

{
Format: GE 550 DeVlieg 4K M908.81.5
12/18/95
Adjusted formats per fax from Jeff Casto
Added to start of output:
G90
G00W0
D00Z0
X0Y0
Changed M00 to M06
Added to tool change: G80D00Z0M05
Only Uses XYZ for moves
W0 added to M03 blocks
W0 added to canned cycles
Changed spped table to match fax from Jeff Casto
TH}

{2/9/96, Updated .81 number to .84, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{11/12/97
Initial: GE 550 DeVlieg 4K M908.87
Created: GE 550 DeVlieg 4K M908.87.1
ForUser: FC Machine
Control: GE 550
Machine: Devlieg 4K
Develop: ComPost2 1.1b2, Virtual 4.21.12
Comment: Modified per marked up readout from Jeff Casto.
Changed to leading zero format.
Modified DoOfstOn sub.
Modified Drilling:
Un-negated default format R in MachSpec.
Un-Negated TrackZ# command.
Changed 'Z' TrackZ# ClearancePlane3# to ZCP3 at end of drilling.
Updated Pecking routine.
Included Peck Full Out with manual pecking routine.
Added NegateZ initializer, Z+ is into the part.
Added NoIJKSigns initializer
Changed ToolChng output from M00 to M06.
Jim Radcliffe}

{7/31/98
Initial: GE 550 DeVlieg 4K M908.87.1
Created: GE 550 DeVlieg 4K M908.89
ForUser: FC Machine
Control: GE 550
Machine: Devlieg 4K
Develop: ComPost2 1.1b3, Virtual Gibbs 4.24
Comment: Modified per fax from John Hartge.
Modified Drilling:
Added DrillCycle to output 'G87' for FI-FO with Dwell (actually FI-Dwell-Stop-RO).
Added SpinOn to each location of the G87 cycle.
Modified DoPeck sub to account for change in Z axis direction!
Changed GreaterThan boolean to LessThan
Changed ADD# to SUB#
Changed SUB# to ADD#
Modified Arcs per GE 550 Cinc M909.87.1:
Changed Arcs to stop on quadrants.
Added K for helical interpolation.
Updated per Fanuc 6M NoSubs M877.89.4
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '#;'
#8 = '0##^####'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNo#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tag#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)
FORMAT(TCZ#,8)
FORMAT(TrackZ#,8)
FORMAT(ArcZRads#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF MultipleParts? AND SubComment?
'( PART ' Tag# ' )' EOL
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

ExitType:
IF FIFO?
FeedC
ELSE
RapidC
END
RETURN

ExitFeed:
IF FIFO?
FeedEntC
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane? AND ZMove?
MoveXYZC 'K' ArcZRads#
ELSE
MoveXYZC
END
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdRapid:
IF LastFeat? AND CutterRadiusCompensation? AND Flag?('2')
SetFlagF('2')
SeqC RapidC EOL
SeqC CRCOffC RapidC MoveXYZC 'D00' EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF LastFeat? AND CutterRadiusCompensation? AND Flag?('2')
SetFlagF('2')
SeqC FeedC FeedRateC EOL
SeqC CRCOffC MoveXYZC 'D00' EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
IF CutterRadiusCompensation? AND NOT Flag?('2')
SetFlag('2')
SeqC FeedC EOL
SeqC CRCOnC MoveXYZC FeedRateC CRCOffsetC EOL
ELSE
SeqC FeedC MoveXYZC FeedRateC EOL
END
DecelMove2
END
IF CutterRadiusCompensation? AND NOT Flag?('2')
SetFlag('2')
SeqC FeedC EOL
SeqC CRCOnC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
SeqC FeedC MoveXYZC DecelFeed EOL
END
ELSE
IF XMove? OR YMove? OR ZMove?
IF CutterRadiusCompensation? AND NOT Flag?('2')
SetFlag('2')
SeqC FeedC EOL
SeqC CRCOnC MoveXYZC FeedRateC CRCOffsetC EOL
ELSE
SeqC FeedC MoveXYZC FeedRateC EOL
END
END
END
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
IF LastFeat? AND CutterRadiusCompensation? AND Flag?('2')
SetFlagF('2')
SeqC CRCOffC 'D00' EOL
END
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
IF FeedConnect?
SeqC FeedC StrtPosC EOL
ELSE
SeqC RapidC StrtPosC EOL
END
END
END
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqC ExitType PRIME ZCP2 ExitFeed EOL
END
NextRep
ELSE
EntryMove
ToolPath2
END
SeqC AbsOrInc EOL
SeqC ExitType ZCP2 ExitFeed EOL
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

DoPeck:
IF NOT Flag?('2')
SetScale('1')
IF LessThan? ADD# Recall# Num#('4') Peck# SPZ# {IF OldZ - Peck# > Depth}
Save# Num#('4') ADD# Recall# Num#('4') Peck# {Save#1 = OldZ - Peck# = NewZ}
RestoreScale
SeqC Feed 'Z' TrackZ# MUL# Recall# Num#('4') NumSc#('1') FeedEntC EOL {move to NewZ}
IF PeckFullRetract?
SeqC Rapid 'Z' TrackZ# ClearancePlane2# EOL {move to CP2}
END
SeqC RapidC 'Z' TrackZ# SUB# Recall# Num#('4') Retract# EOL {move to RetractZ}
ELSE
RestoreScale
SeqC Feed 'Z' TrackZ# SPZ# FeedEntC EOL {move to Depth}
IF RetractToCP1?
SeqC Rapid 'Z' TrackZ# ClearancePlane1# EOL {move to CP1}
ELSE
SeqC Rapid 'Z' TrackZ# ClearancePlane2# EOL {move to CP2}
END
SetFlag('2')
END
END
RETURN

DrillCycle:
IF FIFO? AND Dwell?
'G87'
ELSE
Cycle
END
RETURN

DrillSpinOnC:
IF FIFO? AND Dwell?
IF NOT EmptyLine?
SpinOn
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC
IF FIFO? AND NOT FirstFeat?
Rapid
END
MoveSXYC EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
CutAutoCycle
ELSE { Drilling }
IF Peck?
SeqC RapidC MoveSXYC EOL
SeqC ZCP2C EOL
SetFlagF('2') { done flag }
SetScale('1')
Save# Num#('4') ClearancePlane2#
RestoreScale
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
ELSE
IF RetractToCP1? AND NotEqual? ClearancePlane1# ClearancePlane2#
IF NOT FirstFeat?
SeqC DrillCycle MoveSXYC ZDepth RLevel FeedEnt DrillSpinOnC EOL
IF NOT LastFeat?
SeqC DrillOff 'Z' TrackZ# ClearancePlane1# EOL
END
END
ELSE
SeqC MoveSXYZC DrillSpinOnC EOL {.80.01}
END
END
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF MultipleParts? AND WorkFixtureOffsets?
SeqC SetWFO EOL
ELSE
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC 'M' NewWFO# EOL
END
END
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

DoOfstOn:
SeqC ZCP1 ToolOfst EOL
IF Drilling?
SeqC 'W0' EOL { need to bring W back in, **needs a value here** }
END
RETURN

DoOfstOff:
SeqC DrillOff 'D00Z0' SpinOff EOL
RETURN

DoOp:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
DoOfstOff
END
DoOpComments
WFOStuff
ELSE
Seq AbsOrInc EOL
SeqC Rapid 'W0' EOL
SeqC 'D00Z0' EOL
SeqC 'X0Y0' EOL
SeqC Plane EOL
SeqC CRCOff EOL
DoOpComments
DoPostScript
WFOStuff
SeqC SpinOn Table(1,SpeedRPM#,1) 'W0' EOL
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC Rapid StrtPos EOL
ELSE
SeqC Rapid StrtPos EOL
DoOfstOn
SeqC CoolOn EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
{only need to set up for tool change on 1st part}
ELSE
SeqC CoolOff EOL
DoOfstOff
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M06' EOL
ELSE
SeqC ProgStop EOL
END
END

{Start new Operation}

IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
DoOfstOff
END
DoOpComments
WFOStuff
ELSE
SeqC ToolChng EOL
Seq AbsOrInc EOL
SeqC Plane EOL
SeqC CRCOff EOL
DoOpComments
DoPostScript
WFOStuff
SeqC SpinOn Table(1,SpeedRPM#,1) 'W0' EOL
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC Rapid StrtPos EOL
ELSE
SeqC Rapid StrtPos EOL
SeqC DoOfstOn EOL
SeqC CoolOn EOL
END
ELSE
IF SameTool?

{Finish off last Operation}

IF LAST ProgStop?
SeqC CoolOff EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF LAST ProgStop? OR NewToolOffset?
DoOfstOff
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M06' EOL
END

{Start new Operation}

DoOpComments
DoPostScript
WFOStuff
CheckPass
SeqC PlaneC EOL
SeqC SpinOn Table(1,SpeedRPM#,1) 'W0' EOL
SeqC Rapid StrtPos EOL
IF LAST ProgStop? OR NewToolOffset?
SeqC DoOfstOn EOL
END
IF LAST ProgStop?
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END

{ Common Point for All Operations }

RapidF# {forces the output of a conditional feedrate for each operation}

IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqC
IF NOT FeedConnect?
ExitType PRIME ZCP3C
END
ExitFeed EOL
NEXTRep
END
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
SeqC ExitType ZCP3C ExitFeed EOL
END
ELSE
IF Drilling?
IF Repeats?
EACHRep
DoSubComment
END
GetCycle
IF NOT Peck?
SeqC DrillCycle StrtPos ZDepth RLevel 'W0' FeedEnt EOL
TrackZNO# FIRST SPZ#
IF RetractToCP1? AND NotEqual? ClearancePlane1# ClearancePlane2#
SeqC DrillOff 'Z' TrackZ# ClearancePlane1# EOL
END
END
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff ZCP3 EOL
IF Repeats?
NEXTRep
END
SeqC RapidC ZCP3C EOL
END
END
RETURN

FinishLastOp:
SeqC CoolOff EOL
DoOfstOff
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC Rapid FirstHome EOL
END
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart? {no tool change after doing last part}
IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
ELSE
EOP EOL
END
RETURN

DoToolsOps:
EachOp
IF GTEqual? Operation# Recall# Num#('1') AND LTEqual? Operation# Recall# Num#('2')
{Tools1stOp ² op ² ToolsLastOp}
DoOp
END
NextOp
RETURN

NextTools1stOp:
SetNextToolOp Operation#
RETURN

GetToolsOps:
EachOp
IF Equal? Operation# Recall# Num#('1') {if op = Tools1stOp}
IF GreaterThan? NextTools1stOp Recall# Num#('1') {if NextTools1stOp is greater Tools1stOp}
Save# Num#('2') SUB# NextTools1stOp Num#('1') {ToolsLastOp becomes NextTools1stOp less 1}
ELSE {else}
Save# Num#('2') Recall# Num#('3') {ToolsLastOp becomes ncCAMsLastOp}
END
END
NextOp
RETURN

DoTool:
IF NOT Flag?('1')
GetToolsOps
IF WorkFixtureOffsets?
NewWFO
EachWFO
TagInc
DoToolsOps
IncWFO
NextWFO
ELSE
EachPart
TagInc
DoToolsOps
NextPart
END
IF LessThan? Recall# Num#('2') Recall# Num#('3') {if ToolsLastOp < ncCAMsLastOp}
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') {Tools1stOp becomes NextTools1stOp}
ELSE {else}
SetFlag('1') {set DoneFlag}
END
TagInit
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
SetFlagF('1') {done flag}
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
SetTCZ('6')
NegateZ
NoIJKSigns
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' ToolChangeZ(6), TCZ(6) -' EOL
' Specify the tool change position for the W axis.' EOL
' The value in paentheses will be used for all following operations.' EOL
' by defualt, the output is W60000.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
END
NextOp
IF MultipleParts?
IF AllToolsOnePart?
IF WorkFixtureOffsets?
NewWFO
EachWFO
TagInc
EachOp
DoOp
NextOp
FinishLastOp
IncWFO
NextWFO
ELSE
EachPart
TagInc
EachOp
DoOp
NextOp
FinishLastOp
NextPart
END
ELSE
IF OneToolAllParts?
EachOp
IF FirstOperation?
Save# Num#('1') Operation# {ncCAMs1stOp becomes Tools1stOp}
END
IF LastOp?
Save# Num#('3') Operation# {save ncCAMsLastOp}
END
NextOp
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
FinishLastOp
END
END
ELSE
EachOp
DoOp
NextOp
FinishLastOp
END
EOR EOL
CloseSub
Post2
IF UseComments?
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close