{
MILL=F
LATHE=T
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{2/1/91
Copied & modified: Siemens 810T L040.69.3
For: Oskar Vatterott, Inc
Machine: Emco Meyer #340
Control: Siemens Sinumeric 810T
Replaced all occurances of the obsolete StockXDiameter# command with StockXRadius#.
Added InverseSpinOn for Tapping Operation in ToolPath.
SK}

{4/23/91
Modified: Siemens 810T EM L155.71.2
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Only Canned Cycles supported are RoughContour, Threading and PeckChipBreaker.
DWB}

{11/10/94
Updated: Siemens 810T EM L155.80
For: Gibbs & Associates
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.23
Changes made per Jackson
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1b Format.
Corrected FORMAT3 from '########;0' to '#######0' at Prog Numeric Format Definitions.
Added FORMAT7 '#' for RapidF# at Prog Numeric Format Definitions.
Added RestoreScale Sub per 4-Axis Post Processor.
Modified handling of Approaches.
Added FeedNoCan and FeedRateNoCan subs.
Adds Logic to suppress Feed and FeedRate for SameTool Approaches.
Added ODApproachSP, IDApproachSP, FaceApproachSP and AppMove subs.
Broke up Approach sub for all operations for improved readability and less nested decisions.
Moved StockOff to XCPC and XOpCDC only at Approach sub.
StockOnNoCan still at XSPC.
Added RapidF# at Approach sub.
No Output.
Forces FIRST FeedRateC to Output from ToolPath during FirstOperation OR NewTool.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Combined and modified CheckRapid subs.
Added StandardXZArcs at setup and initializations.
This ensures correct output following use of NegSideLathe Post Processor containing ReverseXZArcs.
Restructured handling of Exit to Approach moves at SameTool.
Moved XOpECDC for IDExit from end of operation to NewTool, SameTool and end of Prog.
This was to ensure that all operations end at the LAST Features EndPoint.
Added Tracking at end of CannedCycle Roughing RoughContour.
Modified handling of non CannedCycle AutoFinish.
Added bypass of AutoFinish for Non-Canned RoughSimple.
Added bypass of AutoFinish for Non-Canned Threading.
Method of testing for IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple? AND NOT Threading?
did not allow for AutoFinish pass of IF Turning?
Rewrote to test for IF Turning? ELSE IF Roughing? AND NOT RoughSimple?
Modified AutoFinish Approaches.
Changed RapidC StrtPos to StockOff StrtPosC for Turning.
Added XSPC ZSPC for RoughContour.
Changed ThrdLead to FeedRateC at ToolPath ThreadFeat.
ThreadLead was outputting value without an address.
Added SetPass1 at CannedCycle Roughing RoughContour for safety reasons.
DWB}

{
Format: Hyundai HiTrol 840C[-] L330.85
5/17/95
For: Hyundai
Fixed pitch in G33 style thread
Added G92 to G96 lines
All canned drills now use L98 cycle
Fixed the output of the start position in a canned cycle
Fixed output of pitch in L97 thread cycle
Added support for many of the new Virtual threading options
TH}

{
Format: Hyundai HiTrol 840C[-] L330.85.1
9/29/95
For: AE Thurber
Added G53DO to home position
Seperated G92 MaxRPM from the G96 lines
Added Tool Change pos to end of program
Changed R20 in thread cycle to output pitch
TH}

{
Format: Hyundai HiTrol 840C[-] L330.85.2
10/12/95
For: Hyundai
Changed Canned Threading to Output Major Dia for R21 & R31
Changed G33 threading to output pitch instead of TPI
Remove M51 from output
Fixed Canned Drilling to output forrect values for R24
TH}

{
Format: Hyundai HiTrol 840C[-] L330.85.3
10/30/95
For: AE Thurber
Moved G53 line to be before Tool ID in NewTool
Dwell values (R27,R28) now always output
TH}

{
Format: Hyundai HiTrol 840C[-] L330.85.4
11/1/96
For: Hyundai
Removed M51 from output


5/21/97 [ws]
Hyundai HiTrol 840C[-] L330.85.5 (Hyundai HiTrol 840C[-] L330.85.4)
For: Hyundai
fixed to support AutoClearance by doing the following:
replaced ZCP with ThisOpEntryZCP in AppMove
replaced XCP with ThisOpEntryXCP in Approach
replaced XCPC with OpExitXCPC in various places
replaced ZCPC with OpExitZCPC in various places
WS}

{11/11/98
Initial: Hyundai HiTrol 840C L330.85.5
Created: Hyundai HiTrol 840EZ Lxxx.85
ForUser: Militec Defense Systems
Control: HiTrol 840EZ
Machine: Hyundai
Develop: Compost2 v1.6b8, Virtual 4.29.63
Comment: New processor per marked up readout and conversation with Tom Sonnen
Modified beginning of tools.
Added Rapid to AbsOrInc line and added line to NewTool.
Deleted G53 Home line
Moved tool offset and spindle on to OpToolID line, leaving G54 on line by itself!
Moved Speed to OpToolID line.
Removed the G53 from the Home line at end of tools.
Modified Canned Cycles
Changed Drill cycle from L98P1 to L998P1
Changed Internal Thread Cycle from L97P1 to L997P1 (external is still L97P1)
Corrected Threading R21 formula (OD was outputting negative values)
Corrected Threading R31 formula (OD was outputting negative values & Taper was incorrect)
Corrected Drilling R25 formula to output initial peck amount
Updated per Fanuc 10T MS [-] L001.85.01.02
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####.####;0'
#3 = '#######0'
#4 = '#####.###;0'
#5 = '0000'
#6 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CycleStartXDia#,2)
FORMAT(CycleStartZ#,2)
FORMAT(StockXRadius#,2)
FORMAT(StockZ#,2)
FORMAT(CutDepth#,2)
FORMAT(FeedIPR#,2)
FORMAT(FinishXDia#,2)
FORMAT(FinishZ#,2)
FORMAT(ThreadXInc#,2)
FORMAT(Retract#,2)
FORMAT(Peck#,2)
FORMAT(DIV#, 2)
FORMAT(SUB#, 2)
FORMAT(ADD#, 2)
FORMAT(SpringPasses#, 2)
FORMAT(ToolOffset#,3)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(RapidF#,6)
FORMAT(FeedContour#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(RunInZ#,2)
FORMAT(RunOutZ#,2)
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPX#,2)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC 'D0' EOL
END
DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
ELSE
SeqC Preset MaxRPM EOL
END
END
SeqC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
ELSE
CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOff 'G95' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF NewToolOffset?
OpToolID 'D' ToolOffset#
END
IF LAST ProgStop?
SpinOn
END
EOL
SeqC
IF LAST ProgStop?
CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF NOT CannedCycle?
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
InverseSpinOn
ELSE
IF Dwell?
SeqC 'G4X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC 'K' FeedIPR# EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR 'MPF' Program# EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq AbsOrInc Rapid EOL
SeqC
IF ConstantSurfaceFeed?
'G92' MaxRPM EOL
SeqC CSSOn 'G96'
ELSE
CSSOff 'G95'
END
Speed OpToolID 'D' ToolOffset# SpinOn EOL
SeqC 'G54' EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC EOL
DoEndOpPS
SeqC Rapid 'D0' NewHome EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
Seq AbsOrInc Rapid EOL
SeqC
IF ConstantSurfaceFeed?
'G92' MaxRPM EOL
SeqC CSSOn 'G96'
ELSE
CSSOff 'G95'
END
Speed OpToolID 'D' ToolOffset# SpinOn EOL
SeqC 'G54' EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughContour?
SetPass2
NewProg
SeqC
FORMAT(Program#,6)
'R20=' Program#
'R21=' SPX#
'R22=' SPZ#
'R24=' StockXRadius#
'R25=' StockZ#
'R26=' CutDepth#
'R27=' {Need to set up for cutter comp}
IF CutterRadiusCompensation?
IF CRCLeft?
'41'
ELSE
'42'
END
ELSE
'40'
END
'R28=' FeedContour#
IF ApproachOD?
'R29=11'
ELSE
IF ApproachID?
'R29=13'
ELSE {OD ApproachFace}
'R29=12' {R29=14 is for ID ApproachFace}
END
END
'R30=1'
EOL
SetPass2
SeqC 'L95P1' EOL
OpenSub
'L' Program# EOL
DoSubComment
SeqC StepMove StrtPos EOL
ToolPath
SeqC 'M17' EOL
CloseSub
IF AutoFinish?
SeqC 'R24=0R25=0'
IF ApproachID?
'R29=22'
ELSE
'R29=21'
END
EOL
SeqC 'L95P1' Feedrate EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SetPass1
SeqC
'R20=' FeedIPR#
IF ApproachOD?
'R21=' SUB# CycleStartXDia# ABS# DiaDistanceToThread#
ELSE
'R21=' ADD# CycleStartXDia# ABS# DiaDistanceToThread#
END
'R22='
IF ZMinusCutDir?
SUB# CycleStartZ# RunInZ#
ELSE
ADD# CycleStartZ# RunInZ#
END
'R23=' SpringPasses#
IF ApproachID?
'R24=' ThreadXInc#
ELSE
'R24=-' ThreadXInc#
END
'R25=' StockXRadius#
'R26=' RunInZ#
'R27=' RunOutZ#
EOL
SeqC
'R28=' CalcNumCuts
'R29=' InFeedAngle#
'R31='
IF ApproachOD?
ADD# SUB# CycleStartXDia# ABS# DiaDistanceToThread# MUL# ABS# Taper# Num#('2')
ELSE
SUB# ADD# CycleStartXDia# ABS# DiaDistanceToThread# MUL# ABS# Taper# Num#('2')
END
'R32='
IF ZMinusCutDir?
ADD# FinishZ# RunOutZ#
ELSE
SUB# FinishZ# RunOutZ#
END
IF ApproachOD?
'L97P1'
ELSE
'L997P1'
END
EOL
ELSE
IF Drilling?
SeqC
IF PeckChipBreaker?
'R11=0'
ELSE
'R11=1'
END
'R22=' CycleStartZ#
IF Peck?
'R24=' Peck#
'R25=' ADD# SUB# CycleStartZ# CalcZSurf# Peck#
END
'R26=' FinishZ#
'R27=' Dwell#
'R28=' Dwell#
EOL
SeqC 'L998P1' Feedrate EOL
EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqC RapidC ZOpECPC EOL
ELSE
SeqC RapidC XOpECDC EOL
END
ApproachSP
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC EOL
SeqC StockOff StrtPosC EOL
ToolPath
SetPass1
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
DoEndOpPS
SeqC CoolOff EOL
SeqC Rapid 'D0' Home EOL
SeqC SpinOff EOL
SeqC EOP EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END