{Change Comments ***********************************************************}

{10/11/88
Created: Generic GE 1050
For: Varec
Machine: Manarch TC-1 Lathe
Control: GE 1050T
No Canned Cycles supported.
Lathe has 2 Turrets.
Upper Turret: Tools 1 - 8, PosSideLathe, StandardXZArcs, SpinForward = M03, Offsets T0100 - T0800.
Lower Turret: Tools 1 - 8 ( 21 - 28 in ncCam Tool List ), NegSideLathe, ReverseXZArcs,
SpinForward = M04, Offsets T1000 - T8000.
JR}

{11/7/88
Deleted XsAreRadii, Lathe Xs are Diameter.
Deleted NegSideLathe and ReverseXZArcs for Lower Turret.
Both are PosSideLathe, StandardXZArcs and SpinForward = M03
JR}

{5/10/90, Updated: GE 1050T Monarch L074.56 to .69.4 format, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}

{12/12/91
Modified: GE 1050T Monarch L074.70
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
Rapid is not used, RapidF and FeedRate instruct the control.
DWB}

{5/6/93
Copied & modified: GE 1050T Monarch L074.82
For: Braden Eng / Twigg Aerospace Components
Control: GE1050T
Machine: W&S 242 VFR Vertical Turret Lathe
5 station turret, each can hold 2 tools that can work on either + or - X axis.
Modified GetToolNum for this special handling of tool number and axis output.
Modified ToolTypeComment to reflect actual turret and tool
Added 'M17' tool change command.
Changed G01, G02, G03 to G21, G22, G23
Changed to output decimal point format without leading or trailing zeros.
Added XsAreRadii to initializations to output radius values for X.
Modified GearRange to output M50(low) & M51(High) with change over at 80 RPM.
Updated to .82ż format.
Jim Radcliffe}

{10/27/93
Modified: GE 1050T W&S 242 VFR L284.82
For: Braden Eng / Twigg Aerospace Components
Deleted XsAreRadii to get Diameter output.
Jim Radcliffe}

{11/18/93
Modified: GE 1050T W&S 242 VFR L284.82.1
For: Braden Eng / Twigg Aerospace Components
Added XsAreRadii to get Radius output, the only diameter value is the Home line.
Modified the Home lines to get a diameter value.
Changed 'G4X1.' to 'G04X2.'
Added leading zeros to G, M & N codes.
Deleted SpinOff from end of program.
Deleted G95 from very beginning of operation, read further for implementation.
Deleted M58, it is not used on this machine.
Modified GearRange to change over at 150 RPM.
Output M80 to set Rapid, M81 to set feed. Modal.
Output G94 (IPM) for Rapid, G95 (IPR) for Feed. Modal.
Jim Radcliffe}

{8/13/95
Initial: GE 1050T W&S 242 VFR L284.82.2
Created: GE 1050T W&S 242 VFR L284.85
ForUser: CNCCS / Twigg
Control: GE 1050T
Machine: Gray W&S
Develop: ComPost 4.21.32, Virtual v.2.20
Comment: Modified Processor per marked up readout from Dalton Harwell.
Changed default format N, sequence numbers, to show 4 digits.
Changed default format S, spindle speed, to show 4 digits.
Deleted T code from Home lines.
Deleted GetLastToolNum sub as it is now no longer used.
Updated to .85 format per Fanuc 10T MS [-] L001.85.01
Jim Radcliffe}

{4/29/96
Initial: GE 1050T W&S 242 VFR L284.85
Created: GE 2000 Bullard VTL L000.85
ForUser: CNCCS / Twigg
Control: GE 2000
Machine: Bullard VTL
Develop: ComPost 4.21.34, Catalyst68K v3.04C
Comment: New Post processor per marked up readout from Terry Shoate
Deleted Dwell at tool index.
Changed format of tool call from Tnxx to Tnnxx:
Added prog formatter #6
Called in GetToolNum sub for Tool# & SUB#
Then, reset to format #3 for comments.
Added missing CheckM80 in SameTool.
Added GetRapidFC CheckM80 to ApproachSP to handle SameTool situation.
Had to move the GetRapidFC sub!
Added '(END, PROG)' to end of program.
Added 'MSG,' to beginning of comments.
Added SetFlagF('1') & SetFlagF('2') at beginning of tool to force G94 & M80 output.
Jim Radcliffe}

{8/27/97,
Initial: GE 2000 Bullard VTL L502.85
Created: GE 2000 White Gray [GT] L633.85
For: General Tool
Added support for CRC,
deleted CheckM80 and CheckM81,
added TTOff to Program inits,
MPK
}

