{Change Comments ***********************************************************}

{4/6/90
Copied & modified: GE 1050T LeBlonde L105.69.3
For: Robbins & Meyers, Inc
Added decimal points & spaces between codes.
Machine: LeBlond Makino Baron 40
Control: General Electric 1050 HL
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{9/5/90
Copied & modified: GE 1050T (R&M) L151.70
For: Robbins & Meyers, Inc
Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.2 Format
DWB}

{9/11/90
Modified: GE 1050T (R&M) L151.72
For: Gibbs & Associates
NOTE!!! This Post Processor suffers from a bug in the XatFinZ Command for Canned Thread Cycles
on a PosSideLathe. To resolve this problem, I have fooled the Lathe by setting it to
NegSideLathe, and Modifying the FORMATs in the Prog and Form that Output any X and/or I Axis
Data, by MULtiplying the Value by -1. Those FORMATs that were MODified in the Prog immediately
follow the FORMAT definitions below. The FORMATs that were MODified in the Form are:
X in the Default FORMATs ( I was not MODified because Control requires NoIJKSigns )
Simple Rough Canned Cycles ( Turning and Facing ):
Finish X at Finish Z
X Taper at Start Z
Contour Rough Canned Cycles ( Turning and Facing ):
X Stock Left
X Stock - Last Pass
Pattern Shift Canned Cycle:
X Stock Left
X - U
Threading Canned Cycle:
Finish X at Finish Z
X Taper at Start Z
It is recommended that at the time the bug is fixed, that all Posts with this NOTE be reverted
to their previous Form and Prog.
DWB}

{12/12/91
Modified: GE 1050T (R&M) L151.72.1
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
NOTE!!! Bug reported on 9/11/90 has been corrected, and this Form and Prog has been reverted.
Full Canned Cycle Support.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '########;0'
#4 = '###.####;0'
#5 = '#.#####;0'
#6 = '###0'
#7 = '+###.####;0'
#8 = '###.#;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(TrackX#,2)
FORMAT(GECSPX#,2)
FORMAT(CycleStartX#,2)
FORMAT(FinishXDia#,2)
FORMAT(TrackZ#,2)
FORMAT(GECSPZ#,2)
FORMAT(FinishZ#,2)
FORMAT(Peck#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(CutDepth#,7)

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( SUBROUTINE FOR OPERATION ' Operation# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

GetGESP:
IF CannedCycle?
SetStatusOff
SetPass2
Save# Num#('1') SPX#
Save# Num#('2') SPZ#
IF Roughing?
IF NOT RoughSimple?
Save# Num#('1') ADD# Recall# Num#('1') MUL# StockXRadius# Num#('2')
Save# Num#('2') ADD# Recall# Num#('2') ADD# StockZ# NumSc#('.1')
IF ApproachFace?
IF GreaterThan? CycleStartX# FirstMoveEPX# { ODFaceApproach }
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('.2')
ELSE { IDFaceApproach }
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('-.2')
END
END
EachFeat
IF LastFeat?
IF ApproachFace?
Save# Num#('2') EPZ#
ELSE
Save# Num#('1') EPX#
END
END
NextFeat
END
ELSE
IF Threading?
IF ApproachOD?
IF ToolOver?('9')
Save# Num#('1') ADD# FinishXDia# MUL# ThreadXInc# Num#('-2')
ELSE
Save# Num#('1') ADD# FinishXDia# MUL# ThreadXInc# Num#('2')
END
ELSE { ApproachID }
IF ToolOver?('9')
Save# Num#('1') ADD# FinishXDia# MUL# ThreadXInc# Num#('2')
ELSE
Save# Num#('1') ADD# FinishXDia# MUL# ThreadXInc# Num#('-2')
END
END
ELSE { Drilling }
IF SameTool? AND LAST Drilling?
Save# Num#('3') Num#('0')
END
END
END
IF ApproachOD?
IF ToolOver?('9')
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('-.2')
ELSE
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('.2')
END
ELSE
IF ApproachID?
IF ToolOver?('9')
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('.2')
ELSE
Save# Num#('1') ADD# Recall# Num#('1') NumSc#('-.2')
END
ELSE { ApproachFace }
IF NOT Threading? AND NOT Drilling?
Save# Num#('2') ADD# Recall# Num#('2') NumSc#('.1')
END
END
END
SetPass1
SetStatusOn
END
RETURN

GESPX:
TrackX# Recall# Num#('1')
Save# Num#('3') Recall# Num#('1')
RETURN

GESPZ:
TrackZ# Recall# Num#('2')
Save# Num#('4') Recall# Num#('2')
RETURN

GESPXC:
IF CannedCycle?
IF NotEqual? Recall# Num#('1') Recall# Num#('3')
' X' GESPX
END
ELSE
XSPC
END
RETURN

GESPZC:
IF CannedCycle?
IF NotEqual? Recall# Num#('2') Recall# Num#('4')
' Z' GESPZ
END
ELSE
ZSPC
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan GESPZC EOL
SeqLabC StockOff XOpCDC EOL
Save# Num#('3') XOpCD#
SeqLabC Feed StockOnNoCan GESPXC FeedRate EOL
RETURN

IDApproachSP:
SeqLabC StockOnNoCan GESPZC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
Save# Num#('3') XOpCD#
SeqLabC Feed StockOnNoCan GESPXC FeedRate EOL
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan GESPXC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
Save# Num#('4') ZOpCP#
SeqLabC Feed StockOnNoCan GESPZC FeedRate EOL
RETURN

AppMove:
ZCP CoolOn
Save# Num#('4') ZStockMax#
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Save# Num#('3') HomeX#
Save# Num#('4') HomeZ#
IF ApproachOD?
SeqLabC Rapid XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC Rapid XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC Rapid StockOnNoCan GESPXC StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

GetConstantSurfaceFeed:
SeqLabC CSSOn ' G96 R'
IF CannedCycle?
GESPX
ELSE
CycleStartX#
END
Speed ' M81' EOL { Inhibit Operation of CSS On }
RETURN

CheckSpinOn:
IF ToolOver?('9')
InverseSpinOn
ELSE
SpinOn
END
RETURN

CheckInverseSpinOn:
IF ToolOver?('9')
SpinOn
ELSE
InverseSpinOn
END
RETURN

CheckGear:
IF NewGear?
CheckSpinOn
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
IF NewGear?
SeqLabC LOfstOff '00' SpinOff EOL
SeqLabC OpToolID LatheOffset GearRange EOL
ELSE
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
ELSE
IF NewGear?
SeqLabC SpinOff EOL
SeqLabC GearRange EOL
END
END
IF ConstantSurfaceFeed?
IF LAST NOT ConstantSurfaceFeed?
CSSOn CalcRPM1
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' Speed ' M80' EOL { Inhibit Operation of CSS Off }
END
END
IF LAST ProgStop?
SeqLabC SpeedC CheckSpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC CheckGear EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FinishThreadStart: { For Canned Thread Cycle }
Save# Num#('6') ADD# FinishXDia# Taper#
FORMAT(Recall#,2)
' X' Recall# Num#('6')
RETURN

FIRSTThreadCutDepth: { For Canned Thread Cycle }
FORMAT(MUL#,7)
MUL# SUB# ABS# SUB# Recall# Num#('6') FirstMoveEPX# ThreadXInc# Num#('2')
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC ArcIJ
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G94' EOL
SeqLabC ' G04 X2.' EOL
SeqLabC ' G95' EOL
SeqLabC Speed CheckInverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G94' EOL
SeqLabC ' G04 X' Dwell# EOL
SeqLabC ' G95' EOL
END
END
ELSE
IF CannedCycle?
IF Roughing?
IF NOT RoughSimple?
SeqLab
END
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
ReverseXZArcs
NoIJKSigns
SetMaxRPM('3500')
SetMaxFeed('400')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'S' ASCII ('18') EOL
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
Plane
DoOpComments
DoPostScript
GetGESP
SeqLab AbsOrInc GearRange EOL
SeqLabC ' G70' EOL
SeqLabC ' G95' EOL { Inches per Revolution FeedRate }
SeqLabC Preset Home EOL
SeqLabC CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
CheckSpinOn EOL
SeqLabC OpToolID LatheOffset EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' CalcRPM2 ' M80' EOL { Inhibit Operation of CSS Off }
END
SeqLabC NewHome EOL
SeqLabC LOfstOff '00' EOL
IF NewGear?
SeqLabC SpinOff EOL
END
IF LAST ProgStop?
SeqLabC ' M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
GetGESP
SeqLab AbsOrInc GearRange EOL
SeqLabC ' G70' EOL
SeqLabC Preset Home EOL
SeqLabC CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
CheckSpinOn EOL
SeqLabC OpToolID LatheOffset EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
GetGESP
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan GESPXC GESPZC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
GetConstantSurfaceFeed
END
ELSE
SeqLabC Preset MaxRPM EOL
GetConstantSurfaceFeed
END
ELSE
SeqLabC Preset MaxRPM EOL
GetConstantSurfaceFeed
END
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
{ G81/G82 [ Turning/Facing ] Cycle:
X (Ä…2.5) = Workpiece Diameter at Final Cutting Depth.
Z (Ä…2.5) = Total Cutting Length at Final Cutting Depth.
P1 ( 2.5) = Maximum Depth of Cut per Pass in the [ X/Z ] Axis, Incremental, Radial Value.
P2 (Ä…2.5) = Taper Pull-out Point at END of LAST Pass, Incremental from
Absolute StartPoint.
P3 (Ä…2.5) = Taper Pull-in Point at Beginning of LAST Pass, Incremental from
Absolute StartPoint.
P4 ( 1 ) = IF a '1' is Programmed, all Moves are 'In Zone'.
P5 ( 3.1) = Pull-in FeedRate. }
StockOn
SetPass1
IF Taper?
' ' EOL
'( NOTE: This Post Processor does not support RoughSimple Cycle with Taper!!! )' EOL
' ' EOL
END
FORMAT(FeedIPR#,8)
SeqLabC LCycle ' X' FinishXDia# ' Z' FinishZ# ' P1' CutDepth# ' P41' ' P5' FeedIPR# FeedRate EOL
ELSE
TagInc
SetPass2
IF RoughContour?
{ G68/G69 [ Turning/Facing ] Cycle:
X (Ä…2.5) = X Axis Contour StartPoint, Diametral Value.
Z (Ä…2.5) = Z Axis Contour StartPoint.
I ( 2.5) = Amount of Finish Stock in X Axis, Incremental, Radial Value.
K ( 2.5) = Amount of Finish Stock in Z Axis, Incremental Value.
P1 ( 4 ) = Sequence Number of Starting Block.
P2 ( 4 ) = Sequence Number of Ending Block.
P3 ( 2.5) = Maximum Depth of Cut per Pass in [ X/Z ] Axis, Incremental, Radial Value.
P4 (Ä…1 ) = Tracing of EACH Pass as follows:
+0 = Tool follows Contour to END of EACH Pass ( Standard Gibbs Cycle ).
-0 = Same as +0, but on LAST Pass, Tool follows entire Contour for a
Clean-up Pass.
+1 = Tool withdraws at 45Ä„ Angle at END of EACH Pass.
-1 = Same as +1, but on LAST Pass, Tool follows entire Contour for a
Clean-up Pass. }
SeqLabC LCycle XSP ZSP XStkLeft ZStkLeft ' P1Å‚' Tag# ' P2²' Tag# CutDepth ' P4+0' FeedRate EOL
ELSE
IF RoughPatternShift?
{ G66/G67 [ Turning/Facing ] Cycle:
X (Ä…2.5) = X Axis Contour StartPoint, Diametral Value.
Z (Ä…2.5) = Z Axis Contour StartPoint.
I ( 2.5) = Amount of Finish Stock in X Axis, Incremental, Radial Value.
K ( 2.5) = Amount of Finish Stock in Z Axis, Incremental Value.
P1 ( 4 ) = Sequence Number of Starting Block.
P2 ( 4 ) = Sequence Number of Ending Block.
P3 ( 2.5) = Maximum Depth of Cut per Pass in [ X/Z ] Axis, Incremental,
Radial Value.
P4 ( 2.5) = Maximum, Total Amount of Stock to be Removed, Incremental,
Diametral Value.
P5 ( 2 ) = Z Axis Angular Shift ²45Ä„. }
SeqLabC
IF ApproachFace?
' G67'
ELSE
LCycle { G66 }
END
XSP ZSP XStkLeft ZStkLeft ' P1Å‚' Tag# ' P2²' Tag# ' P3' CutDepth# XminusU ' P545' FeedRate EOL
END
END
IF AutoFinish?
SeqLabC ' G25 P1Å‚' Tag# ' P2²' Tag# EOL
END
OpenSub
DoSubComment
'>' Tag# EOL
SeqLab
IF FIRST RapidFeat?
Rapid
ELSE
Feed
END
ToolPath
'<' Tag# EOL
CloseSub
END
ELSE
IF Threading?
{ G84 Cycle:
X (Ä…2.5) = Root Diameter at Beginning of Thread, Absolute Value.
Z (Ä…2.5) = ZDepth at End of Thread, Absolute Value.
P1 ( 2.5) = Cutting Depth of FIRST Pass.
P2 ( 1.6) = Thread Lead.
P3 (Ä…2.5) = Tapered Root Diameter at End of Thread, Absolute Value.
P4 (Ä…2.5) = Anticipated Pull-out Lead Distance at End of Thread. }
{ G80 AutoFinish Cycle:
P3 ( 3 ) = Control will make Additional Clean-up Pass(es). }
FORMAT(ADD#,2)
IF AutoFinish?
SeqLabC ' G80 P32' EOL
END
FORMAT(FeedIPR#,5)
SeqLabC LCycle FinishThreadStart FinZ ' P1' FIRSTThreadCutDepth ' P2' FeedIPR#
IF Taper?
' P3' FinishXDia#
END
EOL
ELSE
IF Drilling?
IF Tap?
{ G33 Cycle: }
FORMAT(FeedIPR#,5)
SeqLabC LCycle ZDepth ' K' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC ' G94' EOL
SeqLabC ' G04 X2.' EOL
SeqLabC ' G95' EOL
SeqLabC Speed
IF ToolOver?('9')
SpinOn
ELSE
InverseSpinOn
END
EOL
SeqLabC ZSP EOL
ELSE
IF Peck? AND PeckChipBreaker?
{ G83 Cycle:
Z (Ä…2.5) = Final Hole Depth, Absolute Value.
P1 ( 2.5) = FIRST Peck Increment.
P2 ( 1.2) = Multiplier of [ P1 ] Peck Increment for Succeeding Pecks.
P3 ( 3.4) = Dwell Period at the Bottom of Hole, in Spindle Revolutions.
P4 ( 2.5) = Retract Increment after EACH Peck.
P5 ( 2.5) = Minimum Peck Increment. }
SeqLabC LCycle ZDepth Peck ' P2.8'
IF Dwell?
FORMAT(MUL#,4)
' P3' MUL# DIV# Dwell# Num#('60') SpeedRPM#
END
Retract ' P5' Peck# FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC ' G94' EOL
SeqLabC ' G04 X' Dwell# EOL
SeqLabC ' G95' EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLabC RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC ' G94' EOL
SeqLabC ' G04 X2.' EOL
SeqLabC ' G95' EOL
SeqLabC Speed CheckSpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC XCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
IF ConstantSurfaceFeed?
SeqLabC CSSOff ' G97 S' CalcEPRPM# ' M80' EOL { Inhibit Operation of CSS }
END
SeqLabC CoolOff EOL
SeqLabC FirstHome EOL
SeqLabC OpToolID '00' EOL
IF ProgStop?
SeqLabC ' M00' EOL
END
SeqLabC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
NullFoot ASCII ('4') EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END