{Change Comments ***********************************************************}

{8/24/95, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, DWB}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{29Jul97, Updated to Adv. Mill .13 format, Charles WInston}

{10/02/97,
Initial: Fadal Format 2 [G54] B586.13.
Created: Fadal Format 2 [G54] Bxxx.13.
For: Viratec
Added AbsOrInc calls in FirstOp3 and NewToolOp5 sub-routines.
CDH
}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,2)
FORMAT(CSOffsetB#,2)
FORMAT(SUB#,2)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(ToolDiameter#,4)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(ADD#,5)
FORMAT(CSSubID#,5)
FORMAT(Recall#,5)
FORMAT(Dwell#,6)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLabC '( SUB NUMBER - ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC '( OPERATION ' Operation# ' - ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC '( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC '( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLabC '( TOOL ' Tool# ' - ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC '( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

CSWFO:
'G' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
'G' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSAngleA:
IF AAxisAvail?
'A'
IF WFOCS? AND NOT Flag?('9')
'0.'
ELSE
IF NOT Flag?('9')
IF FirstOperation?
IF LessThan? CSOffsetA# Num#('0')
'-'
END
ELSE
IF LessThan? CSOffsetA# LAST CSOffsetA#
'-'
END
END
END
Save# Num#('1') TRUNC# DIV# CSOffsetA# Num#('360')
IF LessThan? CSOffsetA# Num#('0')
Save# Num#('1') SUB# Recall# Num#('1') Num#('1')
END
SUB# CSOffsetA# MUL# Recall# Num#('1') Num#('360')
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
'B'
IF WFOCS? AND NOT Flag?('9')
'0.'
ELSE
IF NOT Flag?('9')
IF FirstOperation?
IF LessThan? CSOffsetB# Num#('0')
'-'
END
ELSE
IF LessThan? CSOffsetB# LAST CSOffsetB#
'-'
END
END
END
Save# Num#('1') TRUNC# DIV# CSOffsetB# Num#('360')
IF LessThan? CSOffsetB# Num#('0')
Save# Num#('1') SUB# Recall# Num#('1') Num#('1')
END
SUB# CSOffsetB# MUL# Recall# Num#('1') Num#('360')
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
SeqLabC '( CS#' CS# ' - ' CSComment$ ' )' EOL
SetFlag('9')
SeqLabC '( ' CalcCSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' ' CSAngleA ' ' CSAngleB ' )' EOL
SetFlagF('9')
RETURN

PSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqLabC SubID DoSubComment EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
IF WFOCS?
NewProg
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLabC AbsValue SetWFO EOL
SeqLabC SubCall CallLab RepLab OnePart EOL
IncWFO
NextWFO
ELSE
SeqLabC SubCall CallLab RepLab Parts EOL
END
StartSub
END
RETURN

CloseMP:
IF WFOCS?
SeqLabC EndSub EOL
CloseSub
NewWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqLabC CalcCSWFO EOL
SeqLabC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
IF WorkFixtureOffsets?
SeqLabC EndSub EOL
CloseSub
SeqLabC AbsValue WFO1 EOL
ELSE
SeqLabC Preset ShiftPC EOL
SeqLabC EndSub EOL
CloseSub
SeqLabC Preset UnshftPC EOL
END
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqLabC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
SetFlag('2') { CRCOffsetC }
CRCOnC
END
END
RETURN

FormatLine:
DoAbsOrInc ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
IF Flag?('2')
SetFlagF('2')
CRCOffsetC
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatLine FeedRateC ckCRCNum EOL
DecelMove2
END
SeqLabC FormatLine DecelFeed ckCRCNum EOL
ELSE
SeqLabC FormatLine FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLabC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC EOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLabC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLabC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqLabC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLabC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLabC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CRCOffsetC }
SetFlagF('9') { CSAngleA, CSAngleB and DoCSWFOComment }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('24')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
SeqLabC '( Not enough Work Fixture Offsets to handle this part. )' EOL
SeqLabC '( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
SeqLabC '( exceeds the machine limit. Switching to non-WFO output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('24')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
SeqLabC '( Not enough Work Fixture Offsets to handle this part. )' EOL
SeqLabC '( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
SeqLabC '( Switching to non-WFO output. )' EOL
END
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLabC ZCP2C EOL
SeqLabC 'G8' EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
GetCycle
SeqLabC
IF Tap? AND OptCyc1?
'G84.1'
ELSE
Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt
IF Tap? AND OptCyc1?
Speed
END
EOL
IF CallMasterOp?
SeqLabC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLabC SubCall CallLab EOL
StartSub
ToolPath
SeqLabC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

NotSameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
ClearCSOffset
SeqLabC CSWFO EOL
ELSE
ClearCSOffset { 11/8/94 }
SeqLabC CSWFO EOL
END
ELSE
IF NeedWFO1?
SeqLabC 'G' NewWFO# EOL
END
END
RETURN

SameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
ClearCSOffset
SeqLabC CSWFO EOL
ELSE
ClearCSOffset { 11/8/94 }
END
END
RETURN

DefaultWFO:
IF NOT SameTool?
IF NeedWFO1?
SeqLabC WFO1 EOL
END
END
RETURN

DefaultCSWFO:
IF NOT SameTool?
SeqLabC CSWFO EOL
END
RETURN

WFOStuff:
IF MultipleParts?
IF NOT WorkFixtureOffsets?
DefaultWFO
END
ELSE
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
SeqLabC CSWFO EOL
ELSE
DefaultCSWFO
END
ELSE
{this post procesors does not use G52s}
END
RETURN

InitOp:
EOR EOL
SeqLabC ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
SeqLabC '( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC '( FORMAT - ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLabC '( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLabC '( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqLabC '( PARTS PROGRAMMED - ' Parts# ' )' EOL
END
IF StartToolComment?
SeqLabC '( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
SeqLab OpToolID ToolChng EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
SeqLabC Plane 'G80' CRCOff Rapid EOL
IF Drilling? AND Tap? AND OptCyc1?
SeqLabC Speed EOL
SeqLabC 'G84.2' EOL
ELSE
SeqLabC Speed SpinOn EOL
END
RETURN

FirstOp3:
CheckPass
SeqLabC AbsOrInc StrtPos CSAngleA CSAngleB EOL
RETURN

FirstOp4:
SeqLabC OfstOn CoolOn EOL
RETURN

NewToolOp1:
SeqLabC CoolOff EOL
SeqLabC IncValue OfstOff SpinOff EOL
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqLab OpToolID ToolChng EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
SeqLabC Plane 'G80' CRCOff Rapid EOL
IF Drilling? AND Tap? AND OptCyc1?
SeqLabC Speed EOL
SeqLabC 'G84.2' EOL
ELSE
SeqLabC Speed SpinOn EOL
END
RETURN

NewToolOp5:
CheckPass
SeqLabC AbsOrInc StrtPos CSAngleA CSAngleB EOL
RETURN

NewToolOp6:
SeqLabC OfstOn CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC CoolOff EOL
SeqLabC IncValue OfstOff SpinOff EOL
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC IncValue OfstOff SpinOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
DoEndOpPS
IF LAST ProgStop?
IF Drilling? AND Tap? AND OptCyc1?
SeqLabC Speed EOL
SeqLabC 'G84.2' EOL
ELSE
SeqLabC SpeedC SpinOn EOL
END
SeqLabC PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
SeqLabC OfstOn CoolOn EOL
ELSE
IF NewToolOffset? OR ChangeCS?
SeqLabC PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB SpeedC EOL
SeqLabC OfstOn EOL
ELSE
SeqLabC PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
RETURN

End1:
SeqLabC CoolOff EOL
SeqLabC IncValue OfstOff SpinOff EOL
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLabC AbsOrInc Rapid FirstHome EOL
ELSE
SeqLabC AbsValue Rapid 'G59X0Y0' EOL
END

IF NotEqual? CSOffsetA# Num#('0')
IF AAxisAvail?
SeqLabC CSAngleA
END
IF BAxisAvail?
SeqLabC CSAngleB
END
EOL

SeqLabC Preset
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
ELSE
IF NotEqual? CSOffsetB# Num#('0')
IF AAxisAvail?
SeqLabC CSAngleA
END
IF BAxisAvail?
SeqLabC CSAngleB
END
EOL

SeqLabC Preset
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
END
IF ProgStop?
SeqLabC 'M0' EOL
END
RETURN

End3:
SeqLabC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
Reseq
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH - ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH - ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH - ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
WFOStuff
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
OpenMP
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
OpenMP
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp4
OpenMP
FirstOp3 {can't XY position before WFO}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp6
OpenMP
NewToolOp5 {can't XY position before WFO}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
WFOStuff
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END