{10/27/97
Updated & Modified: GE 2000 White Gray [GT] L633.85
Created: GE2000 WhiteGray [GT] L633.85.1
For: General Tool
Versions: Catalyst v4.21.05(mac)/ComPost2 MSL 68K
Changes made per David Bishop of General Tool, fax and phone call.
Changed FORMAT#5 from '##.#;0' to '0' at Prog Numeric Format Definitions.
Modified Home related blocks at FirstOperation, NewTool and end of Prog.
Deleted HomeZ# from FORMAT#2 at Prog Numeric Format Definitions.
Deleted NewHomeZ# from FORMAT#2 at Prog Numeric Format Definitions.
Deleted FirstHomeZ# from FORMAT#2 at Prog Numeric Format Definitions.
Added TrackX# to FORMAT#2 at Prog Numeric Format Definitions.
Added TrackZ# to FORMAT#2 at Prog Numeric Format Definitions.
Post now outputs 'X' TrackX# Num#(27) 'Z' TrackZ# Num#(0) for constant ToolChng Position.
Replaced 'X' MUL# Num#('2') HomeX# 'Z' HomeZ# at FirstOperation and NewTool.
Replaced 'X' MUL# Num#('2') NewHomeX# 'Z' NewHomeZ# at NewTool.
Replaced 'X' MUL# Num#('2') FirstHomeX# 'Z' FirstHomeZ# at end of Prog.
Added ToolNum LatheOffset at AppMove sub.
Changed ToolNum LatheOffset to OpToolID '00' at FirstOperation and NewTool.
Deleted literal 'M17', ToolChng code at FirstOperation and NewTool.
Changed RapidF from 200 to 0 in Rapid Feed Rate: (XXXX^X) Edit Field in Compost2 Movement Dialog.
Updated for Catalyst v3.35C per Fanuc 10T MS [-] L001.85.02d Format.
Updated CheckOffset sub.
ConstantSurfaceFeed handled at CommonPoint.
Updated CkCRC sub.
Added SetMaxFeed(12700) condition for Metric Files at setup and initializations.
Corrected output of G21 only block at end of Manual Thread Cycle.
Added IF LAST ThreadFeat? at ToolPath RapidFeat?
Forces Rapid.
Deleted forced Rapid at ToolPath ThreadFeat.
Added OR LAST Threading? at CheckRapid.
Added OR Threading? at end of Prog.
Correction made on 6/4/97 was causing Virtual files to not output G00 after exiting ToolPath.
Gibbs System files now output Rapid a second time.
Fine Tuned prog flow.
Changed FORMAT#3 from '########;0' to '#######0' at Prog Numeric Format Definitions.
Deleted ADD# from FORMAT#2 at Prog Numeric Format Definitions.
Deleted SUB# from FORMAT#3 at Prog Numeric Format Definitions.
Added Recall# from FORMAT#6 at Prog Numeric Format Definitions.
Moved CoolOn block from each Approach Type to end of Approach sub at Approach sub.
Added CheckRapid sub.
Moved CRCOffC block, CheckG94 call and output of FeedC from NewTool and SameTool.
Changed Feed to FeedC for NewHome at NewTool.
Changed Feed to FeedC two places at AutoFinish Threading.
Changed Feed to FeedC for FirstHome at end of Prog.
Moved SetFlagF(1) from FirstOperation and NewTool to start of Approach sub.
Deleted SetFlagF(2) at setup and initializations, FirstOp and NewTool.
Was used for M80/M81 Rapid/Feed mode in other post processors.
Threading AutoFinish was not outputting XatFinZ FinZ.
Added X##.####;0 to Finish X at Finish Z in Compost2 Threading Dialog.
Added Z##.####;0 to Finish Z in Compost2 Threading Dialog.
Post was output G21G94 blocks.
Modified to output one G-Code per block.
G94 to be output first.
Deleted G21 from Rapid Line Edit Field in Compost2 Movement Dialog.
For non-outputting Rapid Command.
Added non-outputting Rapid Command following G33 block at ToolPath ThreadFeat.
Forces G21 Feed where needed.
Some situations occured where G21 was not being output to cancel G33.
Simplified Tool# related output.
Added Var(1) for Tool# and Formula for Tool#. at setup and initializations.
Rewrote GetToolNum sub.
Called at FirstOperation and NewTool.
Tests value of Tool#.
For Lower Turret:
Tools 1 - 5 stores Tool# and sets NegSideLathe and ReverseXZArcs.
Tools 6 - 10 stores SUB# Tool# Num#(5) and sets PosSideLathe, and StandardXZArcs.
For Upper Turret:
Tools 11 - 15 stores SUB# Tool# Num#(10) and sets NegSideLathe and ReverseXZArcs.
Tools 16 - 20 stores SUB# Tool# Num#(15) and sets PosSideLathe, and StandardXZArcs.
Added ToolPos# sub.
Is called from, and contains contents previously output at, DoOpComments sub.
Added ToolNum sub.
Replaces original GetToolNum sub called from CheckOffset sub, FirstOperation and NewTool.
Added support of PreTool.
Added NextTool# to FORMAT#6 at Prog Numeric Format Definitions.
Added PreToolNum sub.
Outputs value of NextTool# and Formula for NextTool#.
Same test as that performed at GetToolNum sub.
Added call to PreToolNum sub ToolNum LatheOffset at FirstOperation and NewTool.
DWB}

