{Change Comments ***********************************************************}

{7/18/90
Copied & modified: GE 550 HNC L003.52
Updated to Version 3.2 per Fanuc 10T MS [-] L001.70 Format
DWB}

{1/24/91
Modified: GE 550 HNC L003.70
For: Zenith Screw Products, Inc.
Added literal 'F10000' to FirstOperation.
Modified for Threading operation to remove ouput of RapidF, 'G95' & 'G94'.
Deleted CoolOff, SpinOff & UnTool from end of prog.
JR}

{7/15/91
Modified: GE 550 HNC L003.71
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Rapid outputs 'G94' to set control into ipm, Feed outputs 'G95' to set control
into ipr. 'G01' is only output on initial Approach line from FirstOperation and
NewTool, and to cancel 'G02/G03', Thread Cycle and Canned Drill Cycles.
Only Canned Cycles supported are Threading and Tapping.
DWB}

{9/25/91
Modified: GE 550 HNC L003.80
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
DWB}

{9/25/91
Modified: GE 550 HNC L003.80
For: Zenith Screw Products, Inc.
Added Progstop before first ':' in FirstOp.
KLM}

{5/18/95
Updated: GE 550 HNC L003.82.1
For: Gibbs & Associates/Giffen Tec
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.05/Catalyst v2.14.40/Compost 4.21.28
Updated to Version 4.1 per Numbers Lathe L001.82.1a Format.
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Modified non-CannedCycle AutoFinish.
Method of testing for IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple? AND NOT Threading?
did not allow for AutoFinish pass of IF Turning?
Rewrote to test for IF Turning? ELSE IF Roughing? AND NOT RoughSimple?
Modified AutoFinish Approach.
Added XSPC ZSPC at AutoFinish for NOT CannedCycle AND NOT Turning Operations.
Changed RapidC StrtPos to StockOff StrtPosC at AutoFinish for NOT CannedCycle Operations.
Added support for AutoFinish of non-Canned Threading Cycle.
Combined DiaApproachSP and FaceApproachSP subs into one ApproachSP to further simplify.
DWB}

