{Change Comments ***********************************************************}

{8/17/95,
Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85.01 Format.
DWB}

{5/28/96,
Initial: GE 550 HNC [GT] L346.85
Created: GE 550 HNC [GT] L346.85.1
Deleted move to NewHome before Tool Offset cancel in NewTool, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####^###0'
#3 = '#######0'
#4 = '###^##0'
#5 = '###^0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(MUL#,2)
FORMAT(FinishXRadius#,2)
FORMAT(DIV#,3)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(RapidF#,5)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

GetRapidF:
IF NOT Threading? AND NOT EmptyLine?
IF SameTool?
RapidFC
ELSE
RapidF
END
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC GetRapidF EOL
SeqC StockOff ZOpCPC GetRapidF EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC GetRapidF EOL
SeqC StockOff XOpCDC GetRapidF EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
IF Threading?
SeqC XSPC EOL
ELSE
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

GetSpinOnGE: { Virtual does not recognize SpinOnGE }
IF GreaterThan? SpeedRPM# Num#('600') { Refer to SpeedGE command in ComPost Dictionary }
IF CWSpindle?
' M44' { High-SpinOnGE }
ELSE
' M43' { High-InverseSpinOnGE }
END
ELSE { SpeedRPM# <= 600 }
IF CWSpindle?
' M04' { Low-SpinOnGE }
ELSE
' M03' { Low-InverseSpinOnGE }
END
END
RETURN

GetInverseSpinOnGE: { Virtual does not recognize InverseSpinOnGE }
IF GreaterThan? SpeedRPM# Num#('600') { Refer to SpeedGE command in ComPost Dictionary }
IF CWSpindle?
' M43' { High-InverseSpinOnGE }
ELSE
' M44' { High-SpinOnGE }
END
ELSE { SpeedRPM# <= 600 }
IF CWSpindle?
' M03' { Low-InverseSpinOnGE }
ELSE
' M04' { Low-SpinOnGE }
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC LOfstOff '00' EOL
SeqC OpToolID LatheOffset EOL
END
IF LAST ProgStop?
SeqC SpeedGE GetSpinOnGE EOL
SeqC CoolOn EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqC SpeedGE GetSpinOnGE EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
' G02'
ELSE
' G03'
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
SeqC CRCOnC EOL
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
SeqC CRCOffC EOL
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC ' G04 X20000' EOL
SeqC SpeedGE GetInverseSpinOnGE EOL
ELSE
IF Dwell?
SeqC ' G04 X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
RapidC
IF NOT FirstFeat? AND LAST ArcFeat? OR LAST ThreadFeat?
SeqC EOL
' G01'
END
SeqC MoveXC MoveZC
IF NOT FirstFeat? AND LAST ThreadFeat?
RapidF
END
RapidFC EOL
ELSE
IF LineFeat?
CkCRC
FeedC
IF NOT FirstFeat? AND LAST ArcFeat?
SeqC EOL
' G01'
END
SeqC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
SeqC FeedC EOL
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC ' G33' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
SeqC CRCOffC EOL
IF Flag?('1') { End of Prog }
IF Threading?
SetStatusRapid
IF NOT AutoFinish?
' G01'
END
ELSE
SeqC RapidC EOL
END
ELSE { NewTool }
IF LAST Threading?
SetStatusRapid
IF LAST NOT AutoFinish?
' G01'
END
ELSE
SeqC RapidC EOL
END
END
IF NOT EmptyLine?
SetFlagF('2') { CheckRapidF }
END
RETURN

CheckRapidF:
IF NOT EmptyLine?
IF NOT Flag?('2') { CheckRapidF }
IF Flag?('1') { End of Prog }
IF Threading? AND NOT AutoFinish?
RapidF
END
ELSE { NewTool }
IF LAST Threading? AND LAST NOT AutoFinish?
RapidF
END
END
END
RapidFC
SetFlag('2') { CheckRapidF }
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
XsAreRadii
NoIJKSigns
SetMaxRPM('3000')
SetMaxFeed('500')
SetFlagF('1') { end of Prog }
SetFlagF('2') { CheckRapidF }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq Rapid ' F80000 M91' EOL
SeqC IncValue EOL
SeqC ' G01 X-30000 Z-30000' EOL
SeqC ProgStop EOL
':' EOL
SetAbs
CSSOff
Seq Preset Home SpeedGE GetSpinOnGE EOL
':' EOL
SeqC AbsValue OpToolID LatheOffset EOL
SeqC Rapid CoolOn EOL
SeqC ' G01' Home ' F80000' EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC XCPC CheckRapidF EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidF EOL
END
END
SeqC ZCPC CheckRapidF EOL
DoEndOpPS
SeqC OfstOff
IF LAST ProgStop?
' M00'
ELSE
ProgStop
END
EOL
SeqC ' G01' LAST Home EOL

{Start new Operation}

DoOpComments
DoPostScript
':' EOL
Seq Preset Home SpeedGE GetSpinOnGE EOL
':' EOL
SeqC AbsValue OpToolID LatheOffset EOL
SeqC Rapid CoolOn EOL
SeqC ' G01' Home ' F80000' EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC CheckRapidF EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC CheckRapidF EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidF EOL
END
SeqC LAST OpExitZCPC CheckRapidF EOL
SeqC LAST OpExitXCPC CheckRapidF EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidF EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC CheckRapidF EOL
END
SeqC LAST OpExitZCPC CheckRapidF EOL
SeqC XOpCDC CheckRapidF EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC CheckRapidF EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC CheckRapidF EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC CheckRapidF EOL
END
SeqC LAST OpExitZCPC CheckRapidF EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
IF Threading?
StockOn
SetPass1
ToolPath
IF AutoFinish?
SeqC ' X' ADD# FinishXRadius# Taper# EOL
SeqC ' G33'
IF Taper?
' X' FinishXRadius#
END
FinZ ThrdLead EOL
SeqC ' G01' XCSP RapidF EOL
SeqC ZCSP EOL
END
ELSE
IF Drilling?
IF Tap?
SeqC LCycle ZDepth FeedRate EOL
SeqC SpinOff EOL
SeqC ' G04 X20000' EOL
SeqC SpeedGE GetInverseSpinOnGE EOL
SeqC ZSP EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC RapidFC EOL
ELSE
SeqC RapidC XOpECDC RapidFC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC RapidFC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqC ' X' ADD# FinishXRadius# Taper# EOL
SeqC LCycle
IF Taper?
' X' FinishXRadius#
END
FinZ ThrdLead EOL
SeqC ' G01' XCSP RapidF EOL
SeqC ZCSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC ' G04 X20000' EOL
SeqC SpeedGE GetSpinOnGE EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
SeqC CRCOffC EOL
SetFlag('1') { end of Prog }
CheckRapid
IF ApproachOD?
SeqC OpExitXCPC CheckRapidF EOL
ELSE
IF ApproachID?
SeqC XOpECDC CheckRapidF EOL
END
END
SeqC OpExitZCPC CheckRapidF EOL
DoEndOpPS
SeqC FirstHome ' F80000' EOL
SeqC OfstOff
IF ProgStop?
' M00'
ELSE
ProgStop
END
EOL
SeqC ' G01' Home EOL
':' EOL
SeqC ' S60 M43' EOL
SeqC ' M08' EOL
SeqC ' M24' EOL
SeqC ' M25' EOL
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END