{06Jan98
Original: GE2000 WhiteGray [GT] L660.85.1
Created: GE2000 WhiteGray [GT] L660.85.2
For: General Tool Co
Changes made per: David Bishop
Using SetTTOff to output center of tool radius values.
Charles Winston}

{14Jan98
Original: GE2000 WhiteGray [GT] L660.85.1
Created: GE2000 WhiteGray [GT] L660.85.2
For: General Tool Co
Changes made per: David Bishop
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Deleted NoIJKSigns at Start of executable Prog
Deleted Literal '$' Program# and replaced with '(ID,PROG,' Program# ')' in FirstOperation
Deleted EOR at ~End of Prog
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '##.####;0'
#3 = '#######0'
#4 = '###0'
#5 = '0'
#6 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CycleStartX#,2)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(TrackX#,2)
FORMAT(TrackZ#,2)
FORMAT(Dwell#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(CalcEPRPM#,4)
FORMAT(RapidF#,5)
FORMAT(Recall#,6)
FORMAT(SUB#,6)
FORMAT(NextTool#,6)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

GetToolNum:
IF LTEqual? Tool# Num#('10')
IF LTEqual? Tool# Num#('5')
Save# Num#('1') Tool#
PosSideLathe
StandardXZArcs
ELSE
Save# Num#('1') SUB# Tool# Num#('5')
NegSideLathe
ReverseXZArcs
END
ELSE
IF LTEqual? Tool# Num#('15')
Save# Num#('1') SUB# Tool# Num#('10')
PosSideLathe
StandardXZArcs
ELSE
Save# Num#('1') SUB# Tool# Num#('15')
NegSideLathe
ReverseXZArcs
END
END
RETURN

ToolPos#:
FORMAT(Recall#,3)
Recall# Num#('1') ' POSITION '
IF LTEqual? Tool# Num#('10')
'1'
ELSE
'2'
END
FORMAT(Recall#,6)
RETURN

ToolNum:
'T' Recall# Num#('1')
RETURN

PreToolNum:
'D'
IF LTEqual? NextTool# Num#('5')
NextTool#
ELSE
IF LTEqual? NextTool# Num#('10')
SUB# NextTool# Num#('5')
ELSE
IF LTEqual? NextTool# Num#('15')
SUB# NextTool# Num#('10')
ELSE
SUB# NextTool# Num#('15')
END
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'(MSG, TURRET ' ToolPos# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

CheckG94: { Called before Rapid blocks }
IF Flag?('1')
{ We are already in G94 Rapid Mode }
ELSE
SetFlag('1')
SeqC 'G94' EOL { We are in G95 Feed Mode, set to IPM for Rapid moves }
END
RETURN

CheckG95: { Called before Feed blocks }
IF Flag?('1')
SetFlagF('1')
SeqC 'G95' EOL { We are in G94 Rapid Mode, set to IPR for Feed moves }
ELSE
{ We are already in G95 Feed Mode }
END
RETURN

GetRapidFC:
IF NOT EmptyLine?
RapidFC
END
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC GetRapidFC EOL
SeqC StockOff ZOpCPC GetRapidFC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
CheckG95
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC GetRapidFC EOL
SeqC StockOff XOpCDC GetRapidFC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
CheckG95
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP ToolNum LatheOffset RapidF
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
SetFlagF('1') { force G94 output at beginning of tool }
CheckG94
Feed
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
SeqC CoolOn EOL
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
IF NewGear?
SeqC ToolNum '00' SpinOff EOL
SeqC ToolNum LatheOffset GearRange EOL
ELSE
SeqC ToolNum '00' EOL
SeqC ToolNum LatheOffset EOL
END
ELSE
IF NewGear?
SeqC SpinOff EOL
SeqC GearRange EOL
END
END
IF ConstantSurfaceFeed?
{ skip untill we are at the start position }
ELSE
CSSOff
IF LAST ConstantSurfaceFeed?
'G97' Speed
ELSE
IF LAST ProgStop? OR NewGear?
'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G97' Speed
END
END
END
END
IF LAST ProgStop?
SeqC {SpeedC} SpinOn EOL
SeqC CoolOn EOL
ELSE
IF NewGear?
SeqC {SpeedC} SpinOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC ArcIJC
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G4X2.' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G04X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
CheckG94
SeqC FeedC MoveXC MoveZC GetRapidFC EOL
ELSE
IF LineFeat?
CheckG95
SeqC CkCRC EOL
SeqC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
CheckG95
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
CheckG95
SeqC 'G33' MoveXC MoveZC ThrdLead EOL
Rapid { No Output }
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
SeqC CRCOffC EOL
CheckG94
FeedC
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
XsAreRadii
SetTTOff
StandardXZArcs
SetMaxRPM('486')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { ToolPos# }
SetFlagF('1') { used for G94/G95, Flag? true is we are in G94 Rapid }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
'(ID,PROG,' Program# ')' EOL
IF UseComments?
IF ProgramNameComment?
'(MSG, PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
GetToolNum
Seq 'G70' EOL { Inch }
SeqC AbsOrInc EOL
DoOpComments
DoPostScript
Plane
SeqC ToolNum '00'
IF NOT LastTool?
PreToolNum
END
EOL
SeqC GearRange EOL
SeqC Preset 'X' TrackX# Num#('27') 'Z' TrackZ# Num#('0') MaxRPM EOL
SeqC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC GetRapidFC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC GetRapidFC EOL
END
END
SeqC LAST OpExitZCPC GetRapidFC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' CalcRPM2 EOL
END
SeqC FeedC 'X' TrackX# Num#('27') 'Z' TrackZ# Num#('0') GetRapidFC EOL
IF NewGear?
SeqC SpinOff EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Seq 'G70' EOL { Inch }
SeqC AbsOrInc EOL
GetToolNum
DoOpComments
DoPostScript
SeqC ToolNum '00' PreToolNum EOL
SeqC GearRange EOL
SeqC Preset 'X' TrackX# Num#('27') 'Z' TrackZ# Num#('0') MaxRPM EOL
SeqC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC GetRapidFC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC GetRapidFC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC GetRapidFC EOL
END
SeqC LAST OpExitZCPC GetRapidFC EOL
SeqC LAST OpExitXCPC GetRapidFC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC GetRapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC GetRapidFC EOL
END
SeqC LAST OpExitZCPC GetRapidFC EOL
SeqC XOpCDC GetRapidFC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC GetRapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC GetRapidFC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC GetRapidFC EOL
END
SeqC LAST OpExitZCPC GetRapidFC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool?
CSSOn
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
IF LAST ProgStop? OR NewGear?
SeqC 'G96R' CycleStartX# Speed EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqC 'G96R' CycleStartX# Speed EOL
END
END
ELSE
SeqC Preset MaxRPM EOL
SeqC 'G96R' CycleStartX# Speed EOL
END
ELSE
SeqC 'G96R' CycleStartX# Speed EOL
END
END
IF CannedCycle?
{ No Canned Cycle Support }
END
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
CheckG94
IF ApproachFace?
SeqC FeedC ZOpECPC GetRapidFC EOL
ELSE
SeqC FeedC XOpECDC GetRapidFC EOL
END
ApproachSP
CheckG95
SeqC StockOff StrtPosC FeedRateC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
CheckG94
SeqC FeedC XSPC ZSPC GetRapidFC EOL
CheckG95
SeqC FeedC StockOff StrtPosC FeedRateC EOL
ToolPath
SetPass1
ELSE
IF Threading?
CheckG94
SeqC FeedC 'X' MUL# Num#('1') ADD# FinishXRadius# Taper# GetRapidFC EOL
CheckG95
SeqC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
CheckG94
SeqC Feed XSP GetRapidFC EOL
SeqC FeedC ZSP GetRapidFC EOL
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G04X2.' EOL
SeqC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
SeqC CRCOffC EOL
CheckG94
FeedC
IF ApproachOD?
SeqC OpExitXCPC GetRapidFC EOL
ELSE
IF ApproachID?
SeqC XOpECDC GetRapidFC EOL
END
END
SeqC OpExitZCPC GetRapidFC EOL
DoEndOpPS
SeqC CoolOff EOL
IF ConstantSurfaceFeed?
SeqC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqC FeedC 'X' TrackX# Num#('27') 'Z' TrackZ# Num#('0') EOL
IF ProgStop?
SeqC 'M00' EOL
END
SeqC EOP EOL
'(END, PROG)' EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END