{5/24/93
created initial NoSubs Processor to .81 format
FIFO stuff not supported
variables: 1 = tools 1st op; 2 = tools last op; 3 = ncCAMs last op
Jim Radcliffe}

{7/29/93, v.81.1, added FIFO handling, JR}
{8/3/93, v.81.2, SameTool WFO, RapidF#, additional FIFO handling, JR}
{9/12/95, v.81.3, FIFO? queries changed to ExitType & ExitFeed calls, WFO MultipleParts, JR}
{5/8/96, v.89, Return to the StrtPos before next iteration of CutAutoCycle Repeats ZshiftOnly, JR}
{6/4/96, v.89.1, minor corrections SeqC, CRCOff & SameTool, JR}

{7/1/97
Initial: Fanuc 6M NoSubs M877.89.1
Created: Cortini Z-80A 2437 Mxxx.89.1m
ForUser: Olso High School ( Computer Aided Integration )
Control: Cortini Z-80A
Machine: Cortini CNC 2437
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.35 PPC
Comment: New processor per fax from Roman Panov dated 25/6-1997
Changed EOR and ProgID1 lines at beginning of program to M24.
WFOs output by Multiple Part and NewWFO request only.
Plane command has no output.
Added TCZ with Z10. as default to First Op StrtPos line and changed OfstOff to output it.
Changed OfstOn to ZCP1.
Added feed rate and speed to every line of output.
Jim Radcliffe}

{12Jan98
Original: Cortini Z-80A 2437 MX38.89.1m
Created: Cortini Z-80A 2437 MX38.89.2m
For: Olso High School ( Computer Aided Integration )
Changes made per: Kai Eriksen
NOTE:
Customers control cannot do 360 deg arcs using G02/G03. They require G12/G13 formatted Arc commands.
These use the start point and a calculated endpoint for the arc based on an arc of 359.9 degrees because
the control cannot have the Arc Starting co-ordinate and the same Arc End co-ordinate (they must be different).
The end point is calculated 0.1 degrees CW or CCW from the start point. The Circular functions, SIN and COS
provide the coordinates of the endpoint. SetUpArcValues, takes account of the sign of the function depending
on which Quadrant the arc starts and whether it is CW or CCW. This is supported by the following functions:
StartPointANGLE, EndPointANGLE, StoreX_Shift, X_Shift, StoreY_Shift, Y_Shift , SetUpArcValues
EndPointX, EndPointY
Modified FormatArc to support G12/G13 Arcs
Added Formattig for:
ArcAngle, SPMoveAngle, EPMoveAngle, SPX#, EPX#, SPZ#, EPZ#,
ADD#, MUL#, SIN#, COS#, ABS#, SPY#
Changed ArcR to Abs# ArcR#
Moved 'M24' literal to DoOp FirstOperation, and added OpToolID
Deleted ToolChng from DoOp FirstOperation
Moved CoolOn from after the StrtPos line to a seperate line after 'M24' in DoOp FirstOperation
Charles Winston}

{19Feb98
Original: Cortini Z-80A 2437 MX38.89.2m
Created: Cortini Z-80A 2437 MX38.89.3m
For: Olso High School ( Computer Aided Integration )
Changes made per: Kai Eriksen
NOTE: Customers Machine manual is wrong. This CNC does not suppeort G12/G13 ARCS !
Deleted the subs added on 12Jan98 and Modified FormatArc to support Arcs Stop on Quadrants.
Added DoArcStartPoint Sub
Added SetFlagF('3') at the start of Toolpath and also at the Start of executable Prog
Added Booleans at ArcFeat in Toolpath to suppress an Arcs Startpoint
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '###.##;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '000^'
#8 = '*###.##;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(ZDepth#,4)
FORMAT(TrackZ#,4)
FORMAT(TCZ#,4)
FORMAT(ArcAngle#,4)
FORMAT(SPMoveAngle#,4)
FORMAT(EPMoveAngle#,4)
FORMAT(SPX#,4)
FORMAT(EPX#,4)
FORMAT(SPZ#,4)
FORMAT(EPZ#,4)
FORMAT(ADD#,4)
FORMAT(SUB#,4)
FORMAT(MUL#,4)
FORMAT(SIN#,4)
FORMAT(COS#,4)
FORMAT(ABS#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(Recall#,7)
FORMAT(SPY#,8)

{Special Command Subroutines ***********************************************}

SaveFeedEnt:
Save# Num#('5') FeedEntry#
RETURN

SaveFeed:
Save# Num#('5') FeedContour#
RETURN

SaveArc:
Save# Num#('5') ArcFeed#
RETURN

SaveDecel:
Save# Num#('5') DecelFeed#
RETURN

FeedAndSpeed:
IF NOT EmptyLine?
' F' Recall# Num#('5') Speed
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF MultipleParts? AND SubComment?
'( PART ' Tag# ' )' EOL
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

ExitType:
IF FIFO?
FeedC
ELSE
RapidC
END
RETURN

ExitFeed:
IF FIFO?
SaveFeedEnt
END
RETURN

DoArcStartPoint:
IF Flag?('3')
SeqC CRCOnC FeedC ' X' SPX# ' Y' SPY# SaveFeed CRCOffsetC FeedAndSpeed EOL
SetFlag('3')
ELSE
SetFlag('3')
END
RETURN

FormatArc:
IF ArcCW?
DoArcStartPoint
SeqC CWArc MoveXY ' R' ABS# ArcR# ArcIJ
ELSE
DoArcStartPoint
SeqC CCWArc MoveXY ' R' ABS# ArcR# ArcIJ
END
RETURN

StdRapid:
IF LastFeat?
SeqC CRCOffC RapidC MoveXYZC FeedAndSpeed EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC RapidC MoveXYZC FeedAndSpeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC RapidC MoveXYZC CRCOffsetC FeedAndSpeed EOL
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC SaveFeed FeedAndSpeed EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC SaveFeed FeedAndSpeed EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC SaveFeed CRCOffsetC FeedAndSpeed EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC SaveDecel CRCOffsetC FeedAndSpeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC SaveFeed CRCOffsetC FeedAndSpeed EOL
END
END
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc SaveArc FeedAndSpeed EOL
DecelMove2
END
SeqC FormatArc SaveDecel FeedAndSpeed EOL
ELSE
SeqC FormatArc SaveArc FeedAndSpeed EOL
END
NEXTQuadrant
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC SaveFeedEnt FeedAndSpeed EOL
ELSE
SeqC RapidC ZInC FeedAndSpeed EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue FeedAndSpeed EOL
IF Repeats? AND ZshiftOnly?
EachRep
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
IF FeedConnect?
SeqC FeedC StrtPosC FeedAndSpeed EOL
ELSE
SeqC RapidC StrtPosC FeedAndSpeed EOL
END
END
END
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqC ExitType PRIME ZCP2 ExitFeed FeedAndSpeed EOL
END
NextRep
ELSE
EntryMove
ToolPath2
END
SeqC AbsOrInc ExitType ZCP2 ExitFeed FeedAndSpeed EOL
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
SetFlagF('3') { Reset Flag to FALSE. Used when the First item in Toolpath is an ARC }
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqC
IF FIFO?
Rapid
END
MoveSXYC FeedAndSpeed EOL
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
CutAutoCycle
ELSE
SeqC MoveSXYZC FeedAndSpeed EOL {.80.01}
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
IF FirstFeat?
SetFlag('3') { First item in Toolpath is an ARC = TRUE, do not Suppress the Arc Start Point }
ELSE
IF LAST LineFeat?
SetFlagF('3') { Suppress the Arc Start Point }
END
END
StdArc
END
END
END
END
NEXTFeat
RETURN

DoPeck:
IF NOT Flag?('2')
SetScale('1')
IF GreaterThan? SUB# Recall# Num#('4') Peck# SPZ# {IF OldZ - Peck# > Depth}
Save# Num#('4') SUB# Recall# Num#('4') Peck# {Save#1 = OldZ - Peck# = NewZ}
RestoreScale
SeqC Feed ' Z' TrackZ# MUL# Recall# Num#('4') NumSc#('1') SaveFeedEnt FeedAndSpeed EOL {move to NewZ}
IF PeckFullRetract?
SeqC Rapid ZCP2 FeedAndSpeed EOL {move to CP2}
END
SeqC RapidC ' Z' TrackZ# ADD# Recall# Num#('4') Retract# FeedAndSpeed EOL {move to RetractZ}
ELSE
RestoreScale
SeqC Feed ' Z' TrackZ# SPZ# SaveFeedEnt FeedAndSpeed EOL {move to Depth}
IF RetractToCP1?
SeqC Rapid ZCP1 FeedAndSpeed EOL {move to CP1}
ELSE
SeqC Rapid ZCP2 FeedAndSpeed EOL {move to CP2}
END
SetFlag('2')
END
END
RETURN

DrillPath:
EACHFeat
SeqC RapidC MoveSXYC FeedAndSpeed EOL
SeqC ZCP2C FeedAndSpeed EOL
IF Peck?
SetFlagF('2') { done flag }
SetScale('1')
Save# Num#('4') ClearancePlane2#
RestoreScale
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck DoPeck
ELSE
SeqC Feed ' Z' ZDepth# SaveFeedEnt FeedAndSpeed EOL
IF Dwell?
SeqC ' G04 X' Dwell# FeedAndSpeed EOL
END
IF FIRO?
IF RetractToCP1?
SeqC Rapid ZCP1 FeedAndSpeed EOL
ELSE
SeqC Rapid ZCP2 FeedAndSpeed EOL
END
END
IF FIFO?
SeqC ZCP2 FeedAndSpeed EOL
IF RetractToCP1?
SeqC Rapid ZCP1 FeedAndSpeed EOL
END
END
IF TAP?
SeqC InverseSpinOn FeedAndSpeed EOL
SeqC ZCP2 FeedAndSpeed EOL
SeqC SpinOn FeedAndSpeed EOL
IF RetractToCP1?
SeqC Rapid ZCP1 FeedAndSpeed EOL
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF MultipleParts? AND WorkFixtureOffsets?
SeqC SetWFO FeedAndSpeed EOL
ELSE
IF NewWFO?
SeqC ' G' NewWFO# FeedAndSpeed EOL
END
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

DoOp:
IF FirstOperation?
SeqC OpToolID ' M24' EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff FeedAndSpeed EOL
SeqC 'Z' TCZ# FeedAndSpeed EOL
END
DoOpComments
WFOStuff
ELSE
DoOpComments
DoPostScript
WFOStuff
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC Plane Rapid StrtPos FeedAndSpeed EOL
ELSE
SeqC Plane Rapid StrtPos ' Z' TCZ# FeedAndSpeed EOL
SeqC ZCP1 FeedAndSpeed EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
{only need to set up for tool change on 1st part}
ELSE
SeqC CoolOff FeedAndSpeed EOL
SeqC ' Z' TCZ# FeedAndSpeed EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home FeedAndSpeed EOL
END
IF LAST ProgStop?
SeqC ' M00' FeedAndSpeed EOL
ELSE
SeqC ProgStop FeedAndSpeed EOL
END
END

{Start new Operation}

IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff FeedAndSpeed EOL
SeqC ' Z' TCZ# FeedAndSpeed EOL
END
DoOpComments
WFOStuff
ELSE
SeqC OpToolID EOL
SeqC ToolChng EOL
DoOpComments
DoPostScript
WFOStuff
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC Plane Rapid StrtPos FeedAndSpeed EOL
ELSE
SeqC Plane Rapid StrtPos FeedAndSpeed EOL
SeqC ZCP1 CoolOn FeedAndSpeed EOL
END
ELSE
IF SameTool?

{Finish off last Operation}

IF LAST ProgStop?
SeqC CoolOff FeedAndSpeed EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff FeedAndSpeed EOL
END
END
IF LAST ProgStop? OR NewToolOffset?
SeqC ' Z' TCZ# FeedAndSpeed EOL
END
DoEndOpPS
IF LAST ProgStop?
SeqC ' M00' FeedAndSpeed EOL
END

{Start new Operation}

DoOpComments
DoPostScript
WFOStuff
CheckPass
SeqC PlaneC Rapid StrtPos FeedAndSpeed EOL
IF LAST ProgStop? OR NewToolOffset?
SeqC ZCP1 FeedAndSpeed EOL
END
IF LAST ProgStop?
SeqC CoolOn FeedAndSpeed EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn FeedAndSpeed EOL
END
END
END
END
END

{ Common Point for All Operations }

ResetCRCNum {call here to reset for each new operation only, call in tool path to reset for each repeat in an operation}

IF Milling?
SeqC ZCP2C FeedAndSpeed EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqC Connect StrtPos FeedAndSpeed EOL
IF NOT FeedConnect?
SeqC ZCP2C FeedAndSpeed EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqC CRCOffC
IF NOT FeedConnect?
ExitType PRIME ZCP3C
END
ExitFeed FeedAndSpeed EOL
NEXTRep
END
END
IF AutoCycle?
SeqC ZCP3C FeedAndSpeed EOL
ELSE
SeqC CRCOffC ExitType ZCP3C ExitFeed FeedAndSpeed EOL
END
ELSE
IF Drilling?
IF Repeats?
EACHRep
DoSubComment
END
DrillPath
IF Repeats?
SeqC RapidC ZCP3C FeedAndSpeed EOL
NEXTRep
END
SeqC RapidC ZCP3C FeedAndSpeed EOL
END
END
RETURN

FinishLastOp:
SeqC CoolOff FeedAndSpeed EOL
SeqC ' Z' TCZ# FeedAndSpeed EOL
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC Rapid FirstHome FeedAndSpeed EOL
END
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart? {no tool change after doing last part}
IF ProgStop?
SeqC ' M00' FeedAndSpeed EOL
ELSE
SeqC ProgStop FeedAndSpeed EOL
END
ELSE
SeqC EOP EOL
END
RETURN

DoToolsOps:
EachOp
IF GTEqual? Operation# Recall# Num#('1') AND LTEqual? Operation# Recall# Num#('2')
{Tools1stOp ² op ² ToolsLastOp}
DoOp
END
NextOp
RETURN

NextTools1stOp:
SetNextToolOp Operation#
RETURN

GetToolsOps:
EachOp
IF Equal? Operation# Recall# Num#('1') {if op = Tools1stOp}
IF GreaterThan? NextTools1stOp Recall# Num#('1') {if NextTools1stOp is greater Tools1stOp}
Save# Num#('2') SUB# NextTools1stOp Num#('1') {ToolsLastOp becomes NextTools1stOp less 1}
ELSE {else}
Save# Num#('2') Recall# Num#('3') {ToolsLastOp becomes ncCAMsLastOp}
END
END
NextOp
RETURN

DoTool:
IF NOT Flag?('1')
GetToolsOps
IF WorkFixtureOffsets?
NewWFO
EachWFO
TagInc
DoToolsOps
IncWFO
NextWFO
ELSE
EachPart
TagInc
DoToolsOps
NextPart
END
IF LessThan? Recall# Num#('2') Recall# Num#('3') {if ToolsLastOp < ncCAMsLastOp}
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') {Tools1stOp becomes NextTools1stOp}
ELSE {else}
SetFlag('1') {set DoneFlag}
END
TagInit
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
SetFlagF('1') { Multiple Parts done flag }
SetFlagF('2') { Peck Drilling done flag }
SetFlagF('3') { Set Flag to FALSE. Used when the First item in Toolpath is an ARC }
Save# Num#('1') Num#('0') {tools 1st op}
Save# Num#('2') Num#('0') {tools last op}
Save# Num#('3') Num#('0') {ncCAMs last op}
Save# Num#('4') Num#('0') {peck drill Z position}
Save# Num#('5') Num#('0') {current feed rate}
SetAbs
ReverseXZArcs
InitWFONum
SetFlood
SetTCZ('.3937')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
SaveFeedEnt
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE MILLIMETERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
END
NextOp
IF MultipleParts?
IF AllToolsOnePart?
IF WorkFixtureOffsets?
NewWFO
EachWFO
TagInc
EachOp
DoOp
NextOp
FinishLastOp
IncWFO
NextWFO
ELSE
EachPart
TagInc
EachOp
DoOp
NextOp
FinishLastOp
NextPart
END
ELSE
IF OneToolAllParts?
EachOp
IF FirstOperation?
Save# Num#('1') Operation# {ncCAMs1stOp becomes Tools1stOp}
END
IF LastOp?
Save# Num#('3') Operation# {save ncCAMsLastOp}
END
NextOp
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
FinishLastOp
END
END
ELSE
EachOp
DoOp
NextOp
FinishLastOp
END
EOR EOL
CloseSub
Post2
IF UseComments?
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
Close