{Change Comments ***********************************************************}

{7/18/90
Copied & modified: GE 550 HNC L003.52
Updated to Version 3.2 per Fanuc 10T MS [-] L001.70 Format
DWB}

{7/30/90
Copied & modified: GE 550 HNC L003.70
For: Geneva Steel
Machine: Monarch
Control: GE 550
Updated to Version 3.2 per Fanuc 10T MS [-] L001.70 Format
Modified all FORMATs to be leading zero not suppressed.
Added FORMATs for RapidF# and ToolOffset# in prog.
Added literal 'G01' to first line of Approach move.
Changed all occurances of LatheOffset to ToolOffset#.
Added SetHome to FirstOperation.
Deleted all occurances of OfstOff.
Major changes to EachOp loop data.
DWB}

{8/9/90
Copied & modified: GE 550 Monarch (GS) L.70
For: Geneva Steel
Modified all lines that would combine 'G95' or 'G94' with any thing else. These two commands
are required to be all by themselves.
Added additional leading zero to 'I', 'K' and 'Z' formats in form.
DWB}

{7/15/91
Modified: GE 550 Monarch (GS) L.71.1
For: Geneva Steel
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Made modifications per Dan Baxter at Geneva Steel.
Rapid outputs 'G94' to set control into ipm, Feed outputs 'G95' to set control
into ipr. 'G01' is only output on initial Approach line from FirstOperation and
NewTool, and to cancel 'G02/G03', Thread Cycle and Canned Drill Cycles.
Only Canned Cycles supported are Threading and Tapping.
Following modifications made per Dan Baxter at Geneva Steel:
Changed FeedRate to 'F005' in Approach sub.
Changed FORMAT for I Arc Center address from '0##^####;0' to '0#^####;0' in Form.
Changed FORMAT for K ThrdLead address from '0#^####;0' to '0^####;0' in Form.
Deleted literal 'M06' from NewTool.
DWB}

{04/23/92
Modified: GE 550 Monarch 75 L223.80
For: Geneva Steel
Added 'XTapAtZ' to the Thrdlead lines to enable an 'I' output,
also added an 'I' with formating code in the form for same reason.
Added 'T000' at the end of each operation.
Made the CWArc and CCWArc unconditional to force a G02, G03 on every arc move.
Added 'AbsValue' to the beginning of all operations.
Kim Michelman}

{2/25/94
Modified: GE 550 Monarch 75 L223.80.1
For: Geneva Steel
Change requests by Dan Baxter.
Added 40 spaces in front of all comments to place in center of page.
Added dwell value to CheckOffset for SpinOnGE.
Deleted usage of M44 & M43 commands.
Changed FeedRate in Approach from F005 to F015.
Updated per Fanuc 10T MS [-] L001.82ż.
Changed AbsValue to AbsOrInc so MoveType$ would reflect true status.
Updated logic for G94/G95 handling, this greatly simplifies ToolPath!
Added InchPerMin/InchPerRev subs using Flag#1 to output literal G94/G95.
Changed MachSpec Feed from G95 to G01.
Changed MachSpec Rapid from G94 to nothing, Rapid is not used.
Changed literal 'G01' to Feed.
Jim Radcliffe}

{
Format: GE 550 Monarch 75 L223.82.1
Changed FORMAT for K ThrdLead address from '0#^####;0' to '0^####;0' in Form.
TH}

{9/7/95, Updated GE 550 Monarch 75 L223.82.1 to .85 format per v2.20 Update Instructions .01, JR}

{11/25/95
Modified: GE 550 Monarch 75 L223.85
For: Geneva Steel
Change requests by Dan Baxter.
Changed the MachSpec format of 'K' word in threading cycle.
Changed spindle forward and reverse commands in MachSpec.
Changed 'First' and 'Last' Work Fixture Offset to M03 & M04 in MachSpec,
they don't want the 'high CW' or 'high CCW' GE commands.
Joe Cusimano}

