{Change Comments ***********************************************************}

{1/4/91
Copied & modified: GE 550 L&S L184.71.4
For: LTS
Made changes per James Moore.
JC}

{1/29/91
Modified: GE 1050 L&S L191.71.5
For: LTS
Machine: Lodge & Shippley
Control: General Electric Mark Century 1050.
Customer says he is 'going down to a Rybet downloader', which creates a RS232 port on his machine.
Changed all Seq to SeqC
Modified all occurances of OpToolID LatheOffset to be 'T' LatheOffset Tool#.
Rapid outputs 'G21', Feed outputs 'G21', CWArc outputs 'G23' and CCWArc outputs 'G22'.
Rapid, Feed, CWArc and CCWArc to be non-conditional.
Replaced all occurances of SpeedGE to be Speed.
Added SpinOn to Speed line.
Moved CoolOn to line by itself following Speed line.
Deleted second Move to Home in FirstOperation, and to NewHome in NewTool.
Modified NewHome to be LAST Home in NewTool, and FirstHome to be Home at end.
Added Spaces in Front of all Address Labels in both the Prog and Form.
Added GearRange to NewTool.
Modified GearRange resources to be Low = M11 (S500) and High = M13 (S2500).
DWB}

{2/5/91
Modified: GE 1050 L&S L191.71.6
For: LTS
Modified FORMAT for I & K Arc Centers from 0^#### to 0#^#### in the Form.
Modified FORMAT for K Thread Lead from 0^#### to 0^##### in the Form.
Deleted NoIJKSigns from Prog.
DWB}

{12/12/91
Modified: GE 1050 L&S L191.71.7
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
Only Canned Cycles supported is Tapping.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '0#^####;0'
#3 = '########;0'
#4 = '#####^##0'
#5 = '0^###'
#6 = '0000'
#7 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CycleStartX#,2)
FORMAT(FinishXRadius#,2)
FORMAT(CycleStartZ#,2)
FORMAT(FinishZ#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(RapidF#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(Tool#,7) {.72}

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

ODApproachSP:
SeqC Rapid StockOnNoCan ZSP EOL
SeqC Rapid StockOff XOpCD EOL
SeqC Feed StockOnNoCan XSP FeedRate EOL
RETURN

IDApproachSP:
SeqC Rapid StockOnNoCan ZSP EOL
IF SameTool?
SeqC Rapid StockOff XOpCD EOL { for SameTool ApproachID }
END
SeqC Feed StockOnNoCan XSP FeedRate EOL
RETURN

FaceApproachSP:
IF SameTool?
SeqC Rapid StockOnNoCan XSP EOL { for SameTool ApproachFace }
END
SeqC Rapid StockOff ZOpCP EOL
SeqC Feed StockOnNoCan ZSP FeedRate EOL
RETURN

AppMove:
ZCP RapidF
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC Rapid XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC Rapid XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC Rapid StockOnNoCan XSP StockOff AppMove EOL
FaceApproachSP
END
END
RETURN

GetConstantSurfaceFeed:
SeqC CSSOn ' G96' Speed ' R' CycleStartX# EOL
RETURN

CheckSpinOn:
SpinOn
RETURN

CheckGear:
IF NewGear?
CheckSpinOn
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
IF NewGear?
SeqC ' T00' Tool# SpinOff EOL
SeqC ' T' LatheOffset Tool# GearRange EOL
ELSE
SeqC ' T00' Tool# EOL
SeqC ' T' LatheOffset Tool# EOL
END
ELSE
IF NewGear?
SeqC SpinOff EOL
SeqC GearRange EOL
END
END
IF ConstantSurfaceFeed?
IF LAST NOT ConstantSurfaceFeed?
CSSOn CalcRPM1
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOff ' G97' Speed
END
END
IF LAST ProgStop?
SeqC SpeedC CheckSpinOn EOL
SeqC CoolOn EOL
ELSE
SeqC SpeedC CheckGear EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXC MoveZC ArcIJC
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC ' G04 X2000' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqC ' G04 X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC Rapid MoveXC MoveZC RapidFC EOL
ELSE
IF LineFeat?
SeqC Feed MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC ' G33' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
ReverseXZArcs
XsAreRadii
SetMaxRPM('1200')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'S' ASCII('18') EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq AbsValue EOL
SeqC ' G70 M81' EOL
SeqC ' G90 M83' EOL
SeqC ' G95 M13' EOL
SeqC Preset Home GearRange EOL
SeqC AbsValue ' T' LatheOffset Tool# EOL
SeqC CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
SeqC CoolOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
IF LAST ApproachOD?
SeqC Rapid XCP RapidFC EOL
ELSE
IF LAST ApproachID?
SeqC Rapid LAST XOpECD RapidFC EOL
END
END
SeqC Rapid ZCP RapidFC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqC CSSOff ' G97' CalcRPM2 EOL
END
SeqC Rapid LAST Home RapidFC EOL
SeqC ' T0000'
IF LAST ProgStop?
' M00'
ELSE
ProgStop
END
EOL

{Start new Operation}

Seq AbsValue EOL
DoOpComments
DoPostScript
IF NewGear?
SeqC SpinOff EOL
SeqC Preset Home GearRange EOL
ELSE
SeqC Preset Home EOL
END
SeqC AbsValue ' T' LatheOffset Tool# EOL
SeqC CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
SeqC CoolOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
SeqC Rapid StockOnNoCan XSP ZSP RapidFC EOL
ELSE
IF ApproachOD?
IF LAST ApproachOD?
SeqC Rapid LAST XOpECD RapidFC EOL
ELSE {around}
IF LAST ApproachID?
SeqC Rapid LAST XOpECD RapidFC EOL
END
SeqC Rapid ZCP RapidFC EOL
SeqC Rapid XCP EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC Rapid LAST XOpECD RapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC Rapid XCP RapidFC EOL
END
SeqC Rapid ZCP RapidFC EOL
SeqC Rapid XOpCD EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC Rapid LAST ZOpECP RapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC Rapid XCP RapidFC EOL
ELSE {LAST ApproachID}
SeqC Rapid LAST XOpECD RapidFC EOL
END
SeqC Rapid ZCP EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
IF SameTool?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
GetConstantSurfaceFeed
END
ELSE
SeqC ' G98' MaxRPM EOL
GetConstantSurfaceFeed
END
ELSE
SeqC ' G98' MaxRPM EOL
GetConstantSurfaceFeed
END
END
IF CannedCycle?
IF Drilling?
IF Tap?
SeqC LCycle ZDepth ' K' FeedIPR# EOL
SeqC SpinOff EOL
SeqC ' G04 X2000' EOL
SeqC Speed InverseSpinOn EOL
SeqC LCycle ZSP ' K' FeedIPR# EOL
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Threading? AND NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqC Rapid StrtPos RapidFC EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC ' G04 X2000' EOL
SeqC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF ApproachOD?
SeqC Rapid XCP RapidFC EOL
ELSE
IF ApproachID?
SeqC Rapid XOpECD RapidFC EOL
END
END
SeqC Rapid ZCP RapidFC EOL
DoEndOpPS
SeqC CoolOff EOL
IF ConstantSurfaceFeed?
SeqC CSSOff ' G97 S' CalcEPRPM# EOL
END
SeqC Rapid Home RapidFC SpinOff EOL
SeqC ' T0000' EOL
IF ProgStop?
SeqC ' M00' EOL
END
SeqC EOP EOL
Post
EOR EOL
ASCII('04') EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END