{Change Comments ***********************************************************}

{
10/24/94 [cwh]
B611.81.5 ( from B611.81.4 )

Made changes to ZOnlyRep and FinishSub1 subs to properly handle
Feed connects and clearance moves.
}

{11/8/94
Modified: Fadal Format 2 (FW) B611.81.5
For: Gibbs & Associates
Versions: Catalyst v2.14.12C/Compost 4.21.23
Changes made per Pete Jackson
Changed all occurances of SeqC to SeqLab.
Charles reported a problem involving operations that do not change coordinate systems from
previous operations.
Added ClearCSOffset at NotSameToolWFO and SameToolWFO subs.
DWB}

{11/16/94 Fixed Program Stop bug in NewToolOp2. Tom Hubina}

{
Format: Fadal Format 2 (FW) B611.00
1/4/95
Changed version number to .00 from .81.7 per Fanuc 6M (PW) C001.00.03
Changed all CSAngleAC and CSAngleBC calls to CSAngleA and CSAngleB to output the A and B
commands at the start of every operation.
Added AAxisAvail? and BAxisAvail? checks to CSAngleA and CSAngleB subs
Added return to CS1 moves to End2
Added G92 reset of A and/or B axis to End2
Changed NotSameTool WFO so it would restate the current WFO if no change in CS
Added ClearCSOffset to OpenMP: CloseMP: and SubCSMP:
Added if AChange? OR BChange? to home postition call-out in SameToolOp1
Replaced SetZRepInc and RestoreAbsOrInc with one sub called DoAbsOrInc.
Any line with SetZRepInc now has DoAbsOrInc as the first command after the SeqC.
TH}

{
Format: Fadal Format 2 (FW) B611.00.01
1/13/95
Formatted TrackZNO# to #4
}

{ Added ClearCSOffset to SubCSMP TH}

{
Changed SeqC's to SeqLabs
4/21/95
TH}

{
Fixed unwind code in End2:
5/25/95
TH}

{6/9/95
Fixed CRC so it won't output on a helix
TH}

{7/10/95
Updated: Fadal Format 2 (FW) B611.00.04
For: Gibbs & Associates/Tru-Cut Machine Company
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.14.40/Compost 4.21.30/1.0a
Changes made per Pete Jackson and Bryan Widholm of Tru-Cut Machine Company.
Changed Coolant On from M07 to M08 in Mach Spec Commands 3 dialog.
Updated to Version 4.2 per Fanuc 6M M001.81.2g Format.
Modified CkCRC sub.
Added logic to suppress output of CRCOnC on ZMove Feature.
Added logic to suppress output of CRCOnC in OneFeat ToolPath.
Moved ResetCRCNum at start of ToolPath to CkCRC sub.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at CkCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to ZMoveOnly Feature at ToolPath RapidFeat.
Outputs G40 at all Z Retract blocks.
Deleted DoArcCRC sub.
CkCRC sub now also called at FormatArc sub.
Deletes use of Flag(8)
Deleted CRCValue sub.
Not needed because problem has been resolved, see CNCVIS1 M611.81.7, 5/5/93.
Simplified output of Canned Drill Cycle block at IF Drilling.
DWB}

{8/23/95 - Updated to .10 format TH}

{1/17/96, Updated .10 to .11 version, MPK}