{9/7/95, Updated GE 550 HNC L003.82.2 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####^###0'
#3 = '#######0'
#4 = '###^##0'
#5 = '###^0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(MUL#,2)
FORMAT(FinishXRadius#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(RapidF#,5)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

GetRapidF:
IF NOT Threading? AND NOT EmptyLine?
IF SameTool?
RapidFC
ELSE
RapidF
END
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC GetRapidF EOL
SeqC StockOff ZOpCPC GetRapidF EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
IF Threading?
SeqC ZSPC EOL
ELSE
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC GetRapidF EOL
SeqC StockOff XOpCDC GetRapidF EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
IF Threading?
SeqC XSPC EOL
ELSE
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC LOfstOff '00' EOL
SeqC OpToolID LatheOffset EOL
END
SeqC SpeedGE EOL
IF LAST ProgStop?
SeqC SpinOnGE EOL
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
'G02'
ELSE
'G03'
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G04X20000' EOL
SeqC SpeedGE
IF GreaterThan? SpeedRPM# Num#('600') { Refer to SpeedGE command in ComPost Dictionary }
IF CWSpindle?
'M44' { High-InverseSpinOnGE }
ELSE
'M43' { High-SpinOnGE }
END
ELSE { SpeedRPM# <= 600 }
InverseSpinOn
END
EOL
ELSE
IF Dwell?
SeqC 'G04X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC
IF NOT Rapid?
RapidC
END
IF NOT FirstFeat? AND LAST ArcFeat?
EOL
SeqC 'G01'
END
MoveXC MoveZC
IF NOT FirstFeat? AND LAST ThreadFeat?
RapidF
END
RapidFC EOL
ELSE
IF LineFeat?
SeqC CkCRC
IF Rapid?
EOL
SeqC FeedC
END
IF NOT FirstFeat? AND LAST ArcFeat?
EOL
SeqC 'G01'
END
MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
IF Rapid?
SeqC FeedC EOL
END
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC ThrdLead EOL
'G01'
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF Flag?('1') { End of Prog }
IF CannedCycle? AND Threading?
ELSE
RapidC
END
ELSE { NewTool }
IF LAST CannedCycle? AND LAST Threading?
ELSE
RapidC
END
END
RETURN

CheckRapidF:
IF NOT EmptyLine?
IF Flag?('1') { End of Prog }
IF CannedCycle? AND Threading?
ELSE
RapidFC
END
ELSE { NewTool }
IF LAST CannedCycle? AND LAST Threading?
ELSE
RapidFC
END
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
XsAreRadii
NoIJKSigns
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq Rapid 'F10000M91' EOL
SeqC IncValue EOL
SeqC 'G01X-30000Z0' EOL
SeqC ProgStop EOL
':' EOL
SetAbs
Seq Preset Home EOL
':' EOL
SeqC AbsValue OpToolID LatheOffset SpinOnGE EOL
SeqC Rapid SpeedGE CoolOn EOL
SeqC 'G01' Home 'F10000' EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC CheckRapidF EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidF EOL
END
END
SeqC LAST OpExitZCPC CheckRapidF EOL
DoEndOpPS
SeqC NewHome 'F10000' EOL
SeqC OfstOff
IF LAST ProgStop?
'M00'
ELSE
ProgStop
END
EOL
SeqC 'G01' NewHome EOL

{Start new Operation}

DoOpComments
DoPostScript
':' EOL
Seq Preset Home EOL
':' EOL
SeqC AbsValue OpToolID LatheOffset SpinOnGE EOL
SeqC Rapid SpeedGE CoolOn EOL
SeqC 'G01' Home 'F10000' EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC CheckRapidF EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC CheckRapidF EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidF EOL
END
SeqC LAST OpExitZCPC CheckRapidF EOL
SeqC LAST OpExitXCPC CheckRapidF EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidF EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC CheckRapidF EOL
END
SeqC LAST OpExitZCPC CheckRapidF EOL
SeqC XOpCDC CheckRapidF EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC CheckRapidF EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC CheckRapidF EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC CheckRapidF EOL
END
SeqC LAST OpExitZCPC CheckRapidF EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
IF Threading?
StockOn
SetPass1
ToolPath
IF AutoFinish?
SeqC 'X' ADD# FinishXRadius# Taper# EOL
SeqC LCycle
IF Taper?
'X' FinishXRadius#
END
FinZ ThrdLead EOL
SeqC 'G01' XCSP RapidF EOL
SeqC ZCSP EOL
END
ELSE
IF Drilling?
IF Tap?
SeqC LCycle ZDepth FeedRate EOL
SeqC SpinOff EOL
SeqC 'G04X20000' EOL
SeqC SpeedGE
IF GreaterThan? SpeedRPM# Num#('600') { Refer to SpeedGE command in ComPost Dictionary }
IF CWSpindle?
'M44' { High-InverseSpinOnGE }
ELSE
'M43' { High-SpinOnGE }
END
ELSE { SpeedRPM# <= 600 }
InverseSpinOn
END
EOL
SeqC ZSP EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC RapidFC EOL
ELSE
SeqC RapidC XOpECDC RapidFC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC RapidFC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC 'X' ADD# FinishXRadius# Taper# EOL
SeqC LCycle
IF Taper?
'X' FinishXRadius#
END
FinZ ThrdLead EOL
SeqC 'G01' XSP RapidF EOL
SeqC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G04X20000' EOL
SeqC SpeedGE SpinOnGE EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
SetFlag('1') { end of Prog }
CheckRapid
IF ApproachOD?
SeqC OpExitXCPC CheckRapidF EOL
ELSE
IF ApproachID?
SeqC XOpECDC CheckRapidF EOL
END
END
SeqC OpExitZCPC CheckRapidF EOL
DoEndOpPS
SeqC FirstHome 'F10000' EOL
SeqC OfstOff ProgStop EOL
SeqC 'G01' Home EOL
SeqC IncValue 'X30000Z0' EOL
IF ProgStop?
SeqC 'M00' EOL
END
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END