{Change Comments ***********************************************************}

{7/12/89
Copied & modified: Emco 220 T1 L104.55.
For: Hi-Stat.
Changed '0300' to 'O300' at beginning of Prog (letter O).
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{10/19/90
Modified: Emco 220 T1 L104.57
Updated per Fanuc 10T MS [-] L001.71 Format.
Modified FORMAT for 'F' in MachSpec, no decimals with 4 trailing zeros.
Deleted CoolOn & CoolOff commands except for the beginning & end of the Prog.
Deleted SpinOff except at the end of the Prog.
Changed FORMAT of 'D3' Depth of First Cut Parameter for Threading in MachSpec.
JR}

{12/12/90
Modified: Emco 220 T1 L104.57
For Hi-Stat:
Changed all 2.3 FORMATs to 2.4.
Changed 'D5' Peck Drilling Retract Parameter to literal 'D5=80', which is a Multiplier.
Changed literal 'O300' to ProgID1 per customer's request.
JC}

{3/26/91
Modified: Emco 220 T1 L104.71.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Only Canned Cycles supported are SimpleRough, Threading and Pecking Cycle.
DWB}

{8/6/91
Updated: Emco 220 T1 L104.80
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
KM}

{4/14/92
Modified: Emco 220 T1 L104.82
For: Hi-Stat.
Changes made per conversations with Dan Williams at Hi-Stat and sample printout.
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Deleted SetExitFormat sub and call to same.
This sub set the FORMAT for ClearancePlane3# based on the type of Approach but ClearancePlane3#
was not being used.
Changed ArcIJC to ArcIJ in FormatArc Sub, and deleted ArcRC.
All ArcFeats require both I&J.
Increased SetMaxRPM from 2500 to 4000.
Deleted IF ToolChangeAtHome? Booleans at FirstOperation, NewTool and end of Prog.
Lathe ncCAD documents don't give user this option.
Deleted SafeStart at NewTool.
Changed XAtFinZ to ' X' FinishXDia# at RoughSimple Canned Cycle.
Moved code of CheckFeedRate Sub to RoughSimple Canned Cycle.
This sub was only called from here.
Modified 'D6=' Parameter for Canned Threading Cycle.
Changed FORMAT for StockXRadius#, StockZ# and CutDepth# from '^###0' to '##^###0' in Prog.
Changed FORMAT for 'D3' Canned Threading Cycle CutDepth Parameter from '##^####0' to '##^###0'
in MachSpec.
Changed FORMAT for Canned Threading Cycle FeedRate Parameter from '##^####0' to '##^###0'
in MachSpec.
Added literal 'D6=1000' Minimum Peck Amount Parameter to Canned Peck Cycle.
Added 'P2=' FeedIPR# Threading Parameter IF Chamfer = TRUE.
DWB}

{6/25/92
Updated: Emco 220 T1 L104.82.1
For: Hi-Stat
Changes made per conversations with Dan Williams at Hi-Stat and sample printout.
Changed FORMAT for Taper# to output Ä… at Canned Threading Cycle.
Changed FORMAT for 'D6' Parameter at Canned Threading Cycle.
KLM}

{4/13/93
Modified: Emco 220 T1 L104.82.2
For: Hi-Sat
Changed Seq to SeqLab and changed the label in MachSpec to "N? ".
Notice the space following the ?.
Customer requested 2 spaces following the N code.
Added Retag at end of Prog following FILE LENGTH Comments.
NOTE: ReTag is outputting an additional line feed.
JR}

{4/22/93
Modified: Emco 220 T1 L104.82.3
For: Hi-Stat
Modified P2 Chamfer Parameter to output - for FrontSide Threading, + for BackSide Threading.
Restored FORMAT for Taper# to NOT output Ä… at Canned Threading Cycle.
Change was made on 6/25/93 and Customer said that no + signs are needed.
When machining an OD Tapered Thread from the BackSide, ncCam requires a Negative Taper value
causing XTapAtZ to output a Negative value. This is the P0 parameter for this control. Change
negates output of Taper#, same as above P2 Chamfer Parameter.
Deleted StockOn at RoughSimple Cycle.
Changed FinZ to ' Z' FinishZ# at RoughSimple Cycle.
Changed to output D0 & D2 Stock Parameters only when IF AutoFinish? = TRUE at RoughSimple Cycle.
JR}

{Date
Modified: Emco 220 T1 L104.82.4
For: Hi-Stat
Changes made per conversations with Dan Williams at Hi-Stat and sample printout.
Added additional 4.1 version Updates.
Added Formulas for outputting XAtStartZ values for Taper Thread Cycle.
Canned Threading Cycle is different from Fanuc style in that X value is position at start of
Thread, not End. Formulas cover both Front and BackSide Threading.
DWB}

{4/25/97, added Y and J formats to Default formats in form, MPK}

{21May97
Original: Emco 220 T1 L104.82.6
Created: Emco 320 T1 Lxxx.82
For: UOP
Changes made per: Tom Martin
Added support for Tailstock advance and retract in PSStuff: using PIN() and POUT
Added support to open and close parts catcher using boolean OptCyc1 at the start and end of Toolpath:
Changed SetMaxRPM to ('6300')
Deleted ASCII('10') from FirstOp?
Changed all occurences of ':' (colon) in comments and replaced with '.' (period) - Customers control hangs up with ':'
Added OptCyc1F at InitProg and Toolpath:
Deleted G54 and M39 from FirstOp?
Added 'T0' in NewTool? and EndOps
Added support for Rough Turn and Face Canned cycles in MachSpec and IF CannedCycle?
Changed default 'F" Format from '##^###0' to '#0.####' in the MachSpec
Changed Canned Cycle threading feed format to '#0.####' in the MachSpec
Updated PSComment to explain the use of Part Catcher and Tailstock Advance and Retract
Deleted G53 T0000 from EndOp
Charles Winston}

{21May97
Original: Emco 320 T1 L597.82
Created: Emco 320 T1 L597.85
For: UOP
Updated to .85 format per Fanuc 10T MS [-] L001.85.01
Charles Winston}

{09Jun97
Original: Emco 320 T1 L597.85
Created: Emco 320 T1 L597.85.1
For: UOP mat/sen
Changes made per: Tom Martin
Added FORMATs #10, #11 and #12 and Formatted SpringPasses#, Retract and SPX#
Moved OpToolID LatheOffset from AppMove to FirstOperation and NewTool
Added Boolean to ToolPath ThreadFeat to suppress redundant Rapid
for threads with run-in or run-out
Added SpringPass and DoThreadSpringPass subs
Added EOL after EOR in FirstOperation
Moved NewHome to previous line before 'T0' in NewTool
Changed literal ' G70 G95' to ' G40 G70 G95' in NewTool
Changed Threading to output a simple 'G21' canned cycle with SpringPasses
Changed PeckChipBreaker to output 'G76' canned cycle per EMCO manual
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '##.####;0'
#3 = '#######0'
#4 = '0.0000;0'
#5 = '##^###0'
#6 = '###0'
#7 = '#'
#8 = '##^###0'
#9 = '*##^###0' { For Backside Thread }
#10 = '00' { For SpringPasses }
#11 = '#.000;.0'
#12 = '##.####;.0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(FinishXDia#,2)
FORMAT(FinishZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(Peck#,5)
FORMAT(StockXRadius#,5)
FORMAT(StockZ#,5)
FORMAT(CutDepth#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(FirstMoveEPX#,2)
FORMAT(SpringPasses#,10)
FORMAT(Retract#,11)
FORMAT(SPX#,12)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# '. ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# '. ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
IF PalletIn? {For advancing Tailstock}
IF UseComments?
'( Tailstock Advance )' EOL
END
SeqLabC ' M20' EOL
PalletInF
END
IF PalletOut? {For retracting Tailstock}
IF UseComments?
'( Tailstock Retract )' EOL
END
SeqLabC ' M21' EOL
PalletOutF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
IF FirstOperation?
CoolOn
END
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC StockOff ThisOpEntryXCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M0' EOL
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
ELSE
SeqLabC SpeedC EOL
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC ArcIJ
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF FirstFeat? AND OptCyc1?
IF UseComments?
'( Part Catcher Open )' EOL
END
SeqLabC ' M24' EOL {parts catcher open}
END
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 D2.0000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G4 D' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G33' MoveXC MoveZC ThrdLead EOL
IF NEXT NOT ThreadFeat?
Rapid
END
END
END
END
END
END
IF LastFeat? AND OptCyc1?
IF UseComments?
'( Part Catcher Closed )' EOL
END
SeqLabC ' M23' EOL {parts catcher closed}
OptCyc1F
END
NEXTFeat
IF ThreadFeat?
Rapid
END
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

SpringPass:
IF GreaterThan? Recall# NUM#('9') NUM#('0')
SeqLabC 'X' Recall# NUM#('10') EOL
END
Save# NUM#('9') SUB# Recall# NUM#('9') NUM#('1') {counter}
RETURN

DoThreadSpringPass:
Save# NUM#('9') SpringPasses#
SpringPass SpringPass SpringPass SpringPass SpringPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
SetMaxRPM('6300')
SetMaxFeed('500')
OptCyc1F
IF PSComment? AND UseComments?
'PostScript.' EOL
' Literals. put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands. must be all capital letters when typed in.' EOL
' ENDOP .' EOL
' ' EOL
' Tailstock Advance is activated by using the PIN() Postscript Command' EOL
' Tailstock Retract is activated by using POUT Command' EOL
' Part Catcher is activated by using the OPTCYC1 Command at the start' EOL
' of an operation' EOL
' ' EOL
' All literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT. ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLab 'G40 G70 G95' AbsOrInc EOL
SeqLabC Rapid Home EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
CSSOn ' G96'
ELSE
CSSOff ' G97'
END
SeqLabC Speed OpToolID LatheOffset SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' CalcRPM2 EOL
END
SeqLabC RapidC NewHome 'T0' EOL
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab ' G40 G70 G95' EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
CSSOn ' G96'
ELSE
CSSOff ' G97'
END
SeqLabC Speed OpToolID LatheOffset SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
SetPass1
SeqLabC LCycle
IF ApproachFace?
' Z' FinishZ# ' X' FinishXDia#
ELSE
' X' FinishXDia# ' Z' FinishZ#
END
' ' XTapAtZ
IF AutoFinish?
' D0=' StockXRadius# ' D2=' StockZ#
END
' D3=' CutDepth#
IF SameTool?
FeedRateC
ELSE
FeedRate
END
EOL
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G72' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SetFlag('10')
'G21'
EachFeat
IF ThreadFeat?
SeqLabC MoveXC MoveZC
IF Flag?('10')
SetFlagF('10')
XTapAtZ ThrdLead
END
EOL
Save# Num#('10') EPX#
END
NextFeat
IF GreaterThan? SpringPasses# Num#('0')
DoThreadSpringPass
END
ELSE
IF Drilling?
IF PeckChipBreaker?
SeqLabC LCycle 'R' Retract# EOL
SeqLabC LCycle 'X' SPX# ZDepth 'Q' Peck# FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
SeqLabC Rapid ZSP EOL
END
END
END
END
END
ELSE {Not canned Cycle}
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 D2.0000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC CoolOff EOL
DoEndOpPS
IF ConstantSurfaceFeed?
SeqLabC CSSOff ' G97 S' CalcEPRPM# EOL
END
SeqLabC 'T0' EOL
SeqLabC FirstHome SpinOff EOL
IF ProgStop?
SeqLabC ' M0' EOL
END
SeqLabC EOP EOL
EOR EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH. ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH. ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH. ' FileMeters# ' METERS )' EOL
END
Close
END
ReTag