{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=T
MILLTURN_POLAR-SEG=F
MILLTURN_Y-AXIS=F
METRIC=T
}

{5/24/93
created initial NoSubs Processor to .81 format
FIFO stuff not supported
variables: 1 = tools 1st op; 2 = tools last op; 3 = ncCAMs last op
Jim Radcliffe}

{7/29/93, v.81.1, added FIFO handling, JR}
{8/3/93, v.81.2, SameTool WFO, RapidF#, additional FIFO handling, JR}

{9/8/94
Copied & modified: Fanuc 6M NoSubs M001.81.2
For: Precision Performance Products
Control: GE 1050 MCL
Machine: Monarch VMC 75
Leading zeros. Speed codes. NegateZ. Manual PeckChipBreak & RetractToCP1 cycles.
M06 couses full retract.
Jim Radcliffe}

{2/9/96, Updated .81 number to .84, no changes necessary, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}

{5/24/96
Initial: GE 1050 MCL Monarch M687.87
Created: GE 1050MC Monarch VMC Mxxx.89
ForUser: DEN-TAL-EZ, Inc.
Control: GE 1050MC
Machine: Monarch VMC-75
Develop: ComPost 4.21.37, Catalyst68K v3.04.04C
Comment: New Processor per manual.
SetMaxRPM('3500'), SetMaxFeed('400')
Changed formats to use decimal point.
Dwell and Peck labels use K.
Added G75 for full circle programming mode.
Unconditional axis moves in FormatArc.
Added helical interpolation.
Modified cutter radius compensation ( this is a weird comp ).
One G code per line.
Updated per Fanuc 6M NoSubs M877.89
Jim Radcliffe}

{1/2/98,
Created Metric post.
CDH}

{27Jan99
Original: GE 1050MC Mon [DTE] M204.89m
Created: GE 1050MC Mon [FD] NMT90.89m
For: Fomaco, Denmark
Changes made per: Boris Nielsen / Frits Balking of Gimbel A/S
Develop: Catalyst 5.03/ComPost2 1.7b13
Added Post Header Comment at the top of Prog.
Changed Formats to output 3 decimal Places with trailing zeros in Prog and MachSpec.
Changed Addresses to output a leading space in Prog and MachSpec.
Added Format#9 and formatted FeedEntry#
Changed ProgID1 and replaced with '$' Program# at Start of post processing.
Added doG75 Sub, called in FirstOperation, NewTool and SameTool.
Outputs 'G75' if the ToolPath contains an Arc greater than 90 Degrees.
Added 'M06' in FirstOperation
Deleted Table(1,SpeedRPM#,1), Replaced with Speed.
Deleted Table1 in MachSpec.
Moved SpinOn down onto the Spindle on line in FirstOperation, Newtool and SameTool.
Added PreTooling in FirstOperation and NewTool per Customers requirements.
Added 'Z200.000 M05' in FinishLastOp.
Added SeqC before EOP in FinishLastOp.
Charles Winston}

{22Feb99
Original: GE 1050MC Mon [FD] NMT90.89m
Created: GE 1050MC Mon [FD] NMT90.89.1m
For: Fomaco, Denmark
Changes made per: Boris Nielsen / Frits Balking of Gimbel A/S
Develop: Catalyst 5.03/ComPost2 1.7b15
Deleted ' G87' 'R' ClearancePlane1# from DoOfstOn Sub.
Added Boolean in FirstOp and NewTool for Drill Cycle move to ZCP2. ( NOT PeckChipBreaker )
Added Move to ZCP1 in NewTool at Finish Off Last Operation.
Charles Winston}

{03Mar99
Original: GE 1050MC Mon [FD] NMT90.89.1m
Created: GE 1050MC Mon [FD] NMT90.89.2m
For: Fomaco, Denmark
Changes made per: Boris Nielsen / Frits Balking of Gimbel A/S
Develop: Catalyst 5.05/ComPost2 1.7b15
Deleted ToolOfst from Drill Cycle Sub.
Added Flag('9') at Start of executable Prog. Used to Suppress G75 output.
Moved DoOfstOn CoolOn to PeckChipBreaker ZCP2C line in ToolPath
Rewrote the logic for ToolOffset and Coolant in FirstOperation, NewTool and SameTool.
Charles Winston}

{16Mar99
Original: GE 1050MC Mon [FD] NMT90.89.2m
Created: GE 1050MC Mon [FD] NMT90.89.3m
For: Fomaco, Denmark
Changes made per: Boris Nielsen / Frits Balking of Gimbel A/S
Develop: Catalyst 5.05/ComPost2 1.7b15
Changed Num#1 to Num#21 in DoPeck Sub. Num#1 is used for Multiple Parts.
Added Booleans to suppress the DrillCycle and DrillOff in toolPath at Drilling when RetractToCP1 is TRUE.
Changed Literal 'M06' to ZCP1 in FirstOperation, NewTool and SameTool. To retract tool before ToolChange.
Initialised Num#1 thru Num#3 at Start of executable Prog.
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.000;0'
#3 = '*###.000;0'
#4 = '####.000;0'
#5 = '#######0'
#6 = '####.000;0'
#7 = '#;'
#8 = '*####.000;0'
#9 = '#####^0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(HelixPitch#,4)
FORMAT(COS#,4)
FORMAT(SIN#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(TrackZ#,6)
FORMAT(RapidF#,7)
FORMAT(ClearancePlane1#,8)
FORMAT(FeedEntry#,9)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF MultipleParts? AND SubComment?
'( PART ' Tag# ' )' EOL
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

ExitType:
IF FIFO?
FeedC
ELSE
RapidC
END
RETURN

ExitFeed:
IF FIFO?
FeedEntC
END
RETURN

ArcCenter:
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
IF ZMove?
MoveX MoveY ArcCenter MoveZ ' K' HelixPitch#
ELSE
MoveX MoveY ArcCenter
END
ELSE
IF XZPlane?
IF YMove?
MoveX MoveZ ArcCenter MoveY ' J' HelixPitch#
ELSE
MoveX MoveZ ArcCenter
END
ELSE
IF XMove?
MoveY MoveZ ArcCenter MoveX ' I' HelixPitch#
ELSE
MoveY MoveZ ArcCenter
END
END
END
RETURN

StdRapid:
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

SignBlock:
IF GreaterThan? SPMoveAngle# Num#('270')
' XY-'
ELSE
IF GreaterThan? SPMoveAngle# Num#('180')
' X-Y-'
ELSE
IF GreaterThan? SPMoveAngle# Num#('90')
' X-Y'
ELSE
' XY'
END
END
END
RETURN

CompBlock:
IF GreaterThan? SPMoveAngle# Num#('270')
' I' SIN# SUB# SPMoveAngle# Num#('270') ' J' COS# SUB# SPMoveAngle# Num#('270')
ELSE
IF GreaterThan? SPMoveAngle# Num#('180')
' I' COS# SUB# SPMoveAngle# Num#('180') ' J' SIN# SUB# SPMoveAngle# Num#('180')
ELSE
IF GreaterThan? SPMoveAngle# Num#('90')
' I' SIN# SUB# SPMoveAngle# Num#('90') ' J' COS# SUB# SPMoveAngle# Num#('90')
ELSE
' I' COS# SPMoveAngle# ' J' SIN# SPMoveAngle#
END
END
END
RETURN

DoCRCOnC:
IF CutterRadiusCompensation?
IF NOT Flag?('2')
SeqC IncValue EOL
SeqC Feed SignBlock EOL
SeqC CRCOn CompBlock CRCOfst EOL
SeqC AbsOrInc EOL
SetFlag('2')
END
END
RETURN

DoCRCOffC:
IF LastFeat?
IF Flag?('2')
SeqC CRCOff EOL
SetFlagF('2')
END
END
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
DoCRCOnC
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
DoCRCOffC
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
IF FeedConnect?
SeqC FeedC StrtPosC EOL
ELSE
SeqC RapidC StrtPosC EOL
END
END
END
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqC ExitType PRIME ZCP2 ExitFeed EOL
END
NextRep
ELSE
EntryMove
ToolPath2
END
SeqC AbsOrInc EOL
SeqC ExitType ZCP2 ExitFeed EOL
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

DoPeck:
IF GreaterThan? SUB# Recall# Num#('21') Peck# SPZ# {IF OldZ - Peck# > Depth}
Save# Num#('21') SUB# Recall# Num#('21') Peck# {Save#1 = OldZ - Peck# = NewZ}
SeqC Feed ' Z' TrackZ# Recall# Num#('21') FeedEntC EOL {move to NewZ}
IF PeckFullRetract?
SeqC Rapid ZCP2 EOL {move to CP2}
END
SeqC RapidC ' Z' TrackZ# ADD# Recall# Num#('21') Retract# EOL {move to RetractZ}
END
RETURN

DrillCycle:
GetCycle
IF FIFO? AND Dwell?
' G89'
ELSE
Cycle
END
RLevel ZDepth Dwell Peck ' F' FeedEntry#
RETURN

doG75:
EACHFeat
IF ArcFeat?
EACHQuadrant
NEXTQuadrant
IF GreaterThan? ArcAngle# Num#('90.00001')
IF NOT Flag?('9')
SeqC ' G75' EOL
SetFlag('9')
END
END
END
NEXTFeat
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqC
IF FIFO?
Rapid
END
MoveSXYC EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
CutAutoCycle
ELSE { Drilling }
IF PeckChipBreaker?
SeqC RapidC MoveSXYC EOL
SeqC ZCP2C EOL
Save# Num#('21') ClearancePlane2#
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
SeqC Feed ' Z' TrackZ# SPZ# FeedEntC EOL {move to Depth}
IF RetractToCP1?
SeqC Rapid ZCP1 EOL {move to CP1}
ELSE
SeqC Rapid ZCP2 EOL {move to CP2}
END
ELSE
IF NOT FirstFeat?
IF RetractToCP1?
IF NotEqual? ClearancePlane1# ClearancePlane2#
SeqC DrillOff ZCP1 EOL
SeqC MoveSXYC EOL
SeqC DrillCycle EOL
ELSE
SeqC MoveSXYC EOL
END
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
END
END
END
ELSE
DoCRCOnC
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
DoCRCOffC
END
NEXTFeat
RETURN

WFOStuff:
IF MultipleParts? AND WorkFixtureOffsets?
SetWFO
ELSE
IF NewWFO?
' G' NewWFO#
ELSE
IF NOT SameTool?
IF NeedWFO1?
' G' NewWFO#
END
END
END
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
Plane { no output }
RETURN

DoOfstOn:
SetAbs
ZCP1 ToolOfst
SetAbsOrInc
RETURN

DoOp:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
SeqC Rapid OfstOff ZCP1 EOL
END
DoOpComments
ELSE
Plane { no output }
Seq AbsOrInc EOL
SeqC OpToolID ToolChng EOL
SeqC Speed SpinOn
IF NOT LastTool?
PreTool
END
EOL
DoOpComments
DoPostScript
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC Rapid StrtPos WFOStuff EOL
ELSE
SeqC Rapid StrtPos WFOStuff EOL
IF Drilling?
SeqC ZCP2 ToolOfst
IF NOT PeckChipBreaker?
EOL
SeqC DrillCycle CoolOn EOL
ELSE
CoolOn EOL
END
ELSE
SeqC DoOfstOn CoolOn EOL
END
END
doG75
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
{only need to set up for tool change on 1st part}
ELSE
SeqC CoolOff EOL
SeqC ZCP1 EOL
Seq OpToolID ToolChng EOL
DoEndOpPS
DoOpComments
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END
END

{Start new Operation}

IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
SeqC Rapid OfstOff ZCP1 EOL
END
DoOpComments
ELSE
Plane { no output }
SeqC AbsOrInc Speed SpinOn PreTool EOL
DoPostScript
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC Rapid StrtPos WFOStuff EOL
ELSE
SeqC Rapid StrtPos WFOStuff EOL
IF Drilling?
SeqC ZCP2 ToolOfst
IF NOT PeckChipBreaker?
EOL
SeqC DrillCycle CoolOn EOL
ELSE
CoolOn EOL
END
ELSE
SeqC DoOfstOn CoolOn EOL
END
END
doG75
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC Rapid OfstOff ZCP1 EOL
SeqC ' M00' EOL

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc SpinOn EOL
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqC Speed EOL
END
SeqC Rapid StrtPos WFOStuff EOL
IF Drilling?
SeqC ZCP2 ToolOfst
IF NOT PeckChipBreaker?
EOL
SeqC DrillCycle CoolOn EOL
ELSE
CoolOn EOL
END
ELSE
SeqC DoOfstOn CoolOn EOL
END
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC Rapid DrillOff OfstOff ZCP1 EOL

{Start new Operation}

GetStartOfSameTool
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqC Speed EOL
END
SeqC Rapid StrtPos WFOStuff EOL
IF Drilling?
SeqC ZCP2 ToolOfst
IF NOT PeckChipBreaker?
EOL
SeqC DrillCycle CoolOn EOL
ELSE
CoolOn EOL
END
ELSE
SeqC DoOfstOn CoolOn EOL
END
ELSE

{Start new Operation}

GetStartOfSameTool
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqC Speed EOL
END
SeqC Rapid StrtPos WFOStuff EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
doG75
END
END
END

{ Common Point for All Operations }

ResetCRCNum {call here to reset for each new operation only, call in tool path to reset for each repeat in an operation}
RapidF# {forces the output of a conditional feedrate for each operation}

IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqC
IF NOT FeedConnect?
ExitType PRIME ZCP3C
END
ExitFeed EOL
NEXTRep
END
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
SeqC ExitType ZCP3C ExitFeed EOL
END
ELSE
IF Drilling?
IF Repeats?
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqC StrtPos EOL
IF NOT PeckChipBreaker?
SeqC DrillCycle EOL
END
END
END
IF PeckChipBreaker?
ToolPath
ELSE
TrackZNO# SPZ# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff ZCP3 EOL
END
IF Repeats?
NEXTRep
END
SeqC RapidC ZCP3C EOL
END
END
RETURN

FinishLastOp:
SeqC CoolOff EOL
SeqC Rapid OfstOff ' Z200.000 M05' EOL
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC Rapid FirstHome EOL
END
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart? {no tool change after doing last part}
IF ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END
ELSE
SeqC EOP EOL
END
RETURN

DoToolsOps:
EachOp
IF GTEqual? Operation# Recall# Num#('1') AND LTEqual? Operation# Recall# Num#('2')
{Tools1stOp ² op ² ToolsLastOp}
DoOp
END
NextOp
RETURN

NextTools1stOp:
SetNextToolOp Operation#
RETURN

GetToolsOps:
EachOp
IF Equal? Operation# Recall# Num#('1') {if op = Tools1stOp}
IF GreaterThan? NextTools1stOp Recall# Num#('1') {if NextTools1stOp is greater Tools1stOp}
Save# Num#('2') SUB# NextTools1stOp Num#('1') {ToolsLastOp becomes NextTools1stOp less 1}
ELSE {else}
Save# Num#('2') Recall# Num#('3') {ToolsLastOp becomes ncCAMsLastOp}
END
END
NextOp
RETURN

DoTool:
IF NOT Flag?('1')
GetToolsOps
IF WorkFixtureOffsets?
NewWFO
EachWFO
TagInc
DoToolsOps
IncWFO
NextWFO
ELSE
EachPart
TagInc
DoToolsOps
NextPart
END
IF LessThan? Recall# Num#('2') Recall# Num#('3') {if ToolsLastOp < ncCAMsLastOp}
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') {Tools1stOp becomes NextTools1stOp}
ELSE {else}
SetFlag('1') {set DoneFlag}
END
TagInit
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
ReverseXZArcs
ReverseYZArcs
InitWFONum
SetFlood
SetMaxRPM('3500')
SetMaxFeed('400')
SetFlagF('1') {done flag}
SetFlagF('2') { CRCOn flag}
SetFlagF('9') { G75 Flag }
Save# Num#('1') Num#('0') {tools 1st op}
Save# Num#('2') Num#('0') {tools last op}
Save# Num#('3') Num#('0') {ncCAMs last op}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(1), NWFO(1) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
'$' Program# EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MILLIMETERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
END
NextOp
IF MultipleParts?
IF AllToolsOnePart?
IF WorkFixtureOffsets?
NewWFO
EachWFO
TagInc
EachOp
DoOp
NextOp
FinishLastOp
IncWFO
NextWFO
ELSE
EachPart
TagInc
EachOp
DoOp
NextOp
FinishLastOp
NextPart
END
ELSE
IF OneToolAllParts?
EachOp
IF FirstOperation?
Save# Num#('1') Operation# {ncCAMs1stOp becomes Tools1stOp}
END
IF LastOp?
Save# Num#('3') Operation# {save ncCAMsLastOp}
END
NextOp
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
FinishLastOp
END
END
ELSE
EachOp
DoOp
NextOp
FinishLastOp
END
EOR EOL
CloseSub
Post2
IF UseComments?
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close