{11/25/95
Modified: GE 550 Monarch 75 L223.85.1
Created: GE 550 Monarch 75 L223.85.2
For: Geneva Steel per Dan Baxter
Changed the MachSpec format of 'K' arc centers.
Joe Cusimano}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = 'ą0#^####;0'
#3 = '########;0'
#4 = '0##^###;0'
#5 = '^0###;0'
#6 = '0^####;0'
#7 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(MUL#,2)
FORMAT(FinishXRadius#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(RapidF#,5)
FORMAT(FeedIPR#,6)
FORMAT(ToolOffset#,7)

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
' ( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
' ( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
' ( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
' ( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
' ( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

InchPerRev:
IF NOT Flag?('1')
SetFlag('1') 'G95'
END
RETURN

InchPerMin:
IF Flag?('1')
SetFlagF('1') 'G94'
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
InchPerRev
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
'F015'
END
RETURN

ODApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan EOL
SeqC XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan EOL
SeqC XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan EOL
SeqC ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ThisOpEntryZCP RapidF
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
SeqC CoolOn EOL
SeqC InchPerMin EOL
Feed
IF ApproachOD?
SeqC StockOff ThisOpEntryXCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC LOfstOff '00' EOL
SeqC OpToolID ToolOffset# EOL
END
IF LAST ProgStop?
SeqC 'G04X06' GearRange SpinOnGE EOL
SeqC CoolOn EOL
ELSE
IF NewGear?
SeqC 'G04X06' GearRange EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXC MoveZC ArcIJC
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G04X002' EOL
SeqC InverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G04X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC InchPerMin EOL
SeqC FeedC MoveXC MoveZC RapidFC EOL
ELSE
IF LineFeat?
SeqC InchPerRev EOL
SeqC CkCRC EOL
SeqC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
SeqC InchPerRev EOL
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC InchPerRev EOL
SeqC 'G33' MoveXC MoveZC XTapAtZ ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
SeqC CRCOffC EOL
SeqC InchPerMin EOL
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
XsAreRadii
NoIJKSigns
SetMaxRPM('2000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
' ( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
' ( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
' ( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
' ( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
' ( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq AbsOrInc EOL
SeqC InchPerRev EOL
SeqC Preset Home EOL
SeqC 'G04X06' GearRange OpToolID ToolOffset# SpinOnGE EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC RapidFC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC RapidFC EOL
END
END
SeqC LAST OpExitZCPC RapidFC EOL
DoEndOpPS
SeqC SpinOff EOL
SeqC CoolOff EOL
SeqC NewHome EOL
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
SeqC 'T000' EOL

{Start new Operation}

DoOpComments
DoPostScript
Seq AbsOrInc EOL
SeqC InchPerRev EOL
SeqC Preset Home EOL
SeqC 'G04X06' GearRange OpToolID ToolOffset# SpinOnGE EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

SeqC 'T000' EOL
DoOpComments
Seq AbsOrInc EOL
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC RapidFC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC RapidFC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC RapidFC EOL
END
SeqC LAST OpExitZCPC RapidFC EOL
SeqC LAST OpExitXCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC RapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC RapidFC EOL
END
SeqC LAST OpExitZCPC RapidFC EOL
SeqC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC RapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC RapidFC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC RapidFC EOL
END
SeqC LAST OpExitZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
IF Threading?
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF Taper?
SeqC 'X' ADD# FinishXRadius# MUL# Taper# NumSc#('1') EOL
SeqC InchPerRev EOL
SeqC LCycle 'X' FinishXRadius# FinZ XTapAtZ ThrdLead EOL
ELSE
SeqC 'X' FinishXRadius# EOL
SeqC InchPerRev EOL
SeqC LCycle FinZ XTapAtZ ThrdLead EOL
END
SeqC InchPerMin EOL
SeqC Feed XCSP RapidF EOL
SeqC ZCSP EOL
END
ELSE
IF Drilling?
IF Tap?
SeqC LCycle ZDepth 'K' FeedIPR# EOL
SeqC SpinOff EOL
SeqC 'G04X002' EOL
SeqC InverseSpinOn EOL
SeqC LCycle ZSP 'K' FeedIPR# EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
SeqC InchPerMin EOL
IF ApproachFace?
SeqC ZOpECPC RapidFC EOL
FaceApproachSP
ELSE
SeqC XOpECDC RapidFC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqC InchPerMin StrtPos RapidFC EOL
END
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G04X002' EOL
SeqC SpinOnGE EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
SeqC CRCOffC EOL
SeqC InchPerMin EOL
IF ApproachOD?
SeqC OpExitXCPC RapidFC EOL
ELSE
IF ApproachID?
SeqC XOpECDC RapidFC EOL
END
END
SeqC OpExitZCPC RapidFC EOL
DoEndOpPS
SeqC CoolOff EOL
SeqC FirstHome EOL
IF ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END
SeqC 'T000' EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
' ( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
' ( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
' ( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END