{3/25/96, Tested ZOnlyRepAutoCycle, Changed version # to .12, MPK}

{7/19/96
Copied: Fadal Format 2 (FW) B611.12m
Created: Fadal 2 [AE] B072.13.1m
For: Aylward Enterprises, Inc.
Machine: Fadal 3016
Control:
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.05C/Compost 4.21.37/1.0a
Changes made per Tracy Barnes of Aylward Enterprises, faxes, and VNC, TXT and editted TXT files.
Updated for Catalyst v3.05C per Fanuc 6M (FW) B001.13.1m Format.
Added Var(3) for retracting spindle to Z100.mm at NewToolOp2, SameToolOp1 and End2.
Necessary for all ToolChanges, CSGroupChanges, and at end of output.
Initially stores constant value of 100.
Will store 2540 if VNC document is INCH.
Tests to see if ExitClearancePlane is 100.
IF TRUE, post will not bother.
Suppressing DoCSWFOComment for 3 axis.
Deleted G8 block at ToolPath.
Decreased SetMaxRPM from 15000 to 10000.
Increased SetMaxFeed from 500 to 9525.
Deleted Flag(2).
Was set if Incremental output was selected.
Post never tested Flag(2).
Added customized comments at InitOp.
User comments for all types of jobs planned and will be editted manually by programmer.
Added G52 block at FirstOp2, NewToolOp4, SameToolOp1 and End2.
Outputs distance from top left corner of stock definition to part zero.
Added G53X0Y200. block at NewToolOp2, SameToolOp1 and End2.
Necessary for all M00, CSGroupChanges, and at end of output.
Deleted X0Y0Z0E0H0 block at End3.
DWB}

{8/15/96
Modified: Fadal 2 [AE] B072.13.1m
Created: Fadal 2 [AE] B072.13.2m
For: Aylward Enterprises, Inc.
Versions: Catalyst v3.05.03C/Compost 4.21.37/v1.0b1
Changes made per Tracy Barnes of Aylward Enterprises, faxes, and phone call.
Deleted 'T' TLNum# '=' from EachTool/NextTool loop at InitOp.
Customer will take care of this in TLToolComment$.
Changed Tool Length Offset Cancel from G53 to G49 in Compost2 Tool Offsets Dialog.
Added Rapid 'Z0' OfstOff block at End2.
DWB}

{7/11/97
Initial: Fadal 2 [AE] B072.13.2m
Created: Fadal 2 [AE] B072.13.3m
ForUser: Aylward Enterprises, Inc.
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.35 PPC
Comment: Increased ComPost IJ maximum arc radius size from 100 to 10000.
Jim Radcliffe}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0'
#3 = 'ą*#####.###;0'
#4 = '#####.###;0'
#5 = '#######0'
#6 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SUB#,2)
FORMAT(CSOffsetA#,2)
FORMAT(CSOffsetB#,2)
FORMAT(Dwell#,2)
FORMAT(XStockMin#,3)
FORMAT(YStockMax#,3)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(Recall#,5)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(CSSubID#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)

{Prog Subroutines ****}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
Save# Num#('3') Num#('2540') { OfstOff }
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLab '* SUB NUMBER: ' Program# EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
SeqLab '* OPERATION ' Operation#
IF OperationIDComment?
': ' OperationType$
END
EOL
IF OperationComment?
SeqLab '* ' OperationComment$ EOL
END
IF WorkGroupComment?
SeqLab '* ' WorkGroupComment$ EOL
END
SeqLab '* TOOL ' Tool#
IF ToolTypeComment?
': ' ToolDiameter# ' ' ToolType$
END
EOL
IF ToolComment?
SeqLab '* ' ToolComment$ EOL
END
RestoreScale
END
RETURN

CSWFO:
'E' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
'E' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSAngleA:
IF AAxisAvail?
'A'
IF WFOCS? AND NOT Flag?('9')
'0'
ELSE
IF NOT Flag?('9')
IF FirstOperation?
IF LessThan? CSOffsetA# Num#('0')
'-'
END
ELSE
IF LessThan? CSOffsetA# LAST CSOffsetA#
'-'
END
END
END
Save# Num#('1') TRUNC# DIV# CSOffsetA# Num#('360')
IF LessThan? CSOffsetA# Num#('0')
Save# Num#('1') SUB# Recall# Num#('1') Num#('1')
END
SUB# CSOffsetA# MUL# Recall# Num#('1') Num#('360')
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
'B'
IF WFOCS? AND NOT Flag?('9')
'0'
ELSE
IF NOT Flag?('9')
IF FirstOperation?
IF LessThan? CSOffsetB# Num#('0')
'-'
END
ELSE
IF LessThan? CSOffsetB# LAST CSOffsetB#
'-'
END
END
END
Save# Num#('1') TRUNC# DIV# CSOffsetB# Num#('360')
IF LessThan? CSOffsetB# Num#('0')
Save# Num#('1') SUB# Recall# Num#('1') Num#('1')
END
SUB# CSOffsetB# MUL# Recall# Num#('1') Num#('360')
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
IF AAxisAvail?
SetFlag('9')
SeqLab '* CS#' CS# ' - ' CSComment$ EOL
SeqLab '* ' CalcCSWFO ' = X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' ' CSAngleA ' ' CSAngleB EOL
SetFlagF('9')
END
RETURN

DoCSG52Comment:
SeqLab '* CS#' CS# ' - ' CSComment$ EOL
RETURN

PSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab Feed ZIn FeedEnt EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SeqLab SubIDF EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLab '* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

CalcCallLab:
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
RETURN

StdSub:
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachRep
CalcCallLab
NextRep
FORMAT(Recall#,6)
SeqLab CallLab Recall# Num#('10') EOL
FORMAT(Recall#,5)
StartSub
RETURN

FinishSub1: {part 1}
SeqLab CRCOffC EOL
SeqLab
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLab Preset ShiftR EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftR EOL
RETURN

OpenMP:
NewProg
IF WFOCS?
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
IF WorkFixtureOffsets?
NewWFO
EachWFO {simple eachPart}
SeqLab Rapid StrtPos SetWFO EOL
SeqLab CallLab '01' EOL
IncWFO
NextWFO {simple NextPart}
ELSE
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachPart
CalcCallLab
NextPart
FORMAT(Recall#,6)
SeqLab CallLab Recall# Num#('10') EOL
FORMAT(Recall#,5)
END
StartSub
END
RETURN

CloseMP:
IF WFOCS?
SeqLab EndSub EOL
CloseSub
NewWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqLab CalcCSWFO EOL
SeqLab SubCall CallLabB CSSubID# '01' EOL
NextCSOp
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
IF WorkFixtureOffsets?
SeqLab EndSub EOL
CloseSub
ELSE
SeqLab Preset ShiftP EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftP EOL
END
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqLab EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLab AbsValue EOL
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
SetFlag('5')
END
END
RETURN

FormatLine:
DoAbsOrInc ckCRC FeedC MoveXYZC
RETURN

ckCRCNum:
IF Flag?('5')
SetFlagF('5')
CRCOffsetC
END
RETURN

FormatArc:
DoAbsOrInc ckCRC
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLab MoveSXYC EOL
SeqLab CallLab '01' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLab DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc ckCRC RapidC ckCRCNum MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatLine ckCRCNum FeedRateC EOL
DecelMove2
END
SeqLab FormatLine ckCRCNum DecelFeed EOL
ELSE
SeqLab FormatLine ckCRCNum FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc ckCRCNum ArcFeedC EOL
DecelMove2
END
SeqLab FormatArc ckCRCNum DecelFeed EOL
ELSE
SeqLab FormatArc ckCRCNum ArcFeedC EOL
END
NEXTQuadrant
IF LastFeat?
SeqLab CRCOffC EOL
END
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLab AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqLab EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLab AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab IncValue StrtPosC EOL
AbsOrInc
END
END
SeqLab ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqLab IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqLab ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqLab RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab CallLab '01' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLab Feed ZCP2 FeedEnt EOL
ELSE
SeqLab Rapid ZCP2 EOL
END
END
SeqLab EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab Connect StrtPos EOL {added Connect}
END
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL {changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab RapidC ZInPlusInc EOL {added Rapid, reads better} {changed to RapidC, reads better}
END
END
SeqLab CallLab '01' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('9525')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('5') {True = need CRCOffset }
SetFlagF('9') { CSAngleA, CSAngleB and DoCSWFOComment }
Save# Num#('1') Num#('0') { CSAngleA and CSAngleB }
Save# Num#('3') Num#('100') { OfstOff }
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('40')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
SeqLab '* Not enough Work Fixture Offsets to handle this part.' EOL
SeqLab '* Number of parts ( ' Parts# ' ) times CSs ( ' NumOfCS# ' )' EOL
SeqLab '* exceeds the machine limit. Switching to non-WFO output.' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('40') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
SeqLab '* Not enough Work Fixture Offsets to handle this part.' EOL
SeqLab '* Number of CSs ( ' NumOfCS# ' ) exceeds the machine limit.' EOL
SeqLab '* Switching to non-WFO output.' EOL
END
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab ZCP3C EOL
ELSE
SeqLab CRCOffC EOL { Just in case }
IF FIFO?
SeqLab FeedC ZCP3C FeedEntC EOL
ELSE
SeqLab RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLab AbsOrInc Rapid StrtPos EOL
END
IF Pulse? { Positive Approach On }
SeqLab 'M46' EOL
END
SeqLab DrillCP EOL
GetCycle
SeqLab
IF Tap? AND OptCyc1?
'G84.1'
ELSE
Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt
IF Tap? AND OptCyc1?
Speed
END
EOL
IF CallMasterOp?
SeqLab SubCall CallLabB CallMasterNum# '01' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLab SubCall CallLab '01' EOL
StartSub
ToolPath
SeqLab EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
IF Pulse?
SeqLab 'M47' EOL
ResetCool
END
SeqLab Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

DefaultWFO:
IF NOT SameTool?
IF NeedWFO1?
SeqLab WFO1 EOL
END
END
RETURN

DoCSG52:
DoCSG52Comment
DefaultWFO
SeqLab 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
RETURN

DefaultCSG52:
IF NOT SameTool?
DoCSG52
END
RETURN

DefaultCSWFO:
IF NOT SameTool?
SeqLab CSWFO EOL
END
RETURN

WFOStuff:
IF MultipleParts?
IF NOT WorkFixtureOffsets?
DefaultWFO
END
ELSE
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
SeqLab CSWFO EOL
ELSE
DefaultCSWFO
END
ELSE
IF ChangeCS?
DoCSG52
ELSE
DefaultCSG52
END
END
ClearCSOffset
END
RETURN

InitOp:
EOR EOL
SeqLab 'O' Program#
IF UseComments?
IF ProgramNameComment? AND ProgramComment?
'*' ProgramName$ ';' ProgramComment$
ELSE
IF ProgramNameComment?
'* ' ProgramName$
END
IF ProgramComment?
'* ' ProgramComment$
END
END
EOL
SeqLab '* PROGRAM #=2ND OP.;PROGRAM #=3RD OP.' EOL
IF FormatNameComment?
SeqLab '* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
SeqLab '* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
SeqLab '* OUTPUT IN ' MoveType$ ' MILLIMETERS' EOL
END
SeqLab '* Stock type and size' EOL
IF PartsComment?
SeqLab '* THIS PROGRAM RUNS ' Parts# ' PART'
IF MultipleParts?
'S'
END
' PER CYCLE' EOL
END
IF StartToolComment?
SeqLab '* FIRST TOOL NOT IN SPINDLE' EOL
END
SeqLab '* Block Skip Information' EOL
SeqLab '* E1 X0=LEFT END OF LEFT VISE SOLID JAW' EOL
SeqLab '* E1 Y0=FACE OF SOLID VISE JAW STEP' EOL
SeqLab '* LOAD STOCK " FROM E1 X0;A G52 X OFFSET IS IN PLACE' EOL
SeqLab '* Skim cut the face of solid vise jaws before running' EOL
SeqLab '* MAX. VISE JAW STEP HT.=' EOL
SeqLab '* MAX. VISE JAW STEP WIDTH=' EOL
SeqLab '* Set up a rigid stop in X' EOL
SeqLab '* Stock Offset=X' XStockMin# ';Y' YStockMax# EOL
SeqLab '* Endholes of edgeholes to be cut on manual mill' EOL
SeqLab '* Vice jaw spacing =' EOL
SeqLab '* Use Form Jaws' EOL
SeqLab '* Vice jaws are open;Drill tip clearance =' EOL
SeqLab '* Stock loading instructions; to start program and rotation at all M0' ASCII('39') 's' EOL
SeqLab '* Load stock on parallels; remove them before running program' EOL
SeqLab '* Vice pressure = ; do not over-tighten' EOL
SeqLab '* Part needs to be indicated' EOL
SeqLab '* SET TOOLS mm ABOVE SOLID VISE JAW SEAT' EOL
SeqLab '* TOOL DIAMETER OFFSETS=ACT. RAD.-NOM. RAD.' EOL
SeqLab '* Additional diameter offsets =' EOL
SeqLab '* Modify the depth of cut for chamfer tools and corner round endmills as required' EOL
SeqLab '* Verify drill and reamer depth of cut and end clearances before running; modify as required' EOL
SeqLab '* Part finish requirements and shellmills carbide insert comments' EOL
SeqLab '* Select tools as close to nominal size as possible for 2 + 3 axis cutting - does not use cutter compensation' EOL
SeqLab '* Tool selection comment when print requires square shoulders' EOL
END
EOL
EachTool
SeqLab '* ' TLToolComment$ EOL
NextTool
SetProgNum('0')
IF ToolChangeAtHome?
SetHome
END
OpenSub
RestoreScale
RETURN

FirstOp1:
SeqLab OpToolID ToolChng EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
IF Drilling? AND Tap? AND OptCyc1?
SeqLab Speed EOL
SeqLab 'G84.2' EOL
ELSE
SeqLab Speed SpinOn EOL
END
SeqLab 'G52X' XStockMin# 'Y' YStockMax# 'Z0' EOL
RETURN

FirstOp3:
CheckPass
SeqLab Plane AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
RETURN

FirstOp4:
SeqLab OfstOn CoolOn EOL
RETURN

NewToolOp1:
RETURN

NewToolOp2:
IF NotEqual? LAST ClearancePlane3# Recall# Num#('3')
FORMAT(Recall#,2)
SeqLab Rapid 'Z' Recall# Num#('3') EOL { OfstOff }
FORMAT(Recall#,5)
END
IF LAST ProgStop?
SeqLab SpinOff CoolOff EOL
END
SeqLab 'G52X0Y0Z0' EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqLab 'G53' Home EOL
ELSE
IF LAST ProgStop?
SeqLab 'G53X0Y200.' EOL
END
END
IF LAST ProgStop?
SeqLab 'M00' EOL
ELSE
SeqLab ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqLab OpToolID ToolChng EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
IF Drilling? AND Tap? AND OptCyc1?
SeqLab Speed EOL
SeqLab 'G84.2' EOL
ELSE
SeqLab Speed SpinOn EOL
END
SeqLab 'G52X' XStockMin# 'Y' YStockMax# 'Z0' EOL
RETURN

NewToolOp5:
CheckPass
SeqLab Plane AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
RETURN

NewToolOp6:
SeqLab OfstOn CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop? OR ChangeCS?
IF NotEqual? LAST ClearancePlane3# Recall# Num#('3')
FORMAT(Recall#,2)
SeqLab Rapid 'Z' Recall# Num#('3') EOL { OfstOff }
FORMAT(Recall#,5)
END
SeqLab SpinOff CoolOff EOL
SeqLab 'G52X0Y0Z0' EOL
IF ToolChangeAtHome?
SeqLab 'G53' Home EOL
ELSE
SeqLab 'G53X0Y200.' EOL
END
IF LAST ProgStop?
SeqLab 'M00' EOL
END
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab CoolOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop? OR ChangeCS?
IF Drilling? AND Tap? AND OptCyc1?
SeqLab SpeedC EOL
SeqLab 'G84.2' EOL
ELSE
SeqLab SpeedC SpinOn EOL
END
SeqLab PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
SeqLab OfstOn CoolOn EOL
ELSE
SeqLab SpeedC EOL
SeqLab PlaneC AbsOrInc Rapid StrtPos CSAngleA CSAngleB EOL
IF NewToolOffset?
SeqLab OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLab CoolOn EOL
END
END
RETURN

End1:
RETURN

End2:
IF NotEqual? ClearancePlane3# Recall# Num#('3')
FORMAT(Recall#,2)
SeqLab Rapid 'Z' Recall# Num#('3') EOL { OfstOff }
FORMAT(Recall#,5)
END
SeqLab SpinOff CoolOff EOL
SeqLab 'G52X0Y0Z0' EOL
DoEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqLab WFO1 EOL
SeqLab AbsOrInc Rapid FirstHome EOL
ELSE
SeqLab 'G53X0Y200.' EOL
END
SeqLab Rapid 'Z0' OfstOff EOL
IF Equal? CSOffsetA# Num#('0') AND Equal? CSOffsetB# Num#('0')
ELSE
SeqLab
IF AAxisAvail?
CSAngleA
END
IF BAxisAvail?
CSAngleB
END
EOL
SeqLab Preset
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
IF ProgStop?
SeqLab 'M00' EOL
END
RETURN

End3:
SeqLab EOP EOL
EndSubs
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
Reseq
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
WFOStuff
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
OpenMP
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
OpenMP
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp4
OpenMP
FirstOp3 {can't XY position before WFO}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp6
OpenMP
NewToolOp5 {can't XY position before WFO}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
WFOStuff
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END