{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{5/24/93
created initial NoSubs Processor to .81 format
FIFO stuff not supported
variables: 1 = tools 1st op; 2 = tools last op; 3 = ncCAMs last op
Jim Radcliffe}

{7/29/93, v.81.1, added FIFO handling, JR}
{8/3/93, v.81.2, SameTool WFO, RapidF#, additional FIFO handling, JR}

{2/7/94
Copied & modified: Fanuc 6M NoSubs M001.81.2
For: Tenk
Machine: Devlieg 54K-60
Cantrol: GE 550 MC
Machine has W and Z axis. Using W for milling and Z for Driling.
CRCOff on last feature.
Jim Radcliffe}

{3/11/94, .81.3 corrected variable used for PeckChipBreaker, JR}

{6/8/94
Modified: GE 550 MC Devlieg M633.81.3
For: Tenk
Negated Z and R default formats, needed for Drilling.
Negated TrackZ#, used only for and needed for Drilling.
Changed ToolOfst label from a T to a D.
Modifed DoOfstOn sub.
Added Tool change position for the W axis, using SetTCZ & TCZ# commands.
Modified DoOfstOff sub, no longer needs DoLastOfstOff sub, changed all to DoOfstOff!
Jim Radcliffe}

{2/9/96, Updated .81 number to .84, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{23Jun98
Original: GE 550 MC Devlieg M633.87
Created: GE 550 LH Century [SN] MU25.87
For: Shepard Niles
Changes made per: Brain McLean
NEW POST. FIRST DRAFT
Changed Formatting for I,J,X,Y,Z,R to 0##^#### in MachSpec
Added Formatting for SIN#, COS#, Retract#, ClearancePlane1#, ClearancePlane2#, ClearancePlane3#
Changed Format#8 from '###^###0' to '0##^####'
Changed Format#9 from '*###^###0' to '*0##^####'
Deleted all Reference to TCZ# in the Prog
Added Spacing to all Codes in the Prog and MachSpec
Added SignBlock, CompBlock, DoCRCOnC and DoCRCOffC Subs.
Rewrote StdLine Sub.
Deleted CutterRadiusCompensation called in ToolPath, StdRapid, StdLine and StdArc
and replaced it with CRC based on the SIN# and COS# angles of the CRCon Move.
Added support for 'G86' Milling cycle, called in DoOfstOn
Deleted the contents of DoOfstOff Sub. ( Not Supported )
Rewrote the Logic of FirstOperation and NewTool Per customers requirements
Deleted Plane commands in MachSpec ( Plane is called but no output is required )
Rewrote the Table Resource in the Form. 53 items ( Note: Table avoids overlaping Speed# calls )
Added IF Milling? OR PeckChipBreaker? Boolean to FirstOp and NewTool
Deleted calls to WFOStuff in FirstOp and NewTool
Added support for DeadSpindleRetract Drill Cycle in the Prog ( Cycle requires customer to use a custom MDD )
Deleted Booleans for redundant ClearancePlane moves when Drilling
Added ToolChng at End of Prog
Added TagInit at Start of executable Prog
Charles Winston}

{24Nov98
Original: GE 550 LH Century [SN] MU25.87
Created: GE 550 Century [SN] NMU25.87
For: Shepard Niles
Changes made per: Brain McLean
Added Post Header Comment at the top of Prog.
Added CoolOn in FirstOperation, NewTool and SameTool
Added Coolant Code M08 in MachSpech
Added the Y-Retract to the Current Drill Y-value, in Drilling, when FIStopOffWallRO is TRUE.
Provides clearance for the Tool after Spindle Orient.
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '#;'
#8 = '0##^####'
#9 = '*0##^####'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)
FORMAT(Retract#,8)
FORMAT(SIN#,8)
FORMAT(COS#,8)
FORMAT(Add#,8)
FORMAT(TrackY#,8)
FORMAT(TrackZ#,9)
FORMAT(ClearancePlane1#,9)
FORMAT(ClearancePlane2#,9)
FORMAT(ClearancePlane3#,9)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF MultipleParts? AND SubComment?
'( PART ' Tag# ' )' EOL
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

ExitType:
IF FIFO?
FeedC
ELSE
RapidC
END
RETURN

ExitFeed:
IF FIFO?
FeedEntC
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdRapid:
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

SignBlock:
IF GreaterThan? SPMoveAngle# Num#('270')
' X Y-'
ELSE
IF GreaterThan? SPMoveAngle# Num#('180')
' X- Y-'
ELSE
IF GreaterThan? SPMoveAngle# Num#('90')
' X- Y'
ELSE
' X Y'
END
END
END
RETURN

CompBlock:
IF GreaterThan? SPMoveAngle# Num#('270')
' I' SIN# SUB# SPMoveAngle# Num#('270') ' J' COS# SUB# SPMoveAngle# Num#('270')
ELSE
IF GreaterThan? SPMoveAngle# Num#('180')
' I' COS# SUB# SPMoveAngle# Num#('180') ' J' SIN# SUB# SPMoveAngle# Num#('180')
ELSE
IF GreaterThan? SPMoveAngle# Num#('90')
' I' SIN# SUB# SPMoveAngle# Num#('90') ' J' COS# SUB# SPMoveAngle# Num#('90')
ELSE
' I' COS# SPMoveAngle# ' J' SIN# SPMoveAngle#
END
END
END
RETURN

DoCRCOnC:
IF CutterRadiusCompensation?
IF NOT Flag?('2')
SeqC IncValue EOL
SeqC Feed SignBlock EOL
SeqC CRCOn CompBlock CRCOfst EOL
SeqC AbsOrInc EOL
SetFlag('2')
END
END
RETURN

DoCRCOffC:
IF LastFeat?
IF Flag?('2')
SeqC CRCOff EOL
SetFlagF('2')
END
END
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO?
SeqC FeedC PRIME ZCP2 FeedEntC EOL
ELSE
SeqC RapidC PRIME ZCP2 EOL
END
END
NextRep
ELSE
EntryMove
ToolPath2
END
IF FIFO?
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

DoLastPeck: {OldZ - Peck# ² Depth}
SeqC Feed ' Z' TrackZ# SPZ# FeedEntC EOL {move to Depth}
IF RetractToCP1?
SeqC Rapid ' Z' TrackZ# ClearancePlane1# EOL {move to CP1}
ELSE
SeqC Rapid ' Z' TrackZ# ClearancePlane2# EOL {move to CP2}
END
RETURN

DoPeck:
IF GreaterThan? SUB# Recall# Num#('4') Peck# SPZ# {IF OldZ - Peck# > Depth}
Save# Num#('4') SUB# Recall# Num#('4') Peck# {Save#1 = OldZ - Peck# = NewZ}
SeqC Feed ' Z' TrackZ# Recall# Num#('4') FeedEntC EOL {move to NewZ}
SeqC RapidC ' Z' TrackZ# ADD# Recall# Num#('4') Retract# EOL {move to RetractZ}
END
RETURN

ToolPath:
EACHFeat
DoCRCOnC
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqC
IF FIFO?
Rapid
END
MoveSXYC EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
CutAutoCycle
ELSE { Drilling }
IF PeckChipBreaker?
SeqC RapidC MoveSXYC EOL
SeqC ' Z' TrackZ# ClearancePlane2# EOL {**need to make this conditional**}
Save# Num#('4') ClearancePlane2#
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoLastPeck
ELSE
IF RetractToCP1? AND NotEqual? ClearancePlane1# ClearancePlane2#
IF NOT FirstFeat?
SeqC Cycle MoveSXYC ZDepth RLevel FeedEnt EOL
IF NOT LastFeat?
SeqC DrillOff ' Z' TrackZ# ClearancePlane1# EOL
END
END
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
END
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
DoCRCOffC
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC ' M' NewWFO# EOL
END
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

DoOfstOn:
SetAbs
' G86' ' R' ClearancePlane1# ZCP1 ToolOfst
SetAbsOrInc
RETURN

DoOfstOff:
{ Not Supported }
RETURN

DoOp:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
DoOfstOff
END
DoOpComments
ELSE
Plane { no output }
Seq AbsOrInc SpinOn EOL
IF FIStopOffWallRO?
SeqC AbsOrInc ' M14' EOL
END
DoOpComments
DoPostScript
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC Rapid StrtPos EOL
ELSE
SeqC Rapid StrtPos Table(1,SpeedRPM#,1) OpToolID ToolChng EOL
IF Milling? OR PeckChipBreaker?
SeqC DoOfstOn CoolOn EOL
END
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
{only need to set up for tool change on 1st part}
ELSE
SeqC CoolOff EOL
DoOfstOff
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home SpinOff EOL
ELSE
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END
END

{Start new Operation}

IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
DoOfstOff
END
DoOpComments
ELSE
Plane { no output }
Seq AbsOrInc SpinOn EOL
IF FIStopOffWallRO?
SeqC AbsOrInc ' M14' EOL
END
DoOpComments
DoPostScript
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC Rapid StrtPos EOL
ELSE
SeqC Rapid StrtPos Table(1,SpeedRPM#,1) OpToolID ToolChng EOL
IF Milling? OR PeckChipBreaker?
SeqC DoOfstOn CoolOn EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
DoOfstOff
SeqC SpinOff EOL
SeqC ' M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC EOL
SeqC SpinOn Table(1,SpeedRPM#,1) EOL
SeqC Rapid StrtPos EOL
IF Milling? OR PeckChipBreaker?
SeqC DoOfstOn CoolOn EOL
END
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
DoOfstOff

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC EOL
SeqC Table(1,SpeedRPM#,1) EOL
SeqC Rapid StrtPos EOL
IF Milling? OR PeckChipBreaker?
SeqC DoOfstOn
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
END
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC EOL
SeqC Table(1,SpeedRPM#,1) EOL
SeqC Rapid StrtPos EOL
IF NOT CoolOff? AND LAST CoolOff?
IF Milling? OR PeckChipBreaker?
CoolOn
END
END
END
END
END
END
END

{ Common Point for All Operations }

ResetCRCNum {call here to reset for each new operation only, call in tool path to reset for each repeat in an operation}
RapidF# {forces the output of a conditional feedrate for each operation}

IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqC
IF NOT FeedConnect?
ExitType PRIME ZCP3C
END
ExitFeed
EOL
NEXTRep
END
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
SeqC ExitType ZCP3C ExitFeed EOL
END
ELSE
IF Drilling?
IF Repeats?
EACHRep
DoSubComment
END
GetCycle
IF NOT PeckChipBreaker?
IF FIStopOffWallRO?
SeqC ' G87'
ELSE
SeqC Cycle
END
RLevel ZDepth ToolOfst
IF NOT TAP?
FeedEnt
END
CoolOn EOL
IF FIStopOffWallRO?
SeqC Rapid ' M19' EOL
END
TrackZNO# ZDepth#
END
ToolPath
IF FIStopOffWallRO?
SeqC RapidC ' Y' Add# SPY# Retract# EOL
END
IF RetractToCP1?
TrackZNO# ClearancePlane1#
SeqC DrillOff ' Z' TrackZ# ClearancePlane1# EOL
ELSE
TrackZNO# ClearancePlane2#
SeqC DrillOff ' Z' TrackZ# ClearancePlane2# EOL
END
IF Repeats?
NEXTRep
END
END
END
RETURN

FinishLastOp:
SeqC CoolOff EOL
SeqC ToolChng EOL
DoOfstOff
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC AbsOrInc Rapid FirstHome SpinOff EOL
ELSE
SeqC AbsOrInc SpinOn EOL
END
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart? {no tool change after doing last part}
IF ProgStop?
SeqC ' M0' EOL
ELSE
SeqC ProgStop EOL
END
ELSE
EOP EOL
END
RETURN

DoToolsOps:
EachOp
IF GTEqual? Operation# Recall# Num#('1') AND LTEqual? Operation# Recall# Num#('2')
{Tools1stOp ² op ² ToolsLastOp}
DoOp
END
NextOp
RETURN

NextTools1stOp:
SetNextToolOp Operation#
RETURN

GetToolsOps:
EachOp
IF Equal? Operation# Recall# Num#('1') {if op = Tools1stOp}
IF GreaterThan? NextTools1stOp Recall# Num#('1') {if NextTools1stOp is greater Tools1stOp}
Save# Num#('2') SUB# NextTools1stOp Num#('1') {ToolsLastOp becomes NextTools1stOp less 1}
ELSE {else}
Save# Num#('2') Recall# Num#('3') {ToolsLastOp becomes ncCAMsLastOp}
END
END
NextOp
RETURN

DoTool:
IF NOT Flag?('1')
GetToolsOps
EachPart
TagInc
DoToolsOps
NextPart
IF LessThan? Recall# Num#('2') Recall# Num#('3') {if ToolsLastOp < ncCAMsLastOp}
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') {Tools1stOp becomes NextTools1stOp}
ELSE {else}
SetFlag('1') {set DoneFlag}
END
TagInit
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
SetFlagF('1') {done flag}
SetFlagF('2') {CRCOn flag}
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
SetTCZ('12')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
END
NextOp
IF MultipleParts?
IF AllToolsOnePart?
EachPart
TagInc
EachOp
DoOp
NextOp
FinishLastOp
NextPart
ELSE
IF OneToolAllParts?
EachOp
IF FirstOperation?
Save# Num#('1') Operation# {ncCAMs1stOp becomes Tools1stOp}
END
IF LastOp?
Save# Num#('3') Operation# {save ncCAMsLastOp}
END
NextOp
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
FinishLastOp
END
END
ELSE
EachOp
DoOp
NextOp
FinishLastOp
END
EOR EOL
CloseSub
Post2
IF UseComments?
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close