{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=T
MILLTURN_POLAR-SEG=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{8/1/95,
Updated for Catalyst v2.20 per Fanuc 6M M001.85.01 Format.
This is a Tagging Post with special CutterRadiusCompensation.
DWB}

{11/2/95
Modified: Dynapath 20M Convrs M312.85
For: Norman Tool, Inc.
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.08/Catalyst v2.28.04/Compost 4.21.33/1.0a
Changes made per Sam Fredrick of Norman Tool, Inc.
Added UnToolChng sub prior to CloseMP sub.
Called from CloseMP sub and end of Prog.
Customer reported problem when doing MultipleParts AND AllToolsOnePart.
Post was outputting move to ToolChng Position prior to Origin Shift.
This resulted in all but the First Part to be machined at the same place.
Various other necessary minor changes, too numerous to list due to time constraints.
DWB}

{5/22/96,
Initial: Dynapath 20M Convrs M312.85.1
Created: Dynapath 20M Convrs MXXX.85
For: Brockman Precision Machine
The customer's machine does not have a changer, eliminated first tool change, eliminated pretooling,
deleted untool at program end, MPK}

{25Feb99
Original: Dynapath 20M Con [BPM] M379.85
Created: Dynapath 20M Con [JBC] Mxxx.85
For: JBC Machine Inc.
Changes made per: Steve Trudell
Develop: Catalyst 5.05/ComPost2 1.7b15
Added Post Header Comment at the top of Prog.
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added Format#8 and formatting for Div# at Prog Numeric Format Definitions.
Added Tool Change in FirstOperation. The customer's machine does have a changer.
Moved CoolOn up after ToolOffset line in FirstOperation and NewTool.
Added RigidTap Cycle at Drilling. Feed is Negative if Part is Metric.
Added 'Q' Retract# Boolean for Peck Full Out Cycles.
Charles Winston}

{03/08/99,
Initial: Dynapath 20M Cnv [JBC] MQ26.85
Created: Dynapath 20M Cnv [JBC] MQ26.85.1
For: JBC Machine

Changes to Prog:
1) FirstOp - Changed Seq on ToolChng to SeqLab.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0'
#7 = '00'
#8 = '*####.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4)
FORMAT(DIV#,4)
FORMAT(Recall#,5)
FORMAT(Tag#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(RapidF#,6)
FORMAT(Dwell#,6)
FORMAT(NewWFO#,7)
FORMAT(ToolOffset#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

Get$: { For conversational output }
IF NOT EmptyLine?
'$'
END
RETURN

TurnCRCOn:
IF CutterRadiusCompensation? AND NOT Flag?('2')
IF NOT LastFeat? AND NOT ZMove?
SetFlag('2')
SeqLab '(1)'
IF AutoCycle?
MoveSX '/' MoveSY '/'
ELSE
MoveSX MoveSY
END
CRCOff Get$ EOL
END
END
RETURN

TurnCRCOff:
IF CutterRadiusCompensation? AND Flag?('2')
SetFlagF('2')
SeqLab '(1)'
IF AutoCycle?
MoveX '/' MoveY '/'
ELSE
MoveXY
END
CRCOff Get$ EOL
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLab '(T) SUB NUMBER ' Tag# Get$ EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '(T) OPERATION ' Operation# ' ' OperationType$ Get$ EOL
END
IF OperationComment?
SeqLab '(T) ' OperationComment$ Get$ EOL
END
IF WorkGroupComment?
SeqLab '(T) ' WorkGroupComment$ Get$ EOL
END
IF ToolTypeComment?
SeqLab '(T) TOOL# ' Tool# ' ' ToolDiameter# ' ' ToolType$ Get$ EOL
END
IF ToolComment?
SeqLab '(T) ' ToolComment$ Get$ EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript Get$ EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS Get$ EOL
PSStuff
NextPS
RETURN

EntryMove:
SeqLab
IF FeedEntry?
'(1)'
ELSE
'(0)'
END
ZIn
IF AutoCycle? { Implies Incremental }
'/'
END
IF FeedEntry?
FeedEnt
END
Get$ EOL
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) Z CLEARANCE WILL' Get$ EOL
SeqLab '(T) CHANGE WITH EACH' Get$ EOL
SeqLab '(T) CYCLE OF SUB!' Get$ EOL
SeqLab '(T) ' Get$ EOL
END
END
RETURN

StdSub:
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' RepsLess1 Get$ EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
SeqLab
IF AutoCycle?
'(0)' ZCP3
ELSE
IF FIFO?
'(1)' ZCP3 FeedEntC
ELSE
'(0)' ZCP3
END
END
Get$ EOL
END
RETURN

FinishSubG92: {part 2}
SeqLab '(0)' ShiftRC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftRC Preset Get$ EOL
RETURN

OpenMP:
TagUp TagInc
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLab '(9)' SetWFO Get$ EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
IncWFO
NextWFO
ELSE
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' PartsLess1 Get$ EOL
END
StartSub
RETURN

UnToolChng:
SeqLab '(9)' ToolChng Get$ EOL
RETURN

CloseMP:
IF WorkFixtureOffsets?
IF AllToolsOnePart?
UnToolChng
END
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(9)' WFO1 Get$ EOL
ELSE
SeqLab '(0)' ShiftPC Preset Get$ EOL
IF AllToolsOnePart?
UnToolChng
END
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftPC Preset Get$ EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') { AbsoluteMoves? = TRUE }
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') { AbsoluteMoves? = TRUE }
IF SPZMove? AND AbsValue?
SetInc
ELSE
IF NOT SPZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
SetAbs
END
RETURN

GetPlane:
IF XYPlane?
IF NOT AutoCycle?
IF FirstFeat?
IF XMove? OR YMove?
'P0' { This is the default Plane select }
END
END
END
ELSE
IF XZPlane?
'P2'
ELSE {YZPlane}
'P1'
END
END
RETURN

CheckMove:
IF Drilling?
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
IF XMove?
MoveSX '/'
END
IF YMove?
MoveSY '/'
END
IF ZMove?
MoveSZ '/'
END
ELSE
MoveSXYZC
END
ELSE
IF AutoCycle? { Implies Incremental }
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
IF ZMove?
MoveZ '/'
END
ELSE
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
IF ZMove?
MoveZ '/'
END
ELSE
MoveXYZC
END
END
END
RETURN

FormatArc:
DoAbsOrInc GetPlane CheckMove
IF AutoCycle?
ArcI '/' ArcJ '/'
ELSE
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
ArcI '/' ArcJ '/'
ELSE
ArcIJ
END
END
IF ArcCW?
CWArc
ELSE
CCWArc
END
RETURN

ckCRC:
IF CutterRadiusCompensation? AND Flag?('2')
IF NOT LastFeat? AND NOT ZMove?
CRCOnC
END
END
RETURN

FormatLine:
DoAbsOrInc GetPlane CheckMove ckCRC
RETURN

ckCRCNum:
{ Not supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqLab '(0)' MoveSXYC Get$ EOL
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
SeqLab '(0)' DoDrillAbsOrInc CheckMove Get$ EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
TurnCRCOn
IF CutterRadiusCompensation? AND Flag?('2')
SeqLab '(1)' FormatLine RapidFC Get$ EOL
ELSE
SeqLab '(0)' FormatLine Get$ EOL
END
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
TurnCRCOn
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(1)' FormatLine FeedRateC Get$ EOL
DecelMove2
END
SeqLab '(1)' FormatLine DecelFeed Get$ EOL
ELSE
SeqLab '(1)' FormatLine FeedRateC Get$ EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
DecelMove2
END
SeqLab '(2)' FormatArc DecelFeed Get$ EOL
ELSE
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
END
NEXTQuadrant
END
END
END
IF LastFeat? { Exit Length Feature }
TurnCRCOff {.70}
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
Get$ EOL
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) DO NOT USE' Get$ EOL
SeqLab '(T) NEWWFO() WITH' Get$ EOL
SeqLab '(T) NCPOST MULTIPLE' Get$ EOL
SeqLab '(T) PARTS!' Get$ EOL
SeqLab '(T) ' Get$ EOL
ELSE
'E' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'E' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
SeqLab '(1)' 'P0X0./Y0./' Get$ EOL { AutoCycle dummy move to select correct Plane }
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
SeqLab '(1)' ZCP2 FeedEntC Get$ EOL
ELSE
SeqLab '(0)' ZCP2 Get$ EOL
END
END
'<' Tag# EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SetAbs
IF FeedConnect?
'(1)'
ELSE
'(0)'
END
SeqLab StrtPos Get$ EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
IF FeedConnect?
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab '(0)' ZCP2PlusInc Get$ EOL
{can't call for cycle = 1 changed to ZCP2PlusInc}
END
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Get$ EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLab '(1)' ZCP2 FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZCP2 Get$ EOL
END
END
TagDown
'<' Tag# EOL
CloseSub
{Element shift, not pattern}
TagDown
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
IF FeedConnect?
'(1)'
ELSE
'(0)'
END
SeqLab StrtPos Get$ EOL
END
IF FeedConnect?
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab '(0)' ZCP2PlusInc Get$ EOL
END
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Get$ EOL
END
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
'<' Tag# EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
Plane { no output }
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
SetAbs
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CutterRadiusCompensation }
SetFlagF('4') { SubPrograms require 2nd M30 at end }
IF PSComment? AND UseComments?
SeqLab '(T) PostScript:' Get$ EOL
SeqLab '(T) Literals: put between single or double quotes.' Get$ EOL
SeqLab '(T) Separate commands and literals with at least one space.' Get$ EOL
SeqLab '(T) A CR ( RETURN key ) will start a new line.' Get$ EOL
SeqLab '(T) Commands: may be capital and/or lower case letters. Separate commands with a space.' Get$ EOL
SeqLab '(T) EndOP -' Get$ EOL
SeqLab '(T) all literals and commands before an ENDOP command' Get$ EOL
SeqLab '(T) will appear at the beginning of the operation. All' Get$ EOL
SeqLab '(T) literals and commands after an ENDOP command will appear' Get$ EOL
SeqLab '(T) at the end of the operation.' Get$ EOL
SeqLab '(T) NewWFO(56), NWFO(56) -' Get$ EOL
SeqLab '(T) The Work Fixture Offset # you specify will be used for all following operations.' Get$ EOL
SeqLab '(T) Do not use with the ncPost multiple part option.' Get$ EOL
SeqLab '(T) 4thAxisCW(12.5), 4ACW(12.5) -' Get$ EOL
SeqLab '(T) generates a + A move of the value you specify' Get$ EOL
SeqLab '(T) 4thAxisCCW(22.5), 4ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - A move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCW(30), 5ACW(30) -' Get$ EOL
SeqLab '(T) generates a + B move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCCW(22.5), 5ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - B move of the value you specify' Get$ EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
'(' Program# ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLab '(T) PROGRAM ' ProgramName$ Get$ EOL
END
IF ProgramComment?
SeqLab '(T) ' ProgramComment$ Get$ EOL
END
IF FormatNameComment?
SeqLab '(T) FORMAT ' FormatName$ Get$ EOL
END
IF TimeComment?
SeqLab '(T) ' Date$ ' AT ' Time$ Get$ EOL
END
IF MovesComment?
SeqLab '(T) OUTPUT IN ABSOLUTE INCHES' Get$ EOL
END
IF PartsComment?
SeqLab '(T) PARTS PROGRAMMED ' Parts# Get$ EOL
END
IF StartToolComment?
SeqLab '(T) FIRST TOOL NOT IN SPINDLE' Get$ EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Plane { no output }
DoOpComments
DoPostScript
SeqLab '(9)' ToolChng OpToolID Get$ EOL
SeqLab '(9)' SpinOn WFOStuff 'T' ToolOffset# Speed Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab '(9)' CoolOff Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
ELSE
IF OptionalStops?
SeqLab '(9)' ProgStop Get$ EOL
END
END

{Start new Operation}

Plane { no output }
DoOpComments
DoPostScript
SeqLab '(9)' ToolChng OpToolID Get$ EOL
SeqLab '(9)' SpinOn WFOStuff 'T' ToolOffset# Speed Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' CoolOff Get$ EOL
SeqLab '(9)' SpinOff Get$ EOL
SeqLab '(9)' 'M0' Get$ EOL

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' SpinOn WFOStuff OpToolID ToolOffset# Speed Get$ EOL
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab '(9)' CoolOff Get$ EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' WFOStuff OpToolID ToolOffset# Speed Get$ EOL
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' WFOStuff Speed Get$ EOL
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
END
END
END
END {common point for all operations}
IF MultipleParts? OR Repeats? OR AutoCycle?
SetFlag('4') { SubPrograms require 2nd M30 at end }
END
IF Milling?
SeqLab '(0)' ZCP2 Get$ EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF AutoCycle?
SeqLab '(0)' ZCP3 Get$ EOL
ELSE
IF FIFO?
SeqLab '(1)' ZCP3 FeedEntC Get$ EOL
ELSE
SeqLab '(0)' ZCP3 Get$ EOL
END
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SetAbs
SeqLab '(0)' StrtPos Get$ EOL
END
IF RetractToCP1?
LoadFeat Num#('0') Num#('0') ClearancePlane1#
ELSE
LoadFeat Num#('0') Num#('0') ClearancePlane2#
END
IF ZMove?
SeqLab '(0)' MoveZ Get$ EOL
END
GetCycle
SeqLab '(0)' StrtPos RLevel ZDepth Dwell Peck
IF Tap? AND RigidTap?
IF Metric? { Feed is Negative }
FORMAT(DIV#,8)
END
'F' DIV# Num#('1') FeedTapIPR#('1') 'G8'
FORMAT(DIV#,4)
ELSE
IF Peck?
IF PeckChipBreaker?
'/'
END
'Q' Retract#
END
FeedEnt Cycle
END
Get$ EOL
IF CallMasterOp?
SeqLab '(7)'
'FÅ‚' CallMasterNum#
'L²' CallMasterNum# Get$ EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
SetFlag('4') { SubPrograms require 2nd M30 at end }
TagUp
NewMasterTag
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
StartSub
ToolPath
'<' Tag# EOL
TagDown
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLab '(0)' ZCP3 Rapid Get$ EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab '(9)' CoolOff Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab '(9)' EOP Get$ EOL
CloseSub
Post2 {organize Subs into one program}
IF Flag?('4') { SubPrograms exist }
SetFlagF('4')
SeqLab '(9)' EOP Get$ EOL { This is required a second time, at end of all subs }
END
'END' EOL
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'N9997(T) FILE LENGTH: ' FileBytes# ' CHARACTERS' Get$ EOL
END
IF FileFeetComment?
'N9998(T) FILE LENGTH: ' FileFeet# ' FEET' Get$ EOL
END
IF FileMetersComment?
'N9999(T) FILE LENGTH: ' FileMeters# ' METERS' Get$ EOL
END
